areaCalcsByCoords ( xlist ; ylist )

Calculates the area within any shape defined by a series of coordinates.

Average rating: 3.8 (38 votes) Log in to vote

Bill Holt
Notesoft
http://www.notesoft.com

Sample input:

areaCalcsByCoords ( xlist ; ylist )

where: xlist = 12 24 32 15 12
and ylist = 0 14 29 5 0

Sample output:

40.5

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

//  areaCalcsByCoords ( xlist ; ylist )

// Calculates the area enclosed within any 2D shape that is defined by a set of coordinates.  The  
// coordinates must be in order, as if the perimeter were being traversed.

// This function anticipates a space delimited list for the x values and a separate one
// for the y values.  These are cleaned a bit and converted to return delimited lists.

// This is based on an old surveying method for calculating areas.  Took the class 35 yrs ago.

// Traversing in one direction calculates the area as a negative number, the other as a positive.
// Calculate the area of a perfectly balanced figure 8 as written and the answer is zero.  Plus 
// something for the top half, minus something for the bottom.  To get the true answer your coordinate 
// list would taverse the figure without crossing at the center.

// Prerequisites:  none

// ************************

// set first pair of xy values to the first two pairs of list values
//  xt1;xt2;yt1;yt2h

Let ( $count = $count + 1 ;

        Case ( 

// first time through, first Case test

                $count = 1 ;  

                Let ( [ 
                
        // Converting space delimited list to return delimited, with some clean up.
        
                $xValList = Substitute ( xlist ; "     " ; " " ) ;
                $xValList = Substitute ( $xValList ; "    " ; " " ) ;
                $xValList = Substitute ( $xValList ; "   " ; " " ) ;
                $xValList = Substitute ( $xValList ; "  " ; " " ) ;
                $xValList = Substitute ( $xValList ; "- " ; "-" ) ;
                $xValList = Substitute ( $xValList ; " " ; "¶" ) ;


                $yValList = Substitute ( ylist ; "     " ; " " ) ;
                $yValList = Substitute ( $yValList ; "    " ; " " ) ;
                $yValList = Substitute ( $yValList ; "   " ; " " ) ;
                $yValList = Substitute ( $yValList ; "  " ; " " ) ;
                $yValList = Substitute ( $yValList ; "- " ; "-" ) ;
                $yValList = Substitute ( $yValList ; " " ; "¶" ) ;
        
        // Initializing area value

                $area = 0 ];
                
        // And now we're off to the races.

                areaCalcsByCoords ( $xValList ; $yValList )   ) ;  

//   end of actions when the first Case test is true



// The final Case test - for when we're ready to spit out the answer.

                ValueCount ( $xValList ) < 2 ; 

                        Let ( $count = 0 ; $area / 2 ) ;   
                        
        // It's the $area/2 value that is returned
    
// end of final action ... done when the final/second case test is true



// This is where the looping happens ... it's the default for the Case statement
// This is performed repeatedly, until the perimeter of the shape has been traversed.

                Let ( [
                        xt1 = GetAsNumber ( MiddleValues ( $xValList ; 1 ; 1 ) ) ;
                        yt1 = GetAsNumber ( MiddleValues ( $yValList ; 1 ; 1 ) ) ;
                        xt2 = GetAsNumber ( MiddleValues ( $xValList ; 2 ; 1 ) ) ;
                        yt2 = GetAsNumber ( MiddleValues ( $yValList ; 2 ; 1 ) ) ;

// calculate the partial double-area and sum

                        $area = $area + xt1*yt2 - xt2*yt1 ; 

// trim the lists for the next run-though (if required)

                        $xValList = RightValues ( $xValList ; ValueCount ( $xValList ) - 1 ) ;

                        $yValList = RightValues ( $yValList ; ValueCount ( $yValList ) - 1 )   ] ;

// the return value for the current Let statement

                        areaCalcsByCoords ( $xValList; $yValList )    )   
                )

        )

This function returns the area within any shape defined by X and Y coordinate lists. Another custom function is listed on this site which uses the same math technique. I'm sharing this one to demonstrate a technique I find useful. By breaking the logic into three parts - initial, final and repetitive - a CF can be used to emulate a looping behavior, much like you can do with a language like Fortran. Multiple branches can be developed which allow the CF to tackle very complex issues.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

areaCalcsByCoords ( xlist ; ylist )

Comments

Support this website.

Support this website.