FormatTimestamp ( _ts ; _f )

PHP standards 4 timestamp, date and time formatting

Average rating: 3.7 (53 votes) Log in to vote

ThomasSeidler - Show more from this author
The Good Book Company Ltd
http://www.thegoodbook.co.uk

Sample input:

FormatTimestamp(Get(CurrentDate); "Y-d.m")

FormatTimestamp(Get(CurrentTime); "g:ia")

FormatTimestamp(Get(CurrentTimestamp); "RFC822")

FormatTimestamp(Get(CurrentTimestamp); "d.m.y - H:i:s")

Sample output:

2009-6.5

4:44pm

Wed, 06 May 09 16:44:47

06.05.09 - 16:44:47

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/* wanted a standards based function for this - based on http://uk3.php.net/manual/en/function.date.php

_ts - timestamp
_f - format string

recursive to go thru each character

*/

Let (

[

// substitution for constant expressions - i.e. submit RFC822 and away-ish you go - u still need to add timezone stuff to end afterwards...
_f = Substitute (_f ; ["RFC822" ; "D, d M y H:i:s"]; ["RSS"; "D, d M Y H:i:s"]);

_c = Left(_f;1) ;
_lf = Length(_f);
_f = Right(_f; _lf-1);
_result = Case (
	
	// DAY
	Exact(_c; "d" ) ; Right ( "0" & Day( _ts ) ; 2 ) ;
	Exact(_c; "D") ; Left( DayName( _ts ) ; 3 ) ;
	Exact(_c; "j" ); Day ( _ts ) ;
	Exact(_c; "l") ; DayName ( _ts ) ;
	Exact(_c; "N") ; Mod ( DayOfWeek ( _ts ) -2 ; 7 )+1 ;
	Exact(_c; "S" ); /* number_Ordinal_Suffix ( Day ( _ts) ) */ ""  ;
	Exact(_c; "w" ); DayOfWeek ( _ts ) - 1  ;
	Exact(_c; "z") ; DayOfYear ( _ts )  ;
	
	// WEEK
	Exact(_c; "W") ; WeekOfYearFiscal ( _ts ; 2 )  ;
	
	// MONTH
	Exact(_c; "F" ); MonthName ( _ts )  ;
	Exact(_c; "m") ; Right ( "0" & Month ( _ts ) ; 2) ;
	Exact(_c; "M") ; Left ( MonthName ( _ts ) ; 3 )  ;
	Exact(_c; "n") ; Month ( _ts )  ;
	Exact(_c; "t"); Day ( Date ( Month(_ts)+1 ; -1 ; Year(_ts) ) )  ;
	
	// YEAR
	// leap year calc nicked from http://www.mitre.org/tech/cots/LEAPCALC.html
	Exact(_c; "L") ; Let ( _y = Year(_ts);  Case ( Mod ( _y ; 4 ) ≠ 0 ; 0 ; Mod(_y;400)=0; 1; Mod(_y;100)=0; 0; 1)  )  ;
	Exact(_c; "o"); If ( WeekOfYearFiscal ( _ts ; 2 ) > 51  and Day(_ts)<7 ; Year(_ts)-1 ; Year(_ts) )  ;
	Exact(_c; "Y") ; Year(_ts);
	Exact(_c; "y"); Right(Year(_ts); 2);
	
	// TIME
	Exact(_c; "a"); If(Hour(_ts)>=12; "pm"; "am") ;
	Exact(_c; "A"); If(Hour(_ts)>=12; "PM"; "AM") ;
	Exact(_c; "g"); Mod( Hour(_ts)-1;12)+1;
	Exact(_c; "G"); Hour(_ts);
	Exact(_c; "h"); Right( "0" & Mod(Hour(_ts)-1;12)+1; 2);
	Exact(_c; "H"); Right ("0" & Hour(_ts); 2);
	Exact(_c; "i"); Right("0" & Minute(_ts); 2);
	Exact(_c; "s"); Right("0" & Seconds(_ts); 2);
	
	_c

) // end of case	



] ;


_result & If(_lf>1; FormatTimestamp (_ts; _f) )

)

I looked at http://www.briandunning.com/cf/893, but wanted something to be using Timestamps, so either date or time i pass, it can format nicely... i think this is a nice generic function, and cos it uses Exact, u can add to it without worrying about substitution order etc...

To learn format options go to: http://uk3.php.net/manual/en/function.date.php

Timezone stuff don't work. If you wish to go the extra mile and get that working go for it and email me at tom "@t" seidler [dot] co_uk and i'll update this...

I've commented out the ordinal suffix option, cos it depends on another custom function, but kind of useful (http://www.briandunning.com/cf/118).

Comments

		Thomas Seidler, London, UK May 6, 2009
apologies to any who've used this so far, a few bugs, you know how it is with Mod(x - 1; divisor)+1 etc - i left em out in some places... notably the g and h, just corrected... get in touch if u find any bugs...

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

FormatTimestamp ( _ts ; _f )

Comments

Support this website.

Support this website.