DistanceList ( BaseLat ; BaseLong ; ListOfLatLongIdentifiers ; Delimiter ; Units ; SortableDistance )

Prefixes a Value List containing Latitude, Longitude, and an Identifier with the Distance to the Base Lat, Long

Average rating: 4.4 (32 votes) Log in to vote

Hal Gumbert - Show more from this author
CampSoftware
http://www.campsoftware.com

Sample input:

ValuesSort ( DistanceList ( "28.5413" ; "-81.3733" ; "28.5418|-81.3736|18TKD5YISDJA3FWUOVICTDD¶27.9826|-82.3401|18TKD5YISDJA3FWVYTBRV77¶30.2738|-81.7634|18TKD5YISDJA3FWX8R56X10¶30.1608|-85.6475|18TKD5YISDJA3FWYIOYLYUW¶25.8324|-80.2789|18TKD5YISDJA3FWZSMS10OP¶26.6175|-81.8713|18TKD5YISDJA3FX12KLG2II" ; "|" ; "miles" ; 1 ) ; "asc" ; "text" )

Sample output:

00000000000000000000.0390254131982271|28.5418|-81.3736|18TKD5YISDJA3FWUOVICTDD
00000000000000000070.3216154385589278|27.9826|-82.3401|18TKD5YISDJA3FWVYTBRV77
00000000000000000121.9027848952389432|30.2738|-81.7634|18TKD5YISDJA3FWX8R56X10
00000000000000000136.2833063513182311|26.6175|-81.8713|18TKD5YISDJA3FX12KLG2II
00000000000000000198.74801761385407|25.8324|-80.2789|18TKD5YISDJA3FWZSMS10OP
00000000000000000280.4610538634018474|30.1608|-85.6475|18TKD5YISDJA3FWYIOYLYUW

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*
DistanceList ( BaseLat ; BaseLong ; ListOfLatLongIdentifiers ; Delimiter ; Units ; SortableDistance )

By Hal Gumbert, CampSoftware.com

BaseLat: The base Latitude to Compare against.
BaseLong: The base Longitude to Compare against.
ListOfLatLongIdentifiers: The list of values containing a Latitude, Longitude, and any identifying text separated by a Delimiter.
Delimiter: The character(s) used to seperate values in the list.
Units: Accepts "radians", "nm", "km" and "miles".
SortableDistance = Accepts 1 or 0. Passing 1 will prefix the integer portion of the distance with zeros so the list values can be sorted with another custom function.

Requires: Distance ( Lat1 ; Lon1 ; Lat2 ; Lon2 ; Units ) from Vaughan Bromfield, Vaughan Bromfield Design available at http://www.briandunning.com/cf/143

==========================
Example 1

ValuesSort ( DistanceList ( "28.5413" ; "-81.3733" ; "28.5418|-81.3736|18TKD5YISDJA3FWUOVICTDD¶27.9826|-82.3401|18TKD5YISDJA3FWVYTBRV77¶30.2738|-81.7634|18TKD5YISDJA3FWX8R56X10¶30.1608|-85.6475|18TKD5YISDJA3FWYIOYLYUW¶25.8324|-80.2789|18TKD5YISDJA3FWZSMS10OP¶26.6175|-81.8713|18TKD5YISDJA3FX12KLG2II" ; "|" ; "miles" ; 1 ) ; "asc" ; "text" )

00000000000000000000.0390254131982271|28.5418|-81.3736|18TKD5YISDJA3FWUOVICTDD
00000000000000000070.3216154385589278|27.9826|-82.3401|18TKD5YISDJA3FWVYTBRV77
00000000000000000121.9027848952389432|30.2738|-81.7634|18TKD5YISDJA3FWX8R56X10
00000000000000000136.2833063513182311|26.6175|-81.8713|18TKD5YISDJA3FX12KLG2II
00000000000000000198.74801761385407|25.8324|-80.2789|18TKD5YISDJA3FWZSMS10OP
00000000000000000280.4610538634018474|30.1608|-85.6475|18TKD5YISDJA3FWYIOYLYUW
==========================
Example 2

