XMLtag ( tag ; content ; type )

To be used in a script, returns correctly indentend xml

Average rating: 4.8 (22 votes) Log in to vote

Martin Spanjaard - Show more from this author
Trias Digitaal
http://www.triasdigitaal.nl

Sample input:

XMLtag( "Transaction" ; "" ; "start" )

XMLtag( "FinYear" ; "number=2014" ; "single" )

XMLtag("DueDate" ; "2014-04-03" ; "closed" )

Sample output:

2014-04-03

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

Let(
	// This let only takes care of the indentation.
	
	// If necessary initialise the variable
	[ $xmlindents = Case( IsEmpty( $xmlindents ) ; 0 ; $xmlindents )

	// An end tag itself is indented one tab less,
	// all other tags keep the same indentation
	; $xmlindents = 	$xmlindents - ( type = "end" )  // type = "end" is either 1 or 0

	// Calculate the indentation
	; ~indent 		= Left( TAB10 ; $xmlindents )   // TAB10 is a cf returning a string of 10 tab-characters.
	
	// A begin tag has the same indentation as the tag before,
	// but everything thereafter is indented one tab to the right.
	// Therefor in the case of a begin tag, the variable is calculated after the indentation was set.

	; $xmlindents = $xmlindents + Case(  type = "start" or IsEmpty( type ) ; 1 )

];
	// Begin with one or more tabs
	~indent

	// The behaviour of the tags differs according to the type, 
	// so different types have different let's.

	& 	Case(
	
			type = "closed" 
			
			// if there is content: <tag>content</tag>
			// if content is empty: <tag />

			; Let( 
				[ ~beginTag = Case(
								IsEmpty( content )
								; "<" & tag
								; "<" & tag & ">"
							 )

				; ~endTag   = Case(  
								IsEmpty( content ) 
								; " />" 
								; "</" & tag & ">" 
							 ) & ¶

				// Take care of the characters which are forbidden in XML (like: &, ", > and <)
				// because a tag of the type 'closed' often gets names, addresses and the like.
				; ~content 		= XMLEncode( content )

		 	  ]; 

				  ~beginTag & ~content & ~endTag

		  	  )


		;  	type = "end"	
			
			// An end tag is very simple and never has a value.

			; "</" & tag & ">¶"

		; 	// Type = "start", empty or "single")

			Let(
				[ ~nameValuePairs = case( not isempty( content ) ; " " & XMLtag_sub( content ))
				; ~ending = Case( type = "single" ; " /" ) & ">¶"          //  "/>¶" or  ">¶"

			];
				"<" 
				& tag
				& ~nameValuePairs
				& ~ending 

			) // end let
		 ) // end case
) // end let

/*************************************************************************************************************************
29-01-2014 - 01-05-2014
© Martin Spanjaard, Trias Digitaal Amserdam

XMLtag( tag ; content ; type ) returns automatically indented, correctly formatted xml-strings.

Some examples of possible output:

2014-04-03

The output ends with a return (¶).

The parameter 'type' can have one of 4 values:

- single: the tag begins with < and ends with />
- end: the tag begins with
- start: the tag begins with < and ends with >
- closed: - if content is given: value,
- if content is empty: (the same as that of the type 'single')

The content for the types 'single' and 'start' should be in the form of a string with one or more name=value pairs.
In the result the values will be quoted: name="value" and immediately follow the tag, as in the examples above.

The type 'end' does not expect content and doesn't handle it if there were content.

---

The correct indentation is done through the variable $xmlindents which is made in this custom function.
It exists during the script calling XMLtag.
The variable contains the number of tabs the code should be indented.
The method is:
- a start-tag raises the indentation with 1,
- an end-tag lowers it with 1.
The other tags do not change the variable.

*************************************************************************************************************************/

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

XMLtag ( tag ; content ; type )

Comments

Support this website.

Support this website.