HashFNV1a64 ( text ; empty )

A function to calculate the 64 bit FNV-1a hash of a text string.

Average rating: 4.1 (39 votes) Log in to vote

Vaughan Bromfield - Show more from this author

Sample input:

HashFNV1a64 ( "contacts" ; "" )

Sample output:

0001001111000111111110000011001000101000000110100011100111000101

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

// HashFNV1a64 ( text ; empty )
// The initial value for "empty" must be empty ("")
//
// This function computes a 64-bit binary hash
// for the input text based on the FNV-1a algorithm
//
// This function requires the following functions:
//      Bin2dec ( bin ; empty ) 
//      Dec2bin ( decimalNumber ; empty )
//      XORbin ( bin0 ; bin1 ; empty )
//
// This custom function was written by Vaughan Bromfield
// vbromfield@optusnet.com.au
// 14 March 2010
//
// This function is based on the algorithm published at:
// http://www.isthe.com/chongo/tech/comp/fnv/index.html
// http://en.wikipedia.org/wiki/Fowler_Noll_Vo_hash



Case ( 

Length( text ) = 0 ; empty ; // return 64 bit binary result

Let( 
[
offset = 14695981039346656037 ; 
prime = 1099511628211 ; 
chr = Right ( text ; 1 ) ; 
nextxt = Left ( text ; Length( text ) - 1 ) ; 
hash0 = If( IsEmpty( empty ) ; Dec2bin( offset ; "" ) ; empty ) ; 
hash1 = XORbin( hash0 ; Dec2bin( Code( chr ) ; "" ) ; "" ) ; 
hash2 =  Right( "0000000000000000000000000000000000000000000000000000000000000000" & Dec2bin( Mod( Bin2dec( hash1 ; "" ) * prime ; 2^64 ) ; "" ) ; 64 )
] ; 

HashFNV1a64 ( nextxt ; hash2 ) 

) //end let

) //end case

A function to calculate the 64 bit FNV-1a hash of a text string.

Comments

		Vaughan Bromfield Nov 11, 2010
Could the people that rate the function poorly please add a comment to let me know what the disappointment is. Thanks - Vaughan.

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

HashFNV1a64 ( text ; empty )

Comments

Support this website.

Support this website.