balance ( theText ; openbracket ; closebracket ; instance )

Get text to length that balances open/close markers

Average rating: 4.4 (42 votes) Log in to vote

Bruce Robertson - Show more from this author

Sample input:

balance( "((a=b); (1); [ (a,b);(c;d)]); ( 1;3;4)"; "("; ")";1)

Sample output:

((a=b); (1); [ (a,b);(c;d)])

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*
balance( theText; openbracket; closebracket; instance )
Bruce Robertson - Concise Design

Version 2.0
12/17/2014 rewritten to return a specific instance of the bracketed value.

Given text such as JSON formatted text, look for specified instance of openbracket
then look for instance of closebracket satisfying condition
that count of openbracket = count of closebracket

Returns all text up to and including identified closebracket

Example 1
balance( "((a=b); (1); [ (a,b);(c;d)]); ( 1;3;4)"; "("; ")" ; 1)
 => ((a=b); (1); [ (a,b);(c;d)])

Example 2
balance( "((a=b); (1); [ (a,b);(c;d)]); ( 1;3;4)"; "("; ")" ; 3)
 => (1)

balance( "{\"people\":[{\"ID\":\"13\",\"name\":\"Bill\"},{ \"ID\":\"14\",\"name\":\"Sam\"}]}" ; "{" ; "}"; 3 )
 => {"ID":"14","name":"Sam"}

*/

Case( 
IsEmpty( theText ); "" ;

Let ( [
$endBracketNum = 1+ $endBracketNum ;
L1 = Length( openbracket );
L2 = Length( closebracket );
p1 = Position ( theText; openbracket ; 1 ; instance )  ;
p2 = Position ( theText; closebracket ; P1+1; $endBracketNum ) ;
p3 = Position ( theText; openbracket ; P1 ; 1+$endBracketNum )  
];

Case(
P1 = 0; Let( $endBracketNum = ""; "" );
P2 = 0; Let( $endBracketNum = ""; "" ) ;
P3 = 0; Let( $endBracketNum = ""; Middle( theText; P1; P2 +L2 - P1 ));
P3>P2; Let( $endBracketNum = ""; Middle( theText; P1; P2 +L2 - P1 ));

balance( theText;  openbracket; closebracket; instance )
)))

Given text such as JSON or HTML or XML formatted text, look for specified instance of openbracket, then look for instance of closebracket satisfying condition that count of openbracket = count of closebracket.

Returns all text up to and including identified closebracket

Can be used with single or multi character values:
{}; (); []; ; <: :> etc.

Recursive function.
Edited 12/17/2014

Comments

		Christopher Kuhn, Temecula Jul 11, 2014
Hi, I found that if the openbracket and closebracket are the same character then the function returns a single character...the bracket. I changed the function such that the location of the close bracket is AFTER the location of the openbracket.... original: p2 = Position ( theText; closebracket ; 1; $instance ) ; change: p2 = Position ( theText; closebracket ; p1+1 ; $instance ) ; Now, i can find quoted strings with the function :)

		Bruce Robertson Dec 17, 2014
Christopher - thanks for the suggested mod! Incorporated in revised version.

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

balance ( theText ; openbracket ; closebracket ; instance )

Comments

Support this website.

Support this website.