ValuesSort ( DistanceList ( "28.5413" ; "-81.3733" ; "28.5418|-81.3736|18TKD5YISDJA3FWUOVICTDD¶27.9826|-82.3401|18TKD5YISDJA3FWVYTBRV77¶30.2738|-81.7634|18TKD5YISDJA3FWX8R56X10¶30.1608|-85.6475|18TKD5YISDJA3FWYIOYLYUW¶25.8324|-80.2789|18TKD5YISDJA3FWZSMS10OP¶26.6175|-81.8713|18TKD5YISDJA3FX12KLG2II" ; "|" ; "miles" ; 0 ) ; "asc" ; "text" )

.0390254131982271|28.5418|-81.3736|18TKD5YISDJA3FWUOVICTDD
121.9027848952389432|30.2738|-81.7634|18TKD5YISDJA3FWX8R56X10
136.2833063513182311|26.6175|-81.8713|18TKD5YISDJA3FX12KLG2II
198.74801761385407|25.8324|-80.2789|18TKD5YISDJA3FWZSMS10OP
280.4610538634018474|30.1608|-85.6475|18TKD5YISDJA3FWYIOYLYUW
70.3216154385589278|27.9826|-82.3401|18TKD5YISDJA3FWVYTBRV77
==========================

*/

Let ( [

// Get the ListCount
theListCount = ValueCount ( ListOfLatLongIdentifiers ) ; 

// Get the Lat Long for the Last Item in the List
theLastListValue = If ( theListCount > 0 ; GetValue ( ListOfLatLongIdentifiers ; theListCount ) ; "" ) ;
theLastListValueAsValues = Substitute ( theLastListValue ; Delimiter ; "¶" ) ;
theLatPosition = 1 ;
theLongPosition = 2 ;
theLastListValueLat = GetValue ( theLastListValueAsValues ; theLatPosition ) ;
theLastListValueLong = GetValue ( theLastListValueAsValues ; theLongPosition ) ;

// Get the Distance for the Last Items in the List
theLastListValueDistance = Distance ( BaseLat ; BaseLong ; theLastListValueLat ; theLastListValueLong ; Units ) ;

// Prefix the Integer portion of the Distance with Zeros to make the list sortable.
theLastListValueDistancePadded = Right ( "000000000000000000000000000000" & Int ( theLastListValueDistance ) ; 20 ) & ( theLastListValueDistance - Int ( theLastListValueDistance ) ) ;
theLastListValueDistance = If ( SortableDistance ; theLastListValueDistancePadded ; theLastListValueDistance ) ;


// Update the ListValue with the Distance. Distance is prefixed to make sorting by distance easy.
theLastListValueUpdated = theLastListValueDistance & Delimiter & theLastListValue ;

// Store the Results in a Global Variable so we don't need to pass another parameter.
$$DistanceListResult = If ( ValueCount ( $$DistanceListResult ) = 0 ; theLastListValueUpdated ; $$DistanceListResult & "¶" & theLastListValueUpdated ) ;


// If we are done, store the Global variable in a Local variable and destroy the Global variable.
DistanceListResult = If ( theListCount ≤ 1 ; $$DistanceListResult ; "" ) ;
$$DistanceListResult = If ( theListCount ≤ 1 ; "" ; $$DistanceListResult )


] ; 


// If we are done, return the List with Distances, otherwise work on the remaining list.
If ( theListCount ≤ 1 ; DistanceListResult ; DistanceList ( BaseLat ; BaseLong ; LeftValues ( ListOfLatLongIdentifiers ; theListCount - 1 ) ; Delimiter ; Units ; SortableDistance ) )

)

DistanceList ( BaseLat ; BaseLong ; ListOfLatLongIdentifiers ; Delimiter ; Units ; SortableDistance )

By Hal Gumbert, CampSoftware.com

BaseLat: The base Latitude to Compare against.
BaseLong: The base Longitude to Compare against.
ListOfLatLongIdentifiers: The list of values containing a Latitude, Longitude, and any identifying text separated by a Delimiter.
Delimiter: The character(s) used to seperate values in the list.
Units: Accepts "radians", "nm", "km" and "miles".
SortableDistance = Accepts 1 or 0. Passing 1 will prefix the integer portion of the distance with zeros so the list values can be sorted with another custom function.

Requires: Distance ( Lat1 ; Lon1 ; Lat2 ; Lon2 ; Units ) from Vaughan Bromfield, Vaughan Bromfield Design available at http://www.briandunning.com/cf/143

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

DistanceList ( BaseLat ; BaseLong ; ListOfLatLongIdentifiers ; Delimiter ; Units ; SortableDistance )

Comments

Support this website.

Support this website.