NumberInWords ( NumberIn ; Currency ; DecimalCurr )

Convert Number to Words, including currency terms.

Average rating: 3.9 (42 votes) Log in to vote

Chris Harvey
Bank of Bermuda
http://www.bankofbermuda.bm

Sample input:

61915.21

Sample output:

Sixty One Thousand Nine Hundred Fifteen Dollars and Twenty One Cents

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

Case(NumberIn = 0; ""; 

Let ( [
FullNumber = GetAsNumber( numberin ); 
Number = Int( FullNumber ); 
len = If ( Number = 0 ; 0 ; Int(Log(Number)) + 1 )
] ; 
Case(len > 15; 
  "Out of Range"; 
Currency = "EvalOnly"; 
   Let([
    Hundred = Left(number; 1); 
    TensOnes = Right(number; 2); 
    TONum = GetAsNumber(TensOnes); 
    Tens = Left(TensOnes; 1); 
    Ones = If( TONum < 20; TensOnes; Right(TensOnes; 1))
  ];
  Case(len = 3; 
    Choose(hundred; ""; "One"; "Two"; "Three"; "Four "; "Five"; "Six"; "Seven"; "Eight"; "Nine") & " Hundred" & Case(TONum≠0;" "))
  & Case(TONum > 19; 
    Choose(tens; ""; ""; "Twenty"; "Thirty"; "Forty"; "Fifty"; "Sixty"; "Seventy"; "Eighty"; "Ninety") & Case(Ones ≠ 0; " ")) 
  & Choose(ones; ""; "One"; "Two"; "Three"; "Four "; "Five"; "Six"; "Seven"; "Eight"; "Nine"; "Ten"; "Eleven"; "Twelve"; "Thirteen"; "Fourteen"; "Fifteen"; "Sixteen"; "Seventeen"; "Eighteen"; "Nineteen")
);

  Case(len >3; 
    Let([
      UseLeft = Choose(Mod(len;  3);3; 1; 2); 
      NewLen= 10 ^ (len - UseLeft); 
      ThisValue = Div(number; NewLen); 
      NewValue = Number - ThisValue * NewLen
    ]; 
    NumberInWords ( ThisValue; "EvalOnly"; "None" ) & " " & Choose( Div(len - 1; 3); ""; "Thousand"; "Million"; "Billion"; "Trillion" ) & Case(NewValue ≠ 0;" " & NumberInWords(NewValue; ""; "None"))
    ); 
  len = 0; "Zero" ;
  NumberInWords(Number; "EvalOnly"; "None")) & Case(currency ≠ ""; " " & Currency)
  &  Case(DecimalCurr ≠ "None"; " and " 
    & Let(
      Decimal = Int(100 * (fullnumber - number)); 
    If(Decimal = 0; "Zero"; NumberInWords(Decimal; "EvalOnly"; "None"))) & " " & DecimalCurr))
))

This should work for most currencies, or even other units such as gallons or litres, etc. Give a null value for Currency if you don't want one. If you want the decimal part to be ignored, set Decimalcurr to "None".
In it's current form this function will handle values into the Trillions. As it works recursively, you can change the Out of Range check value and the names in one Choose function to extend it. It can also handle British Billions by changing the one Choose list.

Comments

		krishna, Bnagalore Jun 7, 2016
Hello, Kindly help me how can above custom function can be used to convert number to words in vtiget invoice /sales orders. Regards, Krishnaprasad PB

		Philip McGeehan, SMD Ltd Jul 5, 2016
You need FileMaker Pro Advanced to create a new custom function called NumberInWords with the parameters: "NumberIn"; "Currency"; and "DecimalCurr"; and the calculation as above. Then you can create a new calculation field as text in your invoice/sales orders table with the calculation: NumberInWords ( YOURNUMBERFIELD ; "pounds" ; "pence" ) Change the YOURNUMBERFIELD text to the field name where your number you want to convert is.

		Seamus Berkeley, Taos Dec 22, 2016
Thanks so much for this custom function, Chrisâ€”works super! Just one minor edit: the text "Four" has an added space at the end of the word (as written "Four "). Just removed that space in two places and now result has no double spacing.

		Kireet Oct 3, 2018
Hi Philip. This function works great. However, (since I am an amateur at this) I need to write amount in words in Crores, Lac, Thousands (Indian currency).... How can I do that?

		Messahel messaoud, nowhere May 13, 2020
hello thx for this amazing function . by the way i translate your function to arabic . i hop you like what am doing https://www.briandunning.com/cf/2377

		Binu Alexander, ASC, Aug 30, 2020
Works well for INR and Paisa too !

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

NumberInWords ( NumberIn ; Currency ; DecimalCurr )

Comments

Support this website.

Support this website.