ValidaRFC ( RFC , País )

SOLO PARA MEXICO: Valida el RFC de una empresa

Average rating: 4.3 (31 votes) Log in to vote

Ibrahim Bittar Torres - Show more from this author
Eikonsys, S.A. de C.V.
http://www.eikonsys.com

Sample input:

ValidaRFC ( "EIK-100209-S16 , "México" )
ValidaRFC ( "XEXX010101000" , "USA" )
ValidaRFC ( "EIK-100009-S16 , "México" )
ValidaRFC ( "EIK-100239-S16 , "México" )

Sample output:

1
1
0
0

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

//Función: ValidaRFC
//Parámetros: RFC y País
//Creada por: Ibrahim Bittar - Eikonsys
//Fecha: 02/06/2011
//Copyright © 2011 - Ibrahim Bittar Torres. Todos los derechos reservados.
//Usa esta función libremente, nada más respeta los derechos de autor.


Let ( [ RFC_Clear = Filter ( Upper ( RFC ) ; "0123456789QWERTYUIOPASDFGHJKLÑZXCVBNM&$%#@§" ) ; 
        Iniciales= If ( Length ( RFC_Clear ) = 12 ; Left ( RFC_Clear ; 3 ) ; Left ( RFC_Clear ; 4 ) ) ; 
        Año = Left ( Substitute ( RFC_Clear ; Iniciales ; "" ) ; 2 ) ; 
        Mes = Middle ( Substitute ( RFC_Clear ; Iniciales ; "" ) ; 3 ; 2 ) ;
        Día = Middle ( Substitute ( RFC_Clear ; Iniciales ; "" ) ; 5 ; 2 ) ;
        Homoclave = Substitute ( RFC_Clear ; Iniciales & Año & Mes & Día ; "" ) ] ; 

//Aquí vamos validando parte por parte si la cosa va bien o no

//Si el cliente es extranjero el RFC debe ser XEXX010101000, de lo contrario pone 0

Case ( Substitute ( Lower ( País ) ; [ "é" ; "e" ] ; [ "í" ; "i" ] ; [ "ó" ; "o" ] ) ≠ "mexico" and RFC_Clear = "XEXX010101000" ; 1 & Let ( $Exit = 1 ; $Exit ) ; 
       Substitute ( Lower ( País ) ; [ "é" ; "e" ] ; [ "í" ; "i" ] ; [ "ó" ; "o" ] ) = "mexico" and RFC_Clear ≠ "XEXX010101000" ; 1 & Let ( $Exit = 0 ; $Exit ) ; 0 ) and

//Si el RFC tiene 12 caracteres las iniciales tienen 3 caracteres, si tiene 13 caracteres entonces tiene 4, de lo contrario pone 0
 
Case ( Length ( RFC_Clear ) = 12 ; Length ( Iniciales ) = 3 or $Exit ; 
       Length ( RFC_Clear ) = 13 ; Length ( Iniciales ) = 4 or $Exit ; 0 ) and

//Las iniciales no pueden tener números, de lo contrario pone 0
 
If ( IsEmpty ( Filter ( Iniciales ; "0123456789" ) ) or $Exit ; 1 ; 0 ) and

//El mes tiene que estar entre 1 y 12, de lo contrario pone 0

If ( ( GetAsNumber ( Mes ) ≥ 1 and GetAsNumber ( Mes ) ≤ 12 ) or $Exit ; 1 ; 0 ) and

//El día tiene que estar entre 1 y 28, 30 o 31, dependiendo del mes. De lo contrario pone 0

Case ( GetAsNumber ( Mes ) = 2 ; ( GetAsNumber ( Día ) ≥ 1 and GetAsNumber ( Día ) ≤ 29 ) or $Exit ;
       GetAsNumber ( Mes ) = 1 or GetAsNumber ( Mes ) = 3 or GetAsNumber ( Mes ) = 5 or GetAsNumber ( Mes ) = 7 or
       GetAsNumber ( Mes ) = 8 or GetAsNumber ( Mes ) = 10 or GetAsNumber ( Mes ) = 12 ; ( GetAsNumber ( Día ) ≥ 1 and GetAsNumber ( Día ) ≤ 31 ) or $Exit ;
       GetAsNumber ( Mes ) = 4 or GetAsNumber ( Mes ) = 6 or GetAsNumber ( Mes ) = 9 or GetAsNumber ( Mes ) = 11 ; ( GetAsNumber ( Día ) ≥ 1 and GetAsNumber ( Día ) ≤ 30 ) or $Exit ; 0 ) and

//La homoclave tiene que tener tres dígitos

If ( Length ( Homoclave ) = 3 or $Exit ; 1 ; 0 )

) //End let

This function is intended for mexican users only so I'll give the explanation in spanish. If you need this function in english please contact me offline.
-----------------------------
Esta función valida el RFC de cualquier empresa. Las validaciones que hace son las siguientes:

1.- Si la empresa es extranjera el RFC debe ser XEXX010101000.
2.- El RFC debe tener 12 caracteres para empresas y 13 para personas.
3.- Si el RFC es de empresa, las iniciales deben tener 3 caracteres.
4.- Si el RFC es de persona, las iniciales deben tener 4 caracteres.
5.- Las iniciales del RFC no deben tener números.
6.- El mes de fundación debe estar entre 1 y 12.
7.- El día de fundación debe cumplir el siguiente criterio:
7.1.- Si el mes es febrero (02), el día debe estar entre 1 y 29.
7.2.- Si el mes es enero (01), marzo (03), mayo (05), julio (07), agosto (08), octubre (10) o diciembre (12), el día debe estar entre 1 y 31.
7.3.- Si el mes es abril (04), junio (06), septiembre (09) o noviembre (11), el día debe estar entre 1 y 30.
8.- La homoclave debe tener tres caracteres que pueden ser letras o números.

Si alguien sabe cómo se calcula la homoclave por favor póngase en contacto conmigo para añadir esa parte del algoritmo y así la función sea completa.

Saludos

Ibrahim Bittar
Eikonsys

Comments

		Daniel Velazquez, mexico Jan 30, 2018
Los primeros dos caracteres de la homoclave deben ser nÃºmeros o letras y el tercer carÃ¡cter es un dÃgito verificador que puede valer entre 0 y 9 o A. Este es un enlace en donde explican el calculo del dÃgito verificador. https://es.stackoverflow.com/questions/31713/cÃ³mo-validar-un-rfc-de-mÃ©xico-y-su-digito-verificador

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

ValidaRFC ( RFC , País )

Comments

Support this website.

Support this website.