Contains ( Text ; SearchStrings )

Determine whether Text contains any of the strings contained in SearchStrings ('or' logic)

Average rating: 4.4 (34 votes) Log in to vote

Bill Thurmes - Show more from this author
MDCA
http://www.miyotadca.com

Sample input:

Contains ( 24128 ; 412 )
( "CA¶CO¶DE¶IA¶MN¶ND¶SD" ; "GA¶FL" )
Contains ( "Jim,Jane" ; "m\,J" )

Sample output:

1
0
1

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*******************************
* Bill Thurmes 2016
* Syntax: Contains ( Text ; SearchStrings )
* Text = any text, including a delimited value list
* SearchStrings = Delimited value list, with accepted delimiters being commas, semicolons, or ¶
* To include commas, semicolons, ¶ (to be matched) in SearchStrings, include \ before them
*
* Purpose: Determine whether Text contains any of the strings contained in SearchStrings ('or' logic)
* Similar to Position function but will assess several SearchStrings, gives 0 or 1 (No or Yes) as Result
* If using two delimited value lists, FilterValues is probably faster
* Restriction: the following !-containing strings may not be part of SearchStings: !c! !s! !p!
*
* Examples: Contains ( "24128" ; "412" ) [= Contains ( 24128 ; 412 )]; Result = 1
* Contains ( "Jim,Charlie,Frank,Jane,Michelle,George,Kim,Chris" ; "Julie,Melinda,Rachel" ) = 0
* Contains ( "CA¶CO¶DE¶IA¶MN¶ND¶SD" ; "GA¶FL" ) = 0
* Contains ( "CA" ; "GA;FL;MN;CA" ) = 1
* Contains ( "CA" ; "GA;FL;MN; CA" ) = 0 Note the space before CA in SearchStrings
* Contains ( "Jim,Jane" ; "m\,J" ) = 1
* For a single entry in SearchStrings, Contains takes 2.5x as long as a simple PatternCount; 
*	takes slightly longer than the old Contains custom function
********************************/

Let ( [ 
Text = Substitute ( Text ; ¶ ; "!p!" ) ;
SearchStrings = Substitute ( 
		SearchStrings ; 
			["\," ; "!c!" ] ; 
			["\;" ; "!s!" ] ; 
			["\¶" ; "!p!" ] ; 
			[ "," ; ¶ ]; 
			[ ";" ; ¶ ] 
	) ;
ThisValue = Substitute ( 
				GetValue ( SearchStrings ; 1 ) ; 
				[ "!c!" ; "," ] ; 
				[ "!s!" ; ";" ] ) ;
interim = Case ( 
		ValueCount (SearchStrings ) > 1 ; /*IF*/
		If ( 
			Position ( /*THEN*/
				Text ; 
				ThisValue ; 
					1 ; 
					1 
				) ;
			1 ;
			0 )
			&
		Contains ( /*note: if CF name is changed, change here too*/
				Text ; 
				RightValues ( 
					SearchStrings ; 
					ValueCount ( SearchStrings ) - 1 ) 
				) ;
			
		If ( 
			Position ( /*THEN*/
				Text ; 
				ThisValue ; 
					1 ; 
					1 
				) ;
			1 ;
			0 ) 
	) /*End Case*/
	] ;
  
If ( PatternCount ( interim ; "1" ) ; 1 ; 0 )
 )

Determine whether Text contains any of the strings contained in SearchStrings ('or' logic)
In SearchStrings strings should be separated by commas, semicolons, or ¶
To include commas, semicolons, ¶ (to be matched) in SearchStrings, include \ before them
Restriction: the following !-containing strings may not be part of SearchStings: !c! !s! !p!
Similar to Position function but will assess several SearchStrings, gives 0 or 1 (No or Yes) as Result
By the way, where did the "Contains" name come from? HyperTalk, if anyone remembers that.
Updated April 2017 with no change of function, just easier-to-understand formatting and commenting

Comments

		John Vermeulen, Amsterdam (Holland) Jan 10, 2016
Hi there, Great function. This is almost what I'm looking for. I'm still figuring out the recursive part but I'm looking for a way to determine whether Text contains all (instead of of any) of the strings contained in SearchStrings. Is this perhaps possible with an extra parameter? Thanks in advance John

		Bill Thurmes, MDCA Jan 23, 2016
Check out ContainsAll. I wrote it just for you. I had tried to make the Contains function conceptually simple; making a new function rather than adding an additional parameter to this one made more sense to me. Also, the names of the two describe their functions very well now. However, the way I wrote ContainsAll is such that you could add an additional parameter to your own copy of that to mimic the Contains function (just do a PatternCount or position looking for any 1s).

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

Contains ( Text ; SearchStrings )

Comments

Support this website.

Support this website.