CIDR2IPList_IPv4 ( cidr ; start )

Converts IPv4 CIDR notation into a list of IP addresses.

Average rating: 4.3 (28 votes) Log in to vote

Maxwell Klein - Show more from this author
Maxwell Klein Consulting
http://www.maxwellklein.com

Sample input:

CIDR2IPList_IPv4 ( "192.168.1.0/30" ; 0 )

CIDR2IPList_IPv4 ( "10.0.1.128/29" ; 1 )

Sample output:

"192.168.1.0¶192.168.1.1¶192.168.1.2¶192.168.1.3¶192.168.1.4"

"10.0.1.129¶10.0.1.130¶10.0.1.131¶10.0.1.132¶10.0.1.133¶10.0.1.134¶10.0.1.135¶10.0.1.136"

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*

CIDR2IPList_IPv4( cidr ; start )

Requires FileMaker 18, plus custom functions IP2IPLong and IPLong from Dick Impens. Converts IPv4 CIDR notation into a list of IP addresses. For performance the recursion limit is set to only allow subnet masks from 32 to 16.

2021-12-23: Update to use While and SetRecursion, improved CIDR format tests, fix to octet incrementing (thanks Gustav Hobel)
2021-11-29: Update from Ron Smith
2018-08-19: Original version

*/

Let( 
  [ 
    test = Substitute ( cidr ; [ "." ; ¶ ] ; [ "/" ; ¶ ] )
  ; o1 = GetAsNumber ( GetValue ( test ; 1 ) )
  ; o2 = GetAsNumber ( GetValue ( test ; 2 ) )
  ; o3 = GetAsNumber ( GetValue ( test ; 3 ) )
  ; o4 = GetAsNumber ( GetValue ( test ; 4 ) )
  ; m = GetAsNumber ( GetValue ( test ; 5 ) )
  ; ip = GetValue( Substitute ( cidr ; "/" ; ¶ ) ; 1 )
  ]
;
  Case(
       PatternCount( cidr ; "." ) <> 3 or PatternCount( cidr ; "/" ) <> 1  ; "Invalid CIDR"
     ; o1 < 0 or o1 > 255  ; "Invalid CIDR (Octet 1)"
     ; o2 < 0 or o2 > 255  ; "Invalid CIDR (Octet 2)"
     ; o3 < 0 or o3 > 255  ; "Invalid CIDR (Octet 3)"
     ; o4 < 0 or o4 > 255  ; "Invalid CIDR (Octet 4)"
     ; m > 32  ; "Invalid CIDR (Mask)"
     ; m < 16  ; "CIDR to large"
     ; IP2IPLong( ip ) + start < 0 ; "Invalid start"
  ;
     SetRecursion( 
        While(
           [
             cidr = cidr
           ; start = start
           ; ip = GetValue( Substitute ( cidr ; "/" ; ¶ ) ; 1 )
           ; prefix = GetValue( Substitute ( cidr ; "/" ; ¶ ); 2 )
           ; exponent = 32 - prefix
           ; count = 2 ^ exponent - 1
           ; first = IP2IPLong( ip )
           ; current = first + start
           ; out = "" 
           ]
        ;
           start <= count 
        ;
           [
             out = If( IsEmpty( out ) ; "" ; out & ¶ ) &  IPLong( current )
           ; start = start + 1
           ; current = first + start 
           ]
        ;
           out
        )
     ;
        65537
     )
  )
)

Requires FileMaker 18, plus custom functions IP2IPLong and IPLong from Dick Impens. Converts IPv4 CIDR notation into a list of IP addresses. For performance the recursion limit is set to only allow subnet masks from 32 to 16.

Comments

		Ron Smith Nov 29, 2021
Line with 'count = 2 ^ exponent ;' should be: count = 2 ^ exponent - 1;

		Maxwell Klein, Maxwell Klein Consulting Nov 29, 2021
@Ron Smith, thanks for the correction.

		Alan Deffenderfer, ABD Enterprises Dec 22, 2021
SetRecursion() is your friend with this great custom function from Maxwell!

		Maxwell Klein, Maxwell Klein Consulting Dec 23, 2021
@Alan Deffenderfer, SetRecursion set! For performance sake I still limit subnet mask to /16, you can make multiple calls or hack the function if you really need a list with more than 65,536 addresses. Also took the opportunity to modernize with While loop, improved preflight CIDR format and start position, plus fixed a bug that limited octets to .254.

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

CIDR2IPList_IPv4 ( cidr ; start )

Comments

Support this website.

Support this website.