Convert_Text_to_UTF8 ( string )

Converts a FileMaker text string to a UTF-8 string.

Average rating: 4.3 (29 votes) Log in to vote

Mogens Brun
fmIntegrator ApS
http://fmintegrator.com

Sample input:

Convert_Text_to_UTF8 ( "Man" )
Convert_Text_to_UTF8 ( "Mænd med idéer" )

Sample output:

Man
MÃ¦nd med idÃ©er

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*******************************************************************************
 * Convert_Text_to_UTF8 ( string )
 * Converts a FileMaker text string to a UTF-8 string. May be nested with "Convert_Text_to_Base64" to encode FileMaker text string to Base64 for use in URLs as "Convert_Text_to_Base64 ( Convert_Text_to_UTF8 ( string ) )". The combined action of the two custom functions performs with double speed as "AscIIToBase64" (also briandunning.com) and handles all legal char. values in UTF-8.
 *
 * @parameter string: A string of text with character codes between 0 and 4.294.967.295 ( 2^32 - 1 )
 *
 * @return: A string of text encoded in UTF-8. All chars with decimal value < 128 are passed unchanged. Chars with value < 2048 are passed as two bytes with special high order bits. Higher char values are passed as up to 6 bytes.
 *
 * @history 2014-06-27 - Mogens Brun, fmIntegrator ApS, <mogens_brun@me.com> - Created
 *
 * @see http://en.wikipedia.org/wiki/UTF-8
 ******************************************************************************/
Let ( [
	_char = Left ( string ; 1 ) ;
	_code = Code ( _char ) ;
	_chars = Case (
		_code = 13 ; Char ( 13 ) & Char ( 11 ) ; // Convert CR to CR VT (VT will be converted to LF in "Convert_Text_to_Base64"
		_code < 128 ; _char ; // 7 bits
		_code < 2048 ; Char ( 192 + Int ( _code / 64 ) ) &
			Char ( 128 + Mod ( _code ; 64 ) ) ; // 5 + 6 bits = 11 bits
		_code < 65536 ; Char ( 224 + Int ( _code / 4096 ) ) &
			Char ( 128 + Mod ( Int ( _code / 64 ) ; 64 ) ) &
			Char ( 128 + Mod ( _code ; 64 ) ) ; // 4 + 6 + 6 bits = 16 bits
		_code < 2097152 ; Char ( 240 + Int ( _code / 262144 ) ) &
			Char ( 128 + Mod ( Int ( _code / 4096 ) ; 64 ) ) &
			Char ( 128 + Mod ( Int ( _code / 64 ) ; 64 ) ) &
			Char ( 128 + Mod ( _code ; 64 ) )  ; // 3 + 6 + 6 + 6 bits = 21 bits
		_code < 67108864 ; Char ( 248 + Int ( _code / 16777216 ) ) &
			Char ( 128 + Mod ( Int ( _code / 262144 ) ; 64 ) ) &
			Char ( 128 + Mod ( Int ( _code / 4096 ) ; 64 ) ) &
			Char ( 128 + Mod ( Int ( _code / 64 ) ; 64 ) ) &
			Char ( 128 + Mod ( _code ; 64 ) )  ; // 2 + 6 + 6 + 6 + 6 bits = 26 bits ;
   		Char ( 252 + Int ( _code / 1073741824 ) ) &
			Char ( 128 + Mod ( Int ( _code / 16777216 ) ; 64 ) ) &
			Char ( 128 + Mod ( Int ( _code / 262144 ) ; 64 ) ) &
			Char ( 128 + Mod ( Int ( _code / 4096 ) ; 64 ) ) &
			Char ( 128 + Mod ( Int ( _code / 64 ) ; 64 ) ) &
			Char ( 128 + Mod ( _code ; 64 ) ) // 1 + 6 + 6 + 6 + 6 + 6 bits = 31 bits
		)
] ;
	Case (
		_code = 0 ; "" ;
		Length ( string ) = 1 ; _chars ;
		_chars & Convert_Text_to_UTF8 ( Middle ( string ; 2 ; Length ( string ) - 1 ) )
	)
)

Converts a FileMaker text string to a UTF-8 string. May be nested with "Convert_Text_to_Base64" to encode FileMaker text string to Base64 for use in URLs as "Convert_Text_to_Base64 ( Convert_Text_to_UTF8 ( string ) )". The combined action of the two custom functions performs with double speed as "AscIIToBase64" (also briandunning.com) and handles all legal char. values in UTF-8.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

Convert_Text_to_UTF8 ( string )

Comments

Support this website.

Support this website.