ParseTime ( timeText )

This function parses and reformats time (hours and minutes) casually entered into a text field so that it can be converted to a valid time by Filemaker.

Average rating: 4.3 (37 votes) Log in to vote

Fritz Mills
Media LightBridge, LLC
http://www.medialightbridge.com

Sample input:

1245

Sample output:

12:45 PM

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

ParseTime ( timeText ) = 

/* This function parses and reformats time (hours and minutes) casually entered into a text field so that it can be converted to a valid time by Filemaker. It also includes tests so that, if an invalid time string is entered, it will return an error message instead of an invalid time. Further, it incorporates code from the TimeMask custom function written by Steve Gerow of Abrazos Data Consulting that logically assigns AM or PM to times entered without that data between 7am and 7pm. It handles military time correctly as well. Many thanks to Steve, and to Brian Dunning. */


Let ( 
[ 
nums = Filter ( timeText ; "0123456789" ) ; 
chars = Filter (Upper ( timeText ) ; "AMNP" ) ; 
lgthN = Length ( nums ) ; 
lgthC = Length (chars ) ; 
numTest = Case ( GetAsNumber ( nums ) < 1260 ; 1 ; 
                             GetAsNumber (nums ) < 2360 ; 2 ; 
                             0
                           ) ; 
charTest = Case ( lgthC > 0 and lgthC < 3 ; 1 ; 0 ) ; 
mins = Case ( lgthN > 2 ; Right ( nums ; 2 ) ; "00" ) ; 
hrs = Case ( lgthN > 2 ; Middle ( nums ; 1 ; lgthN - 2 ) ; nums ) ; 
hrsN = GetAsNumber ( hrs ) ; 
minsTest = Case ( GetAsNumber ( mins ) > 59 ; 0 ; 1 ) ; 
hrs12 = Case ( numTest = 2 ; GetAsText ( hrsN - 12 ) ; 
                         hrsN = 0 ; "12" ; 
                         hrs
                      ) ; 
suffix = Case ( charTest = 1 and ( PatternCount ( chars ; "A" ) or Exact ( chars ; "M" ) ) ; " AM" ; 
                        charTest = 1 and ( PatternCount ( chars ; "P" ) or Exact ( chars ; "N" ) ) ; " PM" ; 
                        charTest = 0 and Exact ( Left ( nums ; 1 ) ; "0" ) ; " AM" ; 
                        numTest = 2 and hrsN > 12 ; " PM" ; 
                        "" 
                     ) ; 
hrsTest = Case ( GetAsNumber ( hrs12 ) > 12 ; 0 ; 1 ) ; 
suffixTest = Case ( hrsN > 12 and Exact ( suffix ; " AM" ) ; 0 ; 1 ) ; 
inter = GetAsNumber ( hrs12 & mins )
] ; 

 Case ( numTest = 0 ; "INVALID TIME" ; 
            minsTest = 0 ; "INVALID TIME" ; 
            hrsTest = 0 ; "INVALID TIME" ; 
            suffixTest = 0 ; "INVALID TIME" ; 
            inter > 0 and inter < 700 ; Left ( inter ; 1 ) & ":" & Right ( inter ; 2 ) & 
                        If ( not IsEmpty ( suffix ) ; suffix ; " PM" ) ; 
            inter >= 700 and inter < 1000 ; Left ( inter ; 1 ) & ":" & Right ( inter ; 2 ) &
                        If ( not IsEmpty ( suffix ) ; suffix ; " AM" ) ; 
            inter >= 1000 and inter < 1200 ; Left ( inter ; 2 ) & ":" & Right ( inter ; 2 ) & 
                        If ( not IsEmpty ( suffix ) ; suffix ; " AM" ) ; 
            inter >= 1200 and inter < 1260 ; Left ( inter ; 2 ) & ":" & Right ( inter ; 2 ) & 
                        If ( not IsEmpty ( suffix ) ; suffix ; " PM" ) ; 
            "INVALID TIME" 
        )
    )

This function parses and reformats time (hours and minutes) casually entered into a text field so that it can be converted to a valid time by Filemaker. It also includes tests so that, if an invalid time string is entered, it will return an error message instead of an invalid time. Further, it incorporates code from the TimeMask custom function written by Steve Gerow of Abrazos Data Consulting that logically assigns AM or PM to times entered without that data between 7am and 7pm. Many thanks to Steve, and to Brian Dunning.

Comments

		Lewis C. Lorenz, Tulsa, OK Dec 17, 2015
Adding the following as the first Case element at the end allows an empty time entry to pass FMP validation when this function returns its result directly into a FMP time field. Case ( isempty ( nums ) , "" , //Return the empty field so validation works. This is a great custom function!

		Ross Thompson, Rockford, IL Jul 11, 2016
Remove the first line of this, "ParseTime ( timeText )" from the calculation body.

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

ParseTime ( timeText )

Comments

Support this website.

Support this website.