HolidaysAUS ( theYear )

Creates a paragraph-delimited list of dates for Australian national holidays.

Average rating: 5.0 (23 votes) Log in to vote

Vaughan Bromfield - Show more from this author

Sample input:

HolidayAUS ( 2011 )

Sample output:

3/01/2011
26/01/2011
22/04/2011
25/04/2011
26/04/2011
13/06/2011
3/10/2011
26/12/2011
27/12/2011

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

// HolidaysAUS ( theYear )
//
// http://www.briandunning.com/cf/1494
//
// Written by Vaughan Bromfield
// vaughan.bromfield@me.com
// vaughan.bromfield@gmail.com
//
// v1.0 - 22 October 2012
// v1.1 - 23 October 2012 -- added historical limits, changed to List()
// v1.2 - 23 October 2012 -- allowed for ANZAC Day to move due to clash with Easter Monday in 2011
//
// Returns a list of paragraph-delimited dates for Australian national public holidays.
// The list has a NSW bias for Queens Birthday, and Labour Day.
// Does not return dates that fall on Saturday or Sunday.
// An attempt has been made to include the proclamation years of the holidays
// to give them historical limits, but these are not 100% correct.
// Arguably I could exclude any year before 1788 when Australia was first colonised by Europeans,
// or 1901 when Australia became independent from Britain.
//
// Calculates the standard public holidays for Australia (actually NSW):
// New Years Day
// Australia Day
// Good Friday
// Easter Monday
// ANZAC Day
// Queens Birthday (All states except WA)
// Labour Day (ACT, NSW, SA)
// Christmas Day
// Boxing Day
//
// Includes code from the custom function
// Easter_Sunday ( TheYear )
// by Menno van Beek, STB Automatisering & Advies BV.
// http://www.briandunning.com/cf/1473
//

Case( 

// Check the input is valid. The Easter calculation is limited to years between 1583 and 4000.
IsEmpty( theYear ) or theYear < 1583 or Int( theYear ) ≠ theYear or theYear > 4000 ; "" ; 

// Calculate the date for Easter_Sunday.
Let (
[
Y = theYear ;
G = Mod( Y ; 19 ) + 1 ;                                                   //golden number
C = Left( Right( "0000" & Y ; 4 ) ; 2 ) + 1 ;                      //century
L = Truncate( 3*C/4 ; 0 ) - 12 ;                                      //leapyear correction
M = Truncate( ( 8*C+5 ) / 25 ; 0 ) - 5 ;                          //moon correction
S = Truncate( Y*5/4 ; 0 ) - ( L+10 ) ;                              //sunday
E1 = Mod( 11*G + 20 + M - L ; 30 ) ;
E = Case( E1=24 or E1=25 and G>11 ; E1+1  ; E1 ) ;      //Epacta (age of the moon on january 1st)
N = 44-E+Case( 44-E<21 ; 30 ; 0 ) ;                              //Full moon
P = ( N+7 ) - Mod( S+N ; 7 ) ;                                         //number of days after last day of February
Easter_Sunday = Date( 3 ; P ; Y )
] ; 


List( 

// New Years Day: 1 January unless Sat or Sun, then Monday.
Case( 
DayOfWeek( Date( 1 ; 1 ; theYear ) ) = 1 ; Date( 1 ; 2 ; theYear ) ; 
DayOfWeek( Date( 1 ; 1 ; theYear ) ) = 7 ; Date( 1 ; 3 ; theYear ) ; 
Date( 1 ; 1 ; theYear ) 
) ;  

// Australia Day: 26 January unless ≥ 2012 Sat or Sun, then Monday.
Case( 
theYear < 1818 ; "" ; 
theYear < 2012 ; Date( 1 ; 26 ; theYear ) ; 
DayOfWeek( Date( 1 ; 26 ; theYear ) ) = 1 ; Date( 1 ; 27 ; theYear ) ; 
DayOfWeek( Date( 1 ; 26 ; theYear ) ) = 7 ; Date( 1 ; 28 ; theYear ) ; 
Date( 1 ; 26 ; theYear ) 
) ; 

// Good Friday.
Case( 
theYear < 1583 ; "" ; 
Easter_Sunday - 2 
) ; 

// Easter Monday.
Case( 
theYear < 1583 ; "" ; 
Easter_Sunday + 1  
) ; 

// ANZAC Day: 25 April unless Sat or Sun, then Monday.
// In 2011 ANZAC day clashed with Easter Monday and was moved to next day

Case( 
theYear < 1916 ; "" ; 

Let( 
[
temp = Case(
             DayOfWeek( Date( 4 ; 25 ; theYear ) ) = 1 ; Date( 4 ; 26 ; theYear ) ; 
             DayOfWeek( Date( 4 ; 25 ; theYear ) ) = 7 ; Date( 4 ; 27 ; theYear ) ; 
             Date( 4 ; 25 ; theYear ) )
] ; 
Case( temp = Easter_Sunday + 1 ; temp + 1 ; temp )     // MUST calculate Easter Sunday before ANZAC day.
) // end let
) ; 


// Queens Brithday: second Monday in June
Case( 
theYear < 1937 ; "" ; 
DayOfWeek( Date( 6 ; 8 ; theYear ) ) ≤ 2 ; Date( 6 ; 8 ; theYear ) ; 
Date( 6 ; 8 ; theYear ) + 9 - DayOfWeek( Date( 6 ; 8 ; theYear ) ) 
) ; 

// Labour Day: first Monday in October
Case( 
DayOfWeek( Date( 10 ; 1 ; theYear ) ) ≤ 2 ; Date( 10 ; 1 ; theYear ) ; 
Date( 10 ; 1 ; theYear ) + 9 - DayOfWeek( Date( 10 ; 1 ; theYear ) ) 
) ;  

// Christmas Day: 25 December unless Sat or Sun, then Monday or Tuesday respectively.
Case( 
DayOfWeek( Date( 12 ; 25 ; theYear ) ) = 1 ; Date( 12 ; 26 ; theYear ) ; 
DayOfWeek( Date( 12 ; 25 ; theYear ) ) = 7 ; Date( 12 ; 27 ; theYear ) ; 
Date( 12 ; 25 ; theYear )  
) ;  

// Boxing Day: 26 December unless Sat or Sun, then Monday or Tuesday respectively.
Case( 
DayOfWeek( Date( 12 ; 26 ; theYear ) ) = 1 ; Date( 12 ; 28 ; theYear ) ; 
DayOfWeek( Date( 12 ; 26 ; theYear ) ) = 2 ; Date( 12 ; 27 ; theYear ) ; 
DayOfWeek( Date( 12 ; 26 ; theYear ) ) = 7 ; Date( 12 ; 28 ; theYear ) ; 
Date( 12 ; 26 ; theYear ) 
) 

) // end list

) // end Let

) // end case

HolidaysAUS ( theYear )

http://www.briandunning.com/cf/1494

Written by Vaughan Bromfield
vbromfield@optusnet.com.au
vaughan.bromfield@me.com
vaughan.bromfield@gmail.com

v1.0 - 22 October 2012
v1.1 - 23 October 2012 -- added historical limits, changed to List()
v1.2 - 23 October 2012 -- allowed for ANZAC Day clash with Easter Monday in 2011

Returns a list of paragraph-delimited dates for Australian national public holidays. Does not return dates that fall on Saturday or Sunday.
The holiday list has a NSW bias and includes the NSW dates for Queens Birthday and Labour Day.
An attempt has been made to include the proclamation years of the holidays to give them historical limits, but these are not complete nor 100% correct.
Arguably I could exclude any year before 1788 when Australia was first colonised by Europeans, or 1901 when Australia became independent from Britain.

Calculates the standard public holidays for Australia (actually NSW):
New Years Day
Australia Day
Good Friday
Easter Monday
ANZAC Day
Queens Birthday (All states except WA)
Labour Day (ACT, NSW, SA)
Christmas Day
Boxing Day

Includes code from the custom function
Easter_Sunday ( TheYear )
by Menno van Beek, STB Automatisering & Advies BV.
http://www.briandunning.com/cf/1473

Comments

		Robert Schaub, East Hampton CT Oct 22, 2012
All though your sample input is correct RectangleArea ( 2 , 3 ) is 6 as seen in the saample output. I am not quite sure what this has to do with a cf that gets Austrailian holidays?

		Vaughan, Sydney AUstralia Oct 22, 2012
Updated, thanks.

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

HolidaysAUS ( theYear )

Comments

Support this website.

Support this website.