ErrorFunctionInverse ( x )

Calculates the inverse error function via Taylor series expansion

Average rating: 4.4 (28 votes) Log in to vote

Jeremy Bante

http://github.com/jbante

Sample input:

List (
ErrorFunctionInverse ( -.8 ) ;
ErrorFunctionInverse ( -.6 ) ;
ErrorFunctionInverse ( -.4 ) ;
ErrorFunctionInverse ( -.2 ) ;
ErrorFunctionInverse ( 0 ) ;
ErrorFunctionInverse ( .1 ) ;
ErrorFunctionInverse ( .3 ) ;
ErrorFunctionInverse ( .5 ) ;
ErrorFunctionInverse ( .7 ) ;
ErrorFunctionInverse ( .9 )
)

Sample output:

-.90619380243681129116239661400140183641072811603236
-.59511608144999483099716019972985021912702246342263
-.37080715859355792771730281906148776800110420959213
-.17914345462129167542107793245150434382489250138362
0
.0888559904942577
.27246271472675435351518042903635524518984326931916
.47693627620446987015027371023187301092338722790087
.73286907795921666827066321704975849515295969428148
1.16308715364904662588930164987257155615356517332946

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/**
 * =====================================
 * ErrorFunctionInverse ( x )
 * https://github.com/jbante/FileMaker-Techniques/blob/master/CustomFunctions/Math/ErrorFunctionInverse.fmfn
 *
 * RETURNS:
 *		The inverse error function of x (commonly represented as erfinv in other
 *		programming environments).
 *
 * PARAMETERS:
 *		x: A number. -1 < x < 1
 *
 * DEPENDENCIES: none
 *
 * NOTES:
 *		This function calculates the inverse error function by adding successive
 *		values from its Taylor/Maclaurin series until the difference falls to
 *		zero at the current precision. The coefficients for the terms of the
 *		series are memoized in variables to improve performance in repeated
 *		calls to the function within the same local scope.
 *
 * HISTORY:
 *		CREATED on 2013-03-12 by Jeremy Bante <http://scr.im/jbante>.
 *
 * REFERENCES:
 *		http://en.wikipedia.org/wiki/Error_function#Inverse_functions
 * =====================================
 */

Case (
	/* Step 0, set-up */
	not $~erfinv.step ;
		Let ( [
			$~erfinv.coefficient[0] = 1 ;
			x = x * Sqrt ( Pi ) / 2 ;	// common factor in Taylor series
			$~erfinv.step = If ( x ≤ -1 or x ≥ 1 ; -1 ; /* Else */ 1 )
		] ;
			ErrorFunctionInverse ( x )
		) ;

	/* Step 1, accumulate Taylor series */
	$~erfinv.step = 1 ;
		Let ( [
			$~erfinv.k = $~erfinv.k + 1 ;
			$~erfinv.m = -1 ;	// reset inner loop

			// use previously calculated coefficient to add next term of series
			~u = 2 * ( $~erfinv.k - 1 ) + 1 ;
			$~erfinv.result =
				$~erfinv.result
				+ x ^ ~u * $~erfinv.coefficient[$~erfinv.k - 1] / ~u ;

			$~erfinv.step =
				Case (
					// precision limit reached
					$~erfinv.result - $~erfinv.priorResult = 0 ;
						3 ;

					// coefficient for next term is not memoized
					IsEmpty ( $~erfinv.coefficient[$~erfinv.k] ) ;
						$~erfinv.step + 1 ;

					/* Else, add next series term */
						$~erfinv.step
				) ;
			$~erfinv.priorResult = $~erfinv.result
		] ;
			ErrorFunctionInverse ( x )
		) ;

	/* Step 2, calculate series term coefficient (inner loop) */
	$~erfinv.step = 2 ;
		Let ( [
			$~erfinv.m = $~erfinv.m + 1 ;
			$~erfinv.coefficient[$~erfinv.k] =
				$~erfinv.coefficient[$~erfinv.k]
				+ $~erfinv.coefficient[$~erfinv.m]
				* $~erfinv.coefficient[$~erfinv.k - 1 - $~erfinv.m ]
				/ ( ( $~erfinv.m + 1 ) * ( 2 * $~erfinv.m + 1 ) ) ;
			$~erfinv.step =
				If ( $~erfinv.m < $~erfinv.k - 1 ;
					$~erfinv.step ;
					/* Else */ $~erfinv.step - 1
				)
		] ;
			ErrorFunctionInverse ( x )
		) ;

	/* Step 3, clean-up and return result */
	$~erfinv.step = 3 or $~erfinv.step = -1 ;
		Let ( [
			~error = $~erfinv.step = -1 ;
			~result = $~erfinv.result ;

			// purge variables
			// $~erfinv.coefficient variables not purged to improve performance
			$~erfinv.i = "" ;
			$~erfinv.k = "" ;
			$~erfinv.m = "" ;
			$~erfinv.priorResult = "" ;
			$~erfinv.result = "" ;
			$~erfinv.step = ""
		] ;
			If ( ~error ; "?" ; /* Else */ ~result )
		)
)

Returns the inverse error function of x (commonly represented as erfinv(x) in other programming environments). The calculation happens by means of a Taylor/Maclaurin series expansion. The coefficients for the terms of the series are memoized in variables to improve performance in repeated calls to the function within the same local scope.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

ErrorFunctionInverse ( x )

Comments

Support this website.

Support this website.