GetPlatformName ( SysPlatform ; SysVersion ; AppVersion )

Returns the complete system platform and version in a more friendly output.

Average rating: 4.2 (29 votes) Log in to vote

Matt Larson - Show more from this author

Sample input:

GetPlatformName ( Get(SystemPlatform) , Get(SystemVersion) , Get(ApplicationVersion) )

Sample output:

OS X 10.8.2 Mountain Lion
macOS 10.12.1 Sierra
Windows XP 64 Bit
Windows 8.1

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*

GetPlatformName ( SysPlatform ; SysVersion ; AppVersion )
Version 2.1 by Matt Larson

Version History:
1.0 (2012-10-04):  Initial release.
1.1 (2013-08-08):  Dropped the "Mac" part from Mac OS X 10.8 and added "OS X 10.9 Mavericks".
1.2 (2014-06-09):  Added "OS X 10.10 Yosemite" and sorted more recent OS releases to top of list.
1.3 (2014-11-15):  Added "Windows 8.1" version.
1.4 (2015-08-05):  Added "OS X El Capitan" and "Windows 10" versions.
2.0 (2016-12-30):  Added "macOS Sierra" and basic WebDirect support.  Refactored to report more reliable Mac OS versions and better reporting for future OS releases; likely last update.
2.1 (2021-05-12) - Matt Larson - Added additional macOS codenames (High Siera thru Big Sur).

*/

Let(
[
	~IsMac =				Abs(SysPlatform) = 1;
	~MacPPC =			If(SysPlatform = -1; " (PowerPC)");
	~IsWin =				SysPlatform = -2;
	~IsIOS =				SysPlatform = 3;
	~IsWebD =			SysPlatform = 4;

	~MacVersionValues =	Substitute(SysVersion; "."; "¶");
	~MacMajorVersion =		GetValue(~MacVersionValues; 1) & "." & GetValue(~MacVersionValues; 2) ;
	~MacMajorVersion =		If ( ~MacMajorVersion ≥ 11 ; GetValue ( ~MacVersionValues ; 1 ) ; ~MacMajorVersion )
];
	Case(
		~IsMac and ~MacMajorVersion = "10.0"; "Mac OS X " & SysVersion & " Cheetah" & ~MacPPC;
		~IsMac and ~MacMajorVersion = "10.1"; "Mac OS X " & SysVersion & " Puma" & ~MacPPC;
		~IsMac and ~MacMajorVersion = "10.2"; "Mac OS X " & SysVersion & " Jaguar" & ~MacPPC;
		~IsMac and ~MacMajorVersion = "10.3"; "Mac OS X " & SysVersion & " Panther" & ~MacPPC;
		~IsMac and ~MacMajorVersion = "10.4"; "Mac OS X " & SysVersion & " Tiger" & ~MacPPC;
		~IsMac and ~MacMajorVersion = "10.5"; "Mac OS X " & SysVersion & " Leopard" & ~MacPPC;
		~IsMac and ~MacMajorVersion = "10.6"; "Mac OS X " & SysVersion & " Snow Leopard";
		~IsMac and ~MacMajorVersion = "10.7"; "Mac OS X " & SysVersion & " Lion";
		~IsMac and ~MacMajorVersion = "10.8"; "OS X " & SysVersion & " Mountain Lion";
		~IsMac and ~MacMajorVersion = "10.9"; "OS X " & SysVersion & " Mavericks";
		~IsMac and ~MacMajorVersion = "10.10"; "OS X " & SysVersion & " Yosemite";
		~IsMac and ~MacMajorVersion = "10.11"; "OS X " & SysVersion & " El Capitan";
		~IsMac and ~MacMajorVersion = "10.12"; "macOS " & SysVersion & " Sierra";
		~IsMac and ~MacMajorVersion = "10.13"; "macOS " & SysVersion & " High Sierra";
		~IsMac and ~MacMajorVersion = "10.14"; "macOS " & SysVersion & " Mojave";
		~IsMac and ~MacMajorVersion = "10.15"; "macOS " & SysVersion & " Catalina";
		~IsMac and ~MacMajorVersion = "11"; "macOS " & SysVersion & " Big Sur";
		~IsMac; "Mac OS " & SysVersion;

		~IsWin and SysVersion = "5.0"; "Windows 2000";
		~IsWin and SysVersion = "5.1"; "Windows XP 32 Bit";
		~IsWin and SysVersion = "5.2"; "Windows XP 64 Bit";
		~IsWin and SysVersion = "6.0"; "Windows Vista";
		~IsWin and SysVersion = "6.1"; "Windows 7";
		~IsWin and SysVersion = "6.2"; "Windows 8";
		~IsWin and SysVersion = "6.3"; "Windows 8.1";
		~IsWin and SysVersion = "10"; "Windows 10";
		~IsWin; "Windows " & SysVersion;

		~IsIOS and PatternCount(AppVersion; "ipad") > 0; "iOS " & SysVersion & " (iPad)";
		~IsIOS; "iOS " & SysVersion;

		~IsWebD; "WebDirect";  /*  This ought to be expanded to include more interesting information.  */

		"Unknown"
	)
)

Handles Mac platform back to Mac OS X 10.0, Windows platform back to Windows 2000, iOS and WebDirect. If the Mac happens to be running on PowerPC, the text string " (PowerPC)" will be appended to the result. The FileMaker app version is necessary because that's the only way* to detect if the iOS device is an iPad.

*At least before the advent of the Get(Device) function, which premiered with FM 13.

Comments

		John Farrell, Perth Australia Oct 15, 2012
This does not cater for a Mac user with VMware/Parallels running Fmkr under Windows. Extend the case statement I guess is the solution.

		HazMatt, Blaine, MN, USA Oct 15, 2012
FileMaker has no way of detecting if it's running in a virtual machine. And why should it? It reports a Windows platform and that is just as true in a virtual environment as it is on a regular PC running Windows.

		Eric, SJSU Jun 8, 2014
Now that apple is at 10.10 10.10 reports Yosemite as puma... anyone know the fix?

		HazMatt, Blaine, MN, USA Jun 9, 2014
Early adopter, eh? I haven't touched Yosemite yet so I'm glad for the feedback. See version 1.2 of this custom function for the fix.

		Michael Ashley, San Rafael Sep 23, 2015
hello, thank you for this function, I use it in our solutions. I think it gives a nice feedback to the user and helps us with everything from managing records to troubleshooting. I was having an issue with Windows 10 running on Parallels 11, so I made a small change. SysPlatform = -2 and SysVersion > "10"; "Windows 10"; changing "=" to ">" works. Thanks!

		HazMatt, Blaine, MN, USA Sep 23, 2015
Hi Michael, Thanks for the feedback. :) I'm curious as to what FileMaker actually returns for Get(SystemVersion) on Windows 10? I didn't have access to Windows 10 myself (yet), so what I used was an educated guess on limited resources. I see that Microsoft lists "10.0" as the version number here: https://msdn.microsoft.com/en-us/library/windows/desktop/ms724832(v=vs.85).aspx Dismayed that version numbers are still justâ€¦ soâ€¦Â hard for Microsoft. Â¯\_(ãƒ„)_/Â¯

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

GetPlatformName ( SysPlatform ; SysVersion ; AppVersion )

Comments

Support this website.

Support this website.