ntBitwiseOperation ( ope ; base ; value1 ; value2 )

Fast Bitwise Operation

Average rating: 4.5 (31 votes) Log in to vote

Norimichi Tachibana
none
none

Sample input:

ntBitwiseOperation("OR" ; 2 ; "10101" ; "111")
ntBitwiseOperation("XOR" ; 8 ; "3721" ; "437")
ntBitwiseOperation("AND" ; 16 ; "EFD8" ; "F0AC7")
ntBitwiseOperation("NOT" ; 16 ; "EFD8" ; "")
ntBitwiseOperation(">>" ; 2 ; "01101110" ; "3")
ntBitwiseOperation("<<" ; 16 ; "F0" ; "2")

Sample output:

"10111"
"3316"
"00AC3"
"1024"
"00001101"
"C0"

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*
@ Fast Bitwise Operation

[Format]
  ntBitwiseOperation ( ope ; base ; value1 ; value2 )

[Parameters]
  ope:      "OR", "NOR", "XOR", "AND", "NAND", "NOT","<<",">>"
  base:     numeral system base of value1 and value2
            "2" binary number  "8" octal number  "16" hexadecimal number
  value1:   MAX 800bits  (bin 800digits, oct 266digits, hex 200digits)
  value2:   MAX 800bits  (bin 800digits, oct 266digits, hex 200digits)
            If ope is "NOT", value2 number is ignored.

[Require Functions]
  ntRepeat

[Example]
  ntBitwiseOperation ( "OR" ; 2 ; "10101" ; "111" )  --> "10111"
  ntBitwiseOperation ( "XOR" ; 8 ; "3721" ; "437" )  --> "3316"
  ntBitwiseOperation ( "AND" ; 16 ; "EFD8" ; "F0AC7" )  --> "00AC3"
  ntBitwiseOperation ( "NOT" ; 16 ; "EFD8" ; "" )  --> "1024"
  ntBitwiseOperation ( ">>" ; 2 ; "01101110" ; "3" )  --> "00001101"
  ntBitwiseOperation("<<" ; 16 ; "F0" ; "2")  --> "C0"

[Performance Comparison]
  n bits binary digits bitwise XOR   50,000 records
		8bits	16bits	128bits
   Function A	103sec	185sec	1381sec
   Function B	 88sec	168sec	2117sec
   this Function	 63sec	 63sec	  76sec

[History]
  2014.07.17  Norimichi Tachibana   Created
*/

Let ( [
    bsize = Case ( base = 2 ; 1 ; base = 8 ; 3 ; 4 ) ;
    filter_str = Case ( base = 2 ; "01" ;
                        base = 8 ; "01234567" ;
                        "0123456789ABCDEF" ) ;

    ope = Upper ( ope ) ;
    rep0 = Case ( ope = "NAND" ; 1 ; ope = "NOR" or ope = "NOT" ; 3 ; 0 ) ;
    rep1 = If ( ope = "NOR" or ope = "AND" or ope = "NOT" ; 0 ; 1 ) ;
    rep2 = Case ( ope = "OR" or ope = "AND" ; 1 ; ope = "NOT" ; 2 ; 0 ) ;
    rep3 = If ( ope = "NOR" or ope = "NOT" ; 1 ; 3 ) ;

    shift = If ( ope = "<<" or ope = ">>" ; value2 ; 0 ) ;
    value1 = Upper ( value1 ) ;
    value2 = If ( FilterValues ( "NOT¶<<¶>>" ; ope ) = ope & "¶" ;
                               0 ; Upper ( value2 ) ) ;
    len1 = Length ( value1 ) ;
    len2 = Length ( value2 ) ;
    len = If ( len1 > len2 ; len1 ; len2 ) ;
    blen = len * bsize ;

    return = Case (
        len1 * bsize > 800 ; "#value1 length error#" & len1;
        len2 * bsize > 800 ; "#value2 length error#" ;
        Filter ( value1 ; filter_str ) ≠ value1 ; "#value1 illegal digit#" ;
        Filter ( value2 ; filter_str ) ≠ value2 ; "#value2 illegal digit#" ;
        FilterValues ( "2¶8¶16" ; base )  ≠ base & "¶" ; "#illegal base#" ;
        FilterValues ( "OR¶NOR¶XOR¶AND¶NAND¶NOT¶<<¶>>" ; ope ) ≠ ope & "¶" ;
                       "#illegal operator#" ;
        Let ( [
            // Pad numbers with zeros to make them the same length
            pad = SetPrecision ( 1 / 3 ; 400 ) ;
            pad = Substitute ( pad ; [ "3" ; "00" ] ; [ "." ; "" ] ) ;
            value1 = Right ( pad & value1 ; len ) ;
            value2 = Right ( pad & value2 ; len ) ;

            // Convert to binary data
            mixvalue = value1 & value2 ;
            mixvalue = Case (
                   base = 2 ; mixvalue ;
                   base = 8 ; Substitute ( mixvalue ; ["0" ; "000"] ;
                                                      ["1" ; "001"] ;
                                                      ["2" ; "010"] ;
                                                      ["3" ; "011"] ;
                                                      ["4" ; "100"] ;
                                                      ["5" ; "101"] ;
                                                      ["6" ; "110"] ;
                                                      ["7" ; "111"] ) ;
                   base = 16 ; Substitute ( mixvalue ; ["0" ; "0000"] ;
                                                       ["1" ; "0001"] ;
                                                       ["2" ; "0010"] ;
                                                       ["3" ; "0011"] ;
                                                       ["4" ; "0100"] ;
                                                       ["5" ; "0101"] ;
                                                       ["6" ; "0110"] ;
                                                       ["7" ; "0111"] ;
                                                       ["8" ; "1000"] ;
                                                       ["9" ; "1001"] ;
                                                       ["A" ; "1010"] ;
                                                       ["B" ; "1011"] ;
                                                       ["C" ; "1100"] ;
                                                       ["D" ; "1101"] ;
                                                       ["E" ; "1110"] ;
                                                       ["F" ; "1111"] ) ) ;
            value1 = Left ( mixvalue ; blen ) ;
            value2 = Right( mixvalue ; blen ) ;

            result = Case (
                ope = "<<" ; Right ( value1 & Left ( pad ; shift ) ; blen ) ;
                ope = ">>" ; Left ( Left ( pad ; shift ) & value1 ; blen ) ;
                Let ( [
                    // Previous calculation on the head 400 bits
                    p_pos = 1 ;
                    p_len = If ( blen > 400 ; 400 ; blen ) ;
                    p_value1 = Left ( value1 ; p_len ) ;
                    p_value2 = Left ( value2 ; p_len ) ;
                    p_value = Middle ( ( ( "1." & p_value1 ) +
　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　 ( "1." & p_value2 ) ) & pad
　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　 　; 3 ; p_len ) ;
                    result = p_value ;

                    // Previous calculation on the next 400 bits
                    p_len = blen - p_len ;
                    result = result &
                             If ( p_len > 0 ; 
                                  Middle ( ( ( "1." & Middle ( value1 ;
                                                       401 ; p_len ) ) +
                                             ( "1." & Middle ( value2 ;
                                                       401 ; p_len ) ) ) & pad
                                          ; 3 ; p_len )
                             )
                ] ;
                    // Perform a bitwise logical operation
                    Substitute ( result ; [ "0" ; rep0 ] ; [ "1" ; rep1 ] ;
                                          [ "2" ; rep2 ] ; [ "3" ; rep3 ] )
                ) ) ;

            // Convert to original base
            result = If ( base = 2 ; result ;
                          Let ( [
                              $ntr_pos = 1 ;
                              $ntr_str = "" ;
                              $ntr_cmd = "$ntr_str = $ntr_str & Middle ( \"" &
                                         result & "\"; $ntr_pos ; " & bsize &
                                         " ) & \"@\" ;" ;
                              $ntr_cmd = $ntr_cmd &
                                         "$ntr_pos = $ntr_pos + " & bsize ;
                              wk_str = ntRepeat ( len ; $ntr_cmd ; "$ntr_str" )
                          ] ;
                              If ( base = 8 ;
                                   Substitute ( wk_str ; ["000@" ; "0"] ;
                                                         ["001@" ; "1"] ;
                                                         ["010@" ; "2"] ;
                                                         ["011@" ; "3"] ;
                                                         ["100@" ; "4"] ;
                                                         ["101@" ; "5"] ;
                                                         ["110@" ; "6"] ;
                                                         ["111@" ; "7"] ) ;
                                   Substitute ( wk_str ; ["0000@" ; "0"] ;
                                                         ["0001@" ; "1"] ;
                                                         ["0010@" ; "2"] ;
                                                         ["0011@" ; "3"] ;
                                                         ["0100@" ; "4"] ;
                                                         ["0101@" ; "5"] ;
                                                         ["0110@" ; "6"] ;
                                                         ["0111@" ; "7"] ;
                                                         ["1000@" ; "8"] ;
                                                         ["1001@" ; "9"] ;
                                                         ["1010@" ; "A"] ;
                                                         ["1011@" ; "B"] ;
                                                         ["1100@" ; "C"] ;
                                                         ["1101@" ; "D"] ;
                                                         ["1110@" ; "E"] ;
                                                         ["1111@" ; "F"] ) )
                          )
                     )
        ] ;
            result
        )
    )
] ;
    return
)

[Format]
ntBitwiseOperation ( ope ; base ; value1 ; value2 )

[Parameters]
ope: "OR", "NOR", "XOR", "AND", "NAND", "NOT","<<",">>"
base: numeral system base of value1 and value2
"2" binary number "8" octal number "16" hexadecimal number
value1: MAX 800bits (bin 800digits, oct 266digits, hex 200digits)
value2: MAX 800bits (bin 800digits, oct 266digits, hex 200digits)
If ope is "NOT", value2 number is ignored.

[Require Functions]
ntRepeat

Comments

		Jeremy, USA Jul 18, 2014
This is a very clever technique you've come up with. I'm curious to see what the other methods are that you're comparing to. Have you published a file demonstrating your test results anywhere?

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

ntBitwiseOperation ( ope ; base ; value1 ; value2 )

Comments

Support this website.

Support this website.