TriggersEnable

Sets global variables to indicate that the current script is no longer suppressing triggers

Average rating: 4.4 (37 votes) Log in to vote

Jeremy Bante

https://github.com/jbante/

Sample input:

TriggersEnable

Sample output:

1 //True, meaning that the current script is no longer suppressing triggers

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/**
 * =====================================
 * TriggersEnable
 * https://github.com/jbante/FileMaker-Techniques/blob/master/CustomFunctions/Triggers/TriggersEnable.fmfn
 *
 * PURPOSE:
 *		TriggersEnable sets global variables to indicate that the current script
 *		is no longer suppressing triggers. This function will also turn off
 *		trigger suppression altogether if there are no other scripts suppressing
 *		triggers. In order to be suppressed, a script called via trigger should
 *		use the TriggersAreActive function to decide whether or not to run.
 *
 * RETURNS:
 *		True (1) if TriggersEnable successfully removed the current script from
 *		the list of scripts suppressing triggers; False (0) otherwise.
 *
 * PARAMETERS: none
 *
 * REFERENCED VARIABLES:
 *		$$~TRIGGERS_DISABLE
 *		$$~TRIGGERS_SCRIPTS
 *		$~triggers_disableKey
 *
 * DEPENDENCIES: none
 *
 * EXAMPLE (script):
 *		Set Variable [$!; Value:TriggersDisable]
 *		# Do something
 *		Set Variable [$!; Value:TriggersEnable]
 *
 * NOTES:
 *		This function should *always* be used in pairs with the TriggersDisable
 *		function.
 *
 * HISTORY:
 *		MODIFIED on 2013-03-25 by Jeremy Bante <http://scr.im/jbante> to be more
 *		robust to certain programming errors.
 *		MODIFIED on 2011-02-09 by Jeremy Bante <http://scr.im/jbante> to use
 *		differently-named variables.
 *		MODIFIED on 2010-12-13 by Jeremy Bante <http://scr.im/jbante> to use
 *		names suggested at FileMakerStandards.org.
 *		CREATED on 2010-12-12 by Jeremy Bante <http://scr.im/jbante>.
 *
 * REFERENCES:
 *		Supressible Triggered Scripts Best Practice: http://filemakerstandards.org/display/bp/Suppressible+Triggered+Scripts
 * =====================================
 */

If ( not IsEmpty ( $~triggers_disableKey ) ;
	Let ( [
		~scriptsLength = Length ( $$~TRIGGERS_SCRIPTS ) ;
		~scriptPosition =
			Position (
				$$~TRIGGERS_SCRIPTS ;
				Char ( 9 ) /* tab */ & $~triggers_disableKey & ¶ ;
				~scriptsLength ;
				-1
			) ;
		~breakPosition =
			If ( ~scriptPosition > 0 ;
				Position ( $$~TRIGGERS_SCRIPTS ; ¶ ; ~scriptPosition ; 1 ) ;
				/* Else */ 0
			) ;
		$$~TRIGGERS_SCRIPTS =
			Right ( $$~TRIGGERS_SCRIPTS ; ~scriptsLength - ~breakPosition ) ;
		$$~TRIGGERS_DISABLE =
			If ( not IsEmpty ( $$~TRIGGERS_SCRIPTS ) and $$~TRIGGERS_DISABLE ;
				True ;
				/* Else */ ""
			) ;
		$~triggers_disableKey = ""
	] ;
		""
	)
)

TriggersEnable sets global variables to indicate that the current script is no longer suppressing triggers. This function will also turn off trigger suppression altogether if there are no other scripts suppressing triggers. In order to be suppressed, a script called via trigger should use the TriggersAreActive function to decide whether or not to run.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

TriggersEnable

Comments

Support this website.

Support this website.