UUIDFromRFC4122 ( rfc4122 )

Converts a hex RFC 4122 UUID to a decimal format

Average rating: 4.5 (36 votes) Log in to vote

Jeremy Bante

https://github.com/jbante/

Sample input:

1a7024bf-2f24-11e0-89ac-00264a0d4b42

Sample output:

12063432286093000006302476000164451142466

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/**
 * ======================================
 * UUIDFromRFC4122 ( rfc4122 )
 *		https://github.com/jbante/FileMaker-Techniques/blob/master/CustomFunctions/UUID/UUIDGetAsUUID.fmfn
 *
 * PURPOSE:
 *		Converts a UUID in the canonical RFC 4122 hexadecimal format to a
 *		numeric format with better performance characteristics as a primary key
 *		in FileMaker records.
 *
 * RETURNS:
 *		A 41-digit delimited number of the form:
 *		v-r-mmmmmmmmmmmmTsssssss-ccccc@nnnnnnnnnnnnnnn
 *		With version 1 and 2 UUIDs, the sections of the UUID correspond to:
 *		v: The UUID version (type) number
 *		r: A variant code reserved by the RFC 4122 standard
 *		m: The creation timestamp (seconds since 0001-01-01T00:00:00)
 *		s: The sub-second portion of the original UUID's timestamp
 *		c: The "clock sequence"
 *		n: The NIC address ("node") of the device that created the UUID
 *
 * PARAMETERS:
 *		rfc4122: The hexadecimal UUID to convert
 *
 * DEPENDENCIES: none
 *
 * HISTORY:
 *		CREATED on 2011-02-02 by Jeremy Bante <http://scr.im/jbante>.
 *
 * REFERENCES:
 *		Key values Best Practice: http://filemakerstandards.org/pages/viewpage.action?pageId=557138
 *		RFC 4122 UUID standard specification: http://tools.ietf.org/html/rfc4122
 *		UUID functions: https://github.com/jbante/FileMaker-Techniques/tree/master/CustomFunctions/UUID
 * ======================================
 */
Case (
	/*Set-up conversion from base 16 to base 10*/
	not $~uuid.step ;
		Let ( [
			$~uuid.step = 1
		] ;
			UUIDFromRFC4122 (
				Right ( Filter ( Lower ( rfc4122 ) ; "0123456789abcdef" ) ; 32 )
			)
		) ;

	/*Convert to base 10*/
	$~uuid.step = 1 ;
		Let ( [
			$~uuid.i = $~uuid.i + 1 ;
			~hexDigit = Middle ( rfc4122 ; $~uuid.i ; 1 ) ;
			$~uuid.decimal =
				$~uuid.decimal * 16
				+ Position ( "0123456789abcdef" ; ~hexDigit ; 1 ; 1 )
				- 1 ;
			$~uuid.step =
				If ( $~uuid.i < 32 ; $~uuid.step ; /*else*/ $~uuid.step + 1 )
		] ;
			UUIDFromRFC4122 ( rfc4122 )
		) ;

	/*Format and return result*/
	$~uuid.step = 2 ;
		Let ( [
			//extract RFC 4122 components
			~node = Mod ( $~uuid.decimal ; 2^48 ) ;
			~clock_seq_and_reserved = Mod ( Div ( $~uuid.decimal ; 2^48 ) ; 2^16 ) ;
			~reserved =
				Case (
					~clock_seq_and_reserved < 2^15 ; 0 ;
					~clock_seq_and_reserved < 2^15 + 2^14 ; 2 ;
					~clock_seq_and_reserved < 2^15 + 2^14 + 2^13 ; 6 ;
					/*else*/ 7
				);
			~clock_seq =
				Case (
					~reserved = 0 ; ~clock_seq_and_reserved ;
					~reserved = 2 ; Mod ( ~clock_seq_and_reserved ; 2^14 ) ;
					~reserved ≥ 6 ; Mod ( ~clock_seq_and_reserved ; 2^13 ) ;
				) ;
			~time_hi_and_version = Mod ( Div ( $~uuid.decimal ; 2^64 ) ; 2^16 ) ;
			~time_hi = Mod ( ~time_hi_and_version ; 2^12 ) ;
			~version = Div ( ~time_hi_and_version ; 2^12 ) ;
			~time_mid = Mod ( Div ( $~uuid.decimal ; 2^80 ) ; 2^16 ) ;
			~time_low = Mod ( Div ( $~uuid.decimal ; 2^96 ) ; 2^32 ) ;

			//convert to FileMaker-centric format
			~timestamp =
				~time_hi * 2^48
				+ ~time_mid * 2^32
				+ ~time_low ;
			~serialNumber = Right ( ~timestamp ; 7 ) ;
			// move epoch from 0001-01-01T00:00:00 to 1582-10-15T00:00:00
			~timestamp = Div ( ~timestamp ; 10000000 ) + 49916304000 ;

			//purge variables
			$~uuid.decimal = "" ;
			$~uuid.i = "" ;
			$~uuid.step = ""
		] ;
			//format result
			~version
			// & "-"
			& ~reserved
			// & "-"
			& Right ( "000000000000" & ~timestamp ; 12 )
			// & "-"
			& Right ( "0000000" & ~serialNumber ; 7 )
			// & "-"
			& Right ( "00000" & ~clock_seq ; 5 )
			// & "-"
			& Right ( "000000000000000" & ~node ; 15 )
		)
)

Converts a UUID in the canonical RFC 4122 hexadecimal format to a numeric format with better performance characteristics as a primary key in FileMaker records.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

UUIDFromRFC4122 ( rfc4122 )

Comments

Support this website.

Support this website.