RandomPoisson ( mean )

Returns random values from a Poisson distribution

Average rating: 4.6 (30 votes) Log in to vote

Jeremy Bante

https://github.com/jbante/

Sample input:

List (
RandomPoisson ( 10 );
RandomPoisson ( 10 );
RandomPoisson ( 10 );
RandomPoisson ( 10 );
RandomPoisson ( 10 );
RandomPoisson ( 10 );
RandomPoisson ( 10 );
RandomPoisson ( 10 );
RandomPoisson ( 10 );
RandomPoisson ( 10 )
)

Sample output:

8
9
6
13
12
15
9
6
6
11

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/**
 * =====================================
 * RandomPoisson ( mean )
 *
 * PURPOSE:
 *		When called repeatedly with the same input, RandomPoisson returns values
 *		that are Poisson distributed with mean given by the function argument.
 *		This function uses the inverse transform method to generate values.
 *
 * RETURNS:
 *		A number (integer)
 *
 * PARAMETERS:
 *		mean: The average (mean) of the distribution to generate values from.
 *		mean must be > 0
 *
 * DEPENDENCIES: none
 *
 * HISTORY:
 *		CREATED on 2011-05-15 by Jeremy Bante <http://scr.im/jbante>.
 *
 * REFERENCES:
 *		http://en.wikipedia.org/wiki/Poisson_distribution
 * =====================================
 */

Case (
	/* Step 0: initialize process */
	not $~step;
	Let ( [
		$~random = Random;

		$~i = 0;
		$~probability = exp ( 0 - mean );
		$~cumulativeProbability = $~probability;

		$~step =
			Case (
				mean ≤ 0 ; 2;	// value is out of bounds, skip to end
				$~random < $~cumulativeProbability ; 2;	// result is found
				/* Else */ $~step + 1
			)
	];
		RandomPoisson ( mean )
	);

	/* Step 1: find cumulative probability to match random value */
	$~step = 1;
	Let ( [
		$~i = $~i + 1;
		$~probability = mean * $~probability / $~i;	// recursive Poisson density
		$~cumulativeProbability = $~cumulativeProbability + $~probability;

		$~step =
			If ( $~random < $~cumulativeProbability;	// result is found
				$~step + 1;
				/* Else */ $~step
			)
	];
		RandomPoisson ( mean )
	);


	/* Step 2: clean-up and return result */
	$~step = 2;
	Let ( [
		~value = $~i;

		// purge variables
		$~cumulativeProbability = "";
		$~i = "";
		$~probability = "";
		$~random = "";
		$~step = ""
	];
		If ( mean > 0;	// value is within bounds
			~value;
			/* Else */ "?"
		)
	)
)

When called repeatedly with the same input, RandomPoisson returns values that are Poisson distributed with mean given by the function argument. This function uses the inverse transform method to generate values.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

RandomPoisson ( mean )

Comments

Support this website.

Support this website.