GeneratePW ( Digit ; Option )

Generate random password string.

Average rating: 4.5 (30 votes) Log in to vote

Koji Takeuchi - Show more from this author
TonicNote, Inc.
https://tonicnote.com

Sample input:

GeneratePW ( 8 ; "lusn" )

Sample output:

"8Dfu7)e!"

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*
GeneratePW ( Digit ; Option )
2013.10.29, Koji Takeuchi <takeuchi@nemoux.com>

description:
	Generate random password string.
	2020.09.01 Updated. The generated string is still random but unique.
Params:
	Digit		Length of the Password string you are about to generate.
	Option	l	Use lower case (ex. abcd)
			u	Use upper case (ex. ABCD)
			s	Use symbol (ex. $!%)
			n	Use numeral string (ex. 12345)
			Default is "lusn".
Example:
	GeneratePW ( 8 ; "lusn" )
	 -> "8Dfu7)e!"
	GeneratePW ( 8 ; "lus" )
	 -> "Uw*f&%S"
	GeneratePW ( 8 ; "l" )
	 -> "kwpdowgu"

	GeneratePW ( 8 ; "" ) = GeneratePW ( 8 ; "lusn" )
	GeneratePW ( "" ; "?" )	will show this help.
*/

Let (
[
ERROR =
	IsEmpty ( Digit ) or
	Option = "?" ;
MSG =
	Case (
		ERROR ;
		"Usage:	kt_GeneratePW ( Digit ; Option )" & ¶ &
		"Options:" & ¶ &
		"	Digit		Length of the Password string you are about to generate." & ¶ &
		"	Option	l	Use lower case (ex. abcd)" & ¶ &
		"			u	Use upper case (ex. ABCD)" & ¶ &
		"			s	Use symbol (ex. $!%)" & ¶ &
		"			n	Use numeral string (ex. 12345)" & ¶ &
		"			Default is \"lusn\"." & ¶ &
		"Example:" & ¶ &
		"	kt_GeneratePW ( 8 ; \"lusn\" )" & ¶ &
		"	 -> \"8Dfu7)e!\"" & ¶ &
		"	kt_GeneratePW ( 8 ; \"lus\" )" & ¶ &
		"	 -> \"Uw*f&%S\"" & ¶ &
		"	kt_GeneratePW ( 8 ; \"l\" )" & ¶ &
		"	 -> \"kwpdowgu\"" & ¶ &
		¶ &	
		"	kt_GeneratePW ( 8 ; \"\" ) = kt_GeneratePW ( 8 ; \"lusn\" )" & ¶ &
		"	kt_GeneratePW ( \"\" ; \"?\" )	will show this help."
	) ;

NUM =
	GetAsNumber ( Digit ) ;
LOWEROPTION =
	Case (
		IsEmpty ( Option ) ;
		"lusn" ;
		Filter ( Lower ( Option ) ; "lusn" )
	) ;
isLower=
	PatternCount ( LOWEROPTION ; "l" ) ;
isUpper =
	PatternCount ( LOWEROPTION ; "u" ) ;
isSymbol =
	PatternCount ( LOWEROPTION ; "s" ) ;
isNumeral =
	PatternCount ( LOWEROPTION ; "n" ) ;
SOURCE_l =
	"abcdefghijkmnopqrstuvwxyz" ;
SOURCE_u =
	"ABCDEFGHJKLMNPQRTUVWXYZ" ;
SOURCE_s =
	"~!@#$%^&*()-<>" ;
SOURCE_n =
	"2346789" ;
SOURCE =
	Case ( isLower ; SOURCE_l ) &
	Case ( isUpper ; SOURCE_u ) &
	Case ( isSymbol ; SOURCE_s ) &
	Case ( isNumeral ; SOURCE_n ) ;
num_SOURCE =
	Length ( SOURCE ) ;
RNUMBER =
	GetAsNumber ( Right ( Random ; 3 ) ) ;
POS =
	Mod ( RNUMBER ; num_SOURCE ) ;
CHAR_CURRENT =
	Middle ( SOURCE ; POS ; 1 ) ;
VALID =
	IsEmpty ( FilterValues ( $$ARRAY_GENERATEPW ; CHAR_CURRENT ) ) ;
$$ARRAY_GENERATEPW =
	Case (
		VALID ;
		List ( $$ARRAY_GENERATEPW ; CHAR_CURRENT ) ;
		$$ARRAY_GENERATEPW
	) ;
RESULT =
	Case (
		ValueCount ( $$ARRAY_GENERATEPW ) ≥ NUM ;
		Substitute ( $$ARRAY_GENERATEPW ; ¶ ; "" ) ;
		GeneratePW ( Digit ; Option )
	)
] ;

Case (
	ERROR ;
	MSG ;

	Let (
	$$ARRAY_GENERATEPW = "" ;
	RESULT
	)
)
)

GeneratePW ( Digit ; Option )
2013.10.29, Koji Takeuchi

description:
Generate random password string.
Params:
Digit Length of the Password string you are about to generate.
Option l Use lower case (ex. abcd)
u Use upper case (ex. ABCD)
s Use symbol (ex. $!%)
n Use numeral string (ex. 12345)
Default is "lusn".
Example:
GeneratePW ( 8 ; "lusn" )
-> "8Dfu7)e!"
GeneratePW ( 8 ; "lus" )
-> "Uw*f&%S"
GeneratePW ( 8 ; "l" )
-> "kwpdowgu"

GeneratePW ( 8 ; "" ) = GeneratePW ( 8 ; "lusn" )
GeneratePW ( "" ; "?" ) will show this help.

Comments

		AgnÃ¨s, Paris Oct 31, 2013
Hello, Just for fun, you can put the possibility of its own chain and include or exclude duplicates I allowed a different approach, not recursive, but with "false small recursive" this would : // GeneratePW ( Chaine ; Digit ; Option ; Dupli ) // Max Digit = 404 //------------- Let ([ $Chaine = Case ( IsEmpty ( Chaine ) ; Substitute ( "[-]" & Filter ( Option ; "lusn" ) ; [ "[-]" ; Case ( IsEmpty ( Option ) ; "lusn" ; "" ) ] ; [ "l" ; "[l]" ] ; [ "u" ; "[u]" ] ; ["s" ; "[s]" ] ; ["n" ; "[n]" ] ; [ "[l]" ; "abcdefghijkmnopqrstuvwxyz" ] ; [ "[u]" ; "ABCDEFGHJKLMNPQRTUVWXYZ" ] ; [ "[s]" ; "~!@#$%^&()-<>" ] ; [ "[n]" ; "2346789" ] ) ; Chaine ) ; Calc = "Let ( $n = Int ( Random Length ( $Chaine ) ) + 1 ; Middle ( $Chaine ; $n ; 1 ) ) &" ; NoDupli = Case ( Dupli = 0 ; "Let ( $Chaine = Replace ( $Chaine ; $n ; 1 ; """" ) ; """" ) &" ) ] ; Evaluate ( Substitute ( ( 10 ^ Digit ) - 1 ; 9 ; Calc & NoDupli ) & """""" ) ) //-------- for example with : Chaine = "" ; // Empty or No Option = "lusn" ; // Empty or char l u n s only Digit = "10" ; // Length PW Dupli = 1 // 1 for duplicate char or 0 for no duplicate char (Empty = Duplicate ok ) Best regards

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

GeneratePW ( Digit ; Option )

Comments

Support this website.

Support this website.