Convert_Text_to_Base64 ( string )

Converts a FileMaker text string to a Base64 string.

Average rating: 4.2 (33 votes) Log in to vote

Mogens Brun
fmIntegrator ApS
http://fmIntegrator.com

Sample input:

Convert_Text_to_Base64 ( "Man" )
Convert_Text_to_Base64 ( Convert_Text_to_UTF8 ( "Mænd med idéer" ) )

Sample output:

TWFu
TcOmbmQgbWVkIGlkw6llcg==

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*******************************************************************************
 * Convert_Text_to_Base64 ( string )
 * Converts a FileMaker text string to a Base64 string. May be used together with "Convert_Text_to_UTF8" to ensure char values less than 256 in input string - as "Convert_Text_to_Base64 ( Convert_Text_to_UTF8 ( string ) )". The combined action of the two custom functions performs with double speed as "AscIIToBase64" (also briandunning.com) and handles all legal char. values in UTF-8.
 *
 * @parameter string: A string of text with character codes between 0 and 255
 *
 * @return: A string of text encoded in Base64.
 *
 * @history 2014-06-27 - Mogens Brun, fmIntegrator ApS, <mogens_brun@me.com> - Created
 *
 * @see http://en.wikipedia.org/wiki/Base64
 ******************************************************************************/
Let ( [
	_i1 = Code ( Middle ( string ; 1 ; 1 ) ) ;
	_i2 = Code ( Middle ( string ; 2 ; 1 ) ) ;
	_i3 = Code ( Middle ( string ; 3 ; 1 ) ) ;
	_i1 = If ( _i1 = 11 ; 10 ; _i1 ) ;
	_i2 = If ( _i2 = 11 ; 10 ; _i2 ) ;
	_i3 = If ( _i3 = 11 ; 10 ; _i3 ) ;
	_o1 = Int ( _i1 / 4 ) ;
	_o2 = Mod ( _i1 ; 4 ) * 16 + Int ( _i2 / 16 ) ;
	_o3 = Mod ( _i2 ; 16 ) * 4 + Int ( _i3 / 64 ) ;
	_o4 = Mod ( _i3 ; 64 ) ;
	_base64 = "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/" ;
	_length = Length ( string ) ;
	_result = Middle ( _base64 ; _o1 + 1 ; 1 ) & Middle ( _base64 ; _o2 + 1 ; 1 ) & If ( _o3 = 0 and _length < 3 ; "=" ; Middle ( _base64 ; _o3 + 1 ; 1 ) ) & If ( _o4 = 0 and _length < 3 ; "=" ; Middle ( _base64 ; _o4 + 1 ; 1 ) )
] ;
	Case (
		_length = 0 ; ""; 
		_length > 3 ; _result & Convert_Text_to_Base64 ( Middle ( string ; 4 ; _length - 3 ) ) ; 
		_result )
)

Converts a FileMaker text string to a Base64 string. May be used together with "Convert_Text_to_UTF8" to ensure char values less than 256 in input string - as "Convert_Text_to_Base64 ( Convert_Text_to_UTF8 ( string ) )". The combined action of the two custom functions performs with double speed as "AscIIToBase64" (also briandunning.com) and handles all legal char. values in UTF-8.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

Convert_Text_to_Base64 ( string )

Comments

Support this website.

Support this website.