AS_Dialog ( Text ; Button1 ; Button2 ; Button3 ; window_title ; giving_up_after ; default_answer ; hidden_answer ; default_button ; cancel_button ; caution ; result_field )

Generates an dialog box with a number of options

Average rating: 4.0 (43 votes) Log in to vote

Thomas Siebert - Show more from this author
http://www.t-seabird.de

Sample input:

Perform AppleScript [ AS_Dialog ( "Are you there?" ; "yes" ; "" ; "" ; "check" ; 3 ; "" ; 0 ; 1 ; 0 ; 0 ; table::field ) ]

Sample output:

The dialog closes after 3 seconds or by hitting yes returning the choice to a FileMaker Field

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*
AS_Dialog ( Text ; Button1 ; Button2 ; Button3 ; window_title ; giving_up_after ; default_answer ; hidden_answer ; default_button ; cancel_button ; caution ; result_field )

version 14
---------------------------------------------
Thomas Siebert, 08.11.2011
info@t-seabird.de
www.t-seabird.de
---------------------------------------------
Text = The dialog text
Button1 Button2 Button3 = Button-names. up to 3 Buttons possible. Leave those parameters empty to get standard buttons (OK and Cancel)
window_title = name of the window title bar
giving_up_after = timeout in seconds (empty or 0 means: no timeout) to wait before automatically dismissing the dialog
default_answer = generates an field entry with an default text if you want to. Empty parameter means: no entry field.
hidden_answer = enter 1 for bullets (••••••)
default_button = enter a number for the default button (empty or 0 means: no default button)
cancel_button = the number of the cancel button
caution = enter 1, 2 or 3 to get icon (stop/note/caution)
result_field = A FileMaker-Field to return a result


Die CF wird über den Scriptschritt "AppleScript ausführen" mit der Option "Berechnetes Script" genutzt.
"AppleScript ausführen" steht auch direkt in den Tastenkommandos zur Verfügung.

Use the ScriptStep "Perform AppleScript" using the option "Calculated AppleScript"
You also shall use "Perform AppleScript" directly from a button.


*/

Let ([ 
FMP = Case ( RightWords ( Get ( FileMakerPath ) ; 1 ) = "Advanced" ; "FileMaker Pro Advanced" ; "FileMaker Pro" ) ;

result_field = Substitute ( GetFieldName ( result_field ) ; "::" ; ¶ ) ;
Cell_Result = Substitute ( RightValues ( result_field ; 1 ) ; ¶ ; "" ) ;
Table_Result = Substitute ( LeftValues ( result_field ; 1 ) ; ¶ ; "" ) ;

my_dialog = "\"" & Substitute ( Text ; "¶" ; "\r" ) & "\"" ;
buttons = Case ( not IsEmpty ( Button1 ) or not IsEmpty ( Button2 ) or not IsEmpty ( Button3 ) ; " buttons {\"" & 
Substitute (  
Case ( not IsEmpty ( Button1 ) ; Button1 & ¶ ) & 
Case ( not IsEmpty ( Button2 ) ; ¶ & Button2 & ¶ ) & 
Case ( not IsEmpty ( Button3 ) ; ¶ & Button3 ) 
; [ "¶¶" ; "\", \"" ] ; [ ¶ ; "" ] ) & 
"\"}" ) ;
window_title = Case ( not IsEmpty ( window_title ) ; " with title \"" & window_title & "\"" ) ;
giving_up_after = Case ( giving_up_after > 0 ; " giving up after " & giving_up_after ) ;
default_answer = Case ( not IsEmpty ( default_answer ) ; " default answer \"" & default_answer & "\"" ) ;
hidden_answer = Case ( ( not IsEmpty ( hidden_answer ) ) and ( hidden_answer > 0 ) ; " hidden answer " & hidden_answer ) ;
default_button = Case ( ( not IsEmpty ( default_button ) ) and ( default_button > 0 ) ; " default button " & default_button ) ;
cancel_button = Case ( ( not IsEmpty ( cancel_button ) ) and ( cancel_button > 0 ) ; " cancel button " & cancel_button ) ;
caution = Choose ( caution ; "" ; " with icon stop " ; " with icon note " ; " with icon caution " )
 ];

"set myResult to missing value
¶set FMP_Result_Field to missing value
¶set FMP_DB to \"" & Get ( FileName ) & "\"
¶
¶--tell application \"" & FMP & "\"
¶	set FMP_ID_CurrentRec to the ID of current record of database FMP_DB
¶--end tell
¶
¶set myResult to display dialog " & my_dialog & buttons & window_title & giving_up_after & default_answer & hidden_answer & default_button & cancel_button & caution & "
¶
¶set AppleScript's text item delimiters to \"\\\", \\\"\"
¶set the item_list to every text item of myResult
¶set AppleScript's text item delimiters to return
¶set myResult to the item_list as string
¶
¶--tell application \"" & FMP & "\"
¶	save record id FMP_ID_CurrentRec of table \"" & Table_Result & "\" of database FMP_DB
¶	set cell \"" & Cell_Result & "\" of record id FMP_ID_CurrentRec of table \"" & Table_Result & "\" of database FMP_DB to myResult
¶--end tell
¶"

)

Text = The dialog text
Button1 Button2 Button3 = Button-names. up to 3 Buttons possible. Leave those parameters empty to get standard buttons (OK and Cancel)
window_title = name of the window title bar
giving_up_after = timeout in seconds (empty or 0 means: no timeout) to wait before automatically dismissing the dialog
default_answer = generates an field entry with an default text if you want to. Empty parameter means: no entry field.
hidden_answer = enter 1 for bullets (••••••)
default_button = enter a number for the default button (empty or 0 means: no default button)
cancel_button = the number of the cancel button
caution = enter 1, 2 or 3 to get icon (stop/note/caution)
FMP_Result_Field = A FileMaker-Field to return a result

Use the ScriptStep "Perform AppleScript" using the option "Calculated AppleScript"
You also shall use "Perform AppleScript" directly from a button.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

AS_Dialog ( Text ; Button1 ; Button2 ; Button3 ; window_title ; giving_up_after ; default_answer ; hidden_answer ; default_button ; cancel_button ; caution ; result_field )

Comments

Support this website.

Support this website.