TriggersDisable

Sets global variables to indicate that the current script is suppressing triggers.

Average rating: 4.5 (32 votes) Log in to vote

Jeremy Bante

https://github.com/jbante/

Sample input:

TriggersDisable

Sample output:

1 //True, meaning that the current script is now suppressing triggers

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/**
 * =====================================
 * TriggersDisable
 * https://github.com/jbante/FileMaker-Techniques/blob/master/CustomFunctions/Triggers/TriggersDisable.fmfn
 *
 * PURPOSE:
 *		TriggersDisable sets global variables to indicate that the current
 *		script is suppressing triggers. This script must be called from the
 *		context of a script; otherwise, it will not suppress triggers, and it
 *		will return False. In order to be suppressed, a script called via
 *		trigger should use the TriggersAreActive function to decide whether or
 *		not to run.
 *
 * RETURNS:
 *		True (1) if called from the context of a script, and therefore triggers
 *		have been suppressed; False (0) otherwise.
 *
 * PARAMETERS: none
 *
 * REFERENCED VARIABLES:
 *		$$~TRIGGERS_DISABLE
 *		$$~TRIGGERS_SCRIPTS
 *		$~triggers_disableKey
 *
 * DEPENDENCIES: none
 *
 * EXAMPLE (script):
 *		Set Variable [$!; Value:TriggersDisable]
 *			# Do something
 *		Set Variable [$!; Value:TriggersEnable]
 *
 * NOTES:
 *		This function should *always* be used in pairs with the TriggersEnable
 *		function.
 *
 * HISTORY:
 *		MODIFIED on 2013-03-25 by Jeremy Bante <http://scr.im/jbante> to be more
 *		robust to certain programming errors.
 *		MODIFIED on 2011-02-09 by Jeremy Bante <http://scr.im/jbante> to use
 *		differently-named variables.
 * 		MODIFIED on 2010-12-13 by Jeremy Bante <http://scr.im/jbante> to use
 *		names suggested at filemakerstandards.org.
 *		CREATED on 2010-12-12 by Jeremy Bante <http://scr.im/jbante>.
 *
 * REFERENCES:
 *		Supressible Triggered Scripts Best Practice: http://filemakerstandards.org/display/bp/Suppressible+Triggered+Scripts
 * =====================================
 */

Let ( [
	~scriptName			= Get ( ScriptName ) ;
	~scriptIsRunning	= not IsEmpty ( Get ( ScriptName ) ) ;
	~disableIsRunning	= not IsEmpty ( $~triggers_disableKey ) ;
	$~triggers_disableKey =
		Case (
			~disableIsRunning	; $~triggers_disableKey ;
			~scriptIsRunning	; Get ( UUID )
		) ;
	$$~TRIGGERS_SCRIPTS =
		If ( ~scriptIsRunning and not ~disableIsRunning ;
			~scriptName
			& Char ( 9 )	// tab
			& $~triggers_disableKey
			& ¶
			& $$~TRIGGERS_SCRIPTS ;
		/* Else */
			$$~TRIGGERS_SCRIPTS
		) ;
	$$~TRIGGERS_DISABLE =
		If ( ~scriptIsRunning ; True ; /* Else */ $$~TRIGGERS_DISABLE )
] ;
	~scriptIsRunning
)

TriggersDisable sets global variables to indicate that the current script is suppressing triggers. This script must be called from the context of a script; otherwise, it will not suppress triggers, and it will return False. In order to be suppressed, a script called via trigger should use the TriggersAreActive function to decide whether or not to run.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

TriggersDisable

Comments

Support this website.

Support this website.