CheckdigitDamm ( digitSequence )

Calculates a check digit using the Damm algorithm

Average rating: 4.8 (22 votes) Log in to vote

Jeremy Bante
Beezwax Datatools, Inc.
http://beezwax.net

Sample input:

List (
CheckdigitDamm ( 12345 ) ;
12345 & CheckdigitDamm ( 12345 ) ;
CheckdigitDamm ( 12345 & CheckdigitDamm ( 12345 ) )
)

Sample output:

9
123459
0

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*******************************************************************************
 * CheckdigitDamm ( digitSequence )
 * Calculates a checkdigit to append to a digit sequence that can be used to
 * validate that the digit sequence has been transcribed correctly.
 *
 * This custom function implements an algorithm described by H. Michael Damm in
 * 2004.
 *
 * @parameter digitSequence: A sequence of decimal digits
 *
 * @return A single decimal digit, designed to be appended to the input
 *
 * @history 2014-04-21 - Jeremy Bante <http://scr.im/jbante> - Created
 *
 * @see http://en.wikipedia.org/wiki/Damm_algorithm
 ******************************************************************************/

Case (
	/* Step 0, set-up */
	not $~cdd.step ;
		Let ( [
			digitSequence = Filter ( digitSequence ; "0123456789" ) ;
			$~cdd.interim = 0 ;
			$~cdd.i = 1 ;
			$~cdd.digit = Middle ( digitSequence ; $~cdd.i ; 1 ) ;
			$~cdd.step = If ( IsEmpty ( $~cdd.digit ) ; 2 ; /* Else */ 1 )
		] ;
			CheckdigitDamm ( digitSequence )
		) ;

	/* Step 1, perform successive lookups from Damm's quasigroup */
	$~cdd.step = 1 ;
		Let ( [
			$~cdd.interim =
				Choose ( $~cdd.interim ;
					Choose ( $~cdd.digit ; 0 ; 3 ; 1 ; 7 ; 5 ; 9 ; 8 ; 6 ; 4 ; 2 ) ;
					Choose ( $~cdd.digit ; 7 ; 0 ; 9 ; 2 ; 1 ; 5 ; 4 ; 8 ; 6 ; 3 ) ;
					Choose ( $~cdd.digit ; 4 ; 2 ; 0 ; 6 ; 8 ; 7 ; 1 ; 3 ; 5 ; 9 ) ;
					Choose ( $~cdd.digit ; 1 ; 7 ; 5 ; 0 ; 9 ; 8 ; 3 ; 4 ; 2 ; 6 ) ;
					Choose ( $~cdd.digit ; 6 ; 1 ; 2 ; 3 ; 0 ; 4 ; 5 ; 9 ; 7 ; 8 ) ;
					Choose ( $~cdd.digit ; 3 ; 6 ; 7 ; 4 ; 2 ; 0 ; 9 ; 5 ; 8 ; 1 ) ;
					Choose ( $~cdd.digit ; 5 ; 8 ; 6 ; 9 ; 7 ; 2 ; 0 ; 1 ; 3 ; 4 ) ;
					Choose ( $~cdd.digit ; 8 ; 9 ; 4 ; 5 ; 3 ; 6 ; 2 ; 0 ; 1 ; 7 ) ;
					Choose ( $~cdd.digit ; 9 ; 4 ; 3 ; 8 ; 6 ; 1 ; 7 ; 2 ; 0 ; 5 ) ;
					Choose ( $~cdd.digit ; 2 ; 5 ; 8 ; 1 ; 4 ; 3 ; 6 ; 7 ; 9 ; 0 )
				) ;
			$~cdd.i = $~cdd.i + 1 ;
			$~cdd.digit = Middle ( digitSequence ; $~cdd.i ; 1 ) ;
			$~cdd.step = If ( IsEmpty ( $~cdd.digit ) ; 2 ; /* Else */ 1 )
		] ;
			CheckdigitDamm ( digitSequence )
		) ;

	/* Step 2, clean-up and return result */
	$~cdd.step = 2 ;
		Let ( [
			~result = $~cdd.interim ;

			// purge variables
			$~cdd.digit = "" ;
			$~cdd.i = "" ;
			$~cdd.interim = "" ;
			$~cdd.step = ""
		] ;
			~result
		)
)

Calculates a check digit to append to a digit sequence that can be used to validate that the digit sequence has been transcribed correctly.

This custom function implements an algorithm described by H. Michael Damm in 2004.

Comments

		Mark Scott, San Francisco Jan 9, 2015
Excellent! The Damm algorithm is, AFAIK, the most robust one out there for a single-numeric-digit check digit scheme. It's able to detect all single-digit transcription errors (e.g., 6â†”9) and all adjacent transpositions (e.g., 47â†”74)â€”which together account for 90% of errorsâ€”and most (though not all) of the other common errors, such as jump transpositions (e.g., 358â†”853), twin errors (e.g., 44â†”66), and jump twins (e.g., 494â†”797). Additionally, it detects all English-language phonetic errors (e.g., 16â†”60). The older and more widely known Luhn algorithm misses the transposition 09â†”90â€”yikes! those digits are right next to one another on any keyboard without a dedicated numeric keypad (think laptop!)â€”as well as the twin errors 22â†”55, 33â†”66, and 44â†”77. Yikes, again! Those three pairs are each vertically adjacent on a numeric keypad. I was about to code this myself, then decided to check here to see if someone has saved me from reinventing the wheel. Thanks, Jeremy; good work! Mark

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

CheckdigitDamm ( digitSequence )

Comments

Support this website.

Support this website.