ChecksumAdler32 ( asciiText )

Computes an Adler-32 checksum

Average rating: 4.5 (30 votes) Log in to vote

Jeremy Bante
Fugue
fuguedata.co

Sample input:

ChecksumAdler32 ( "message digest" )

Sample output:

695534982

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*******************************************************************************
 * ChecksumAdler32 ( asciiText )
 * Computes a 32 bit checksum for a string of text using the Adler-32 algorithm.
 *
 * @parameter asciiText: A string a text with character codes between 0 and 255.
 *
 * @return A number representing a 32-bit checksum
 *
 * @history 2014-01-05 - Jeremy Bante <http://scr.im/jbante> - Created
 *
 * @see http://en.wikipedia.org/wiki/Adler-32
 * @see http://www.ietf.org/rfc/rfc1950.txt
 ******************************************************************************/

Case (
	/* Step 0, set-up */
	not $~adler.step ;
		Let ( [
			// initialize checksum values
			$~adler.a = 1 ;
			$~adler.b = 0 ;
			$~adler.i = 1 ;
			$~adler.byte = Code ( Middle ( asciiText ; $~adler.i ; 1 ) ) ;
			$~adler.step =
				Case (
					IsEmpty ( $~adler.byte ) ; 2 ;	// end
					$~adler.byte > 255 ; -1 ;	// out of range
					/* Else */ 1
				)
		] ;
			ChecksumAdler32 ( asciiText )
		) ;

	/* Step 1, accumulate checksum */
	$~adler.step = 1 ;
		Let ( [
			$~adler.a = Mod ( $~adler.a + $~adler.byte ; 65521 ) ;
			$~adler.b = Mod ( $~adler.b + $~adler.a ; 65521 ) ;
			$~adler.i = $~adler.i + 1 ;
			$~adler.byte = Code ( Middle ( asciiText ; $~adler.i ; 1 ) ) ;
			$~adler.step =
				Case (
					IsEmpty ( $~adler.byte ) ; 2 ;	// end
					$~adler.byte > 255 ; -1 ;	// out of range
					/* Else */ 1
				)
		] ;
			ChecksumAdler32 ( asciiText )
		) ;

	/* Step 2, clean-up and return result */
	$~adler.step = 2 or $~adler.step = -1 ;
		Let ( [
			~result =
				Case (
					$~adler.step = -1 ;
						"ERROR: Character out of range ("
						& $~adler.byte
						& ")" ;

					/* Else */
						$~adler.b * 65536 + $~adler.a
				) ;

			// purge variables
			$~adler.a = "" ;
			$~adler.b = "" ;
			$~adler.byte = "" ;
			$~adler.i = "" ;
			$~adler.step = ""
		] ;
			~result
		)
)

Computes a 32 bit checksum for a string of text using the Adler-32 algorithm.

Comments

		Bruce Robertson Jan 6, 2014
Jeremy: any comments on the relative merits of your version vs Vaughn's? Vaughn's calc looks way simpler. http://www.briandunning.com/cf/1122

		Jeremy, USA Jan 6, 2014
Mine doesn't require developers to remember the initial values for the two component checksums, or even to acknowledge their existence â€”Â This function is more encapsulated.

		Uli Graser, Miami Beach, FL Jun 7, 2017
Vaughns function is strictly functional - without side-effects and won't use variables outside the scope and canonically tail-recursive. much faster and could be multi-threaded and used even for rendering on many layout objects in parallel ..

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

ChecksumAdler32 ( asciiText )

Comments

Support this website.

Support this website.