ValidateCPR ( CPR )

Validates Danish CPR-number

Average rating: 4.9 (20 votes) Log in to vote

jra@rtm.dk
RTM Insurance Brokers A/S
http://www.rtm.dk/

Sample input:

ValidateCPR ( "070777-1119" )

Sample output:

1
1
07/07/1977
Mand

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/****
Signature: ValidateCPR ( CPR )
source: http://da.wikipedia.org/wiki/CPR-nummer
 
Parameters:
CPR: a text string in the form ddmmyy-cccc
method: not employed ATM; a possible 2nd parameter, but maybe it is more useful to have a list of results
 
result
1st line: validation of date part: an error code if the format is not valid, otherwise 1
- validation of full date will not fail, as the 31st in a 30-day month is the 1st of the next month
2nd line: modulus validation: 0 or 1
3rd line: the full date, if it passed validation
4th line: gender: male or female
****/
 
Let ( [
  // CPR = "130600-5738" ; to allow debugging in Data Viewer; make sure this is commented out for production version!
  digits = "0123456789" ;
  datePart = Filter ( Left ( CPR ; 6 ) ; digits ) ;
  controlPart = Filter ( Right ( CPR ; 4 ) ; digits );
 
  error =
    List (
      Case ( Length ( CPR ) ≠ 11 or Length ( Filter ( CPR ; digits ) ) ≠ 10 ; "Forkert længde" ) ;
      Case ( Middle ( CPR ; 7 ; 1 ) ≠ "-" ; "Forkert format" ) ;
      Case ( Length ( datePart ) ≠ 6 ; "Ikke-numerisk dato" ) ;
      Case ( Length ( controlPart ) ≠ 4 ; "Ikke-numeriske tjekcifre" )
    ) ;
 
  dd = GetAsNumber ( Middle ( datePart ; 1 ; 2 ) ) ;
  mm = GetAsNumber ( Middle ( datePart ; 3 ; 2 ) ) ;
  yy = Middle ( datePart ; 5 ; 2 ) ;
  yyNum = GetAsNumber ( yy ) ;
  digit7 = Left ( controlPart ; 1 ) ;
  digit10 = Right ( controlPart ; 1 ) ;
 
  century =
    Case (
      digit7 ≤ 3 ; 19;
      digit7 = 4 ; Case ( yyNum ≥ 0 and yyNum ≤ 36 ; 20 ; 19 ) ;
      digit7 ≤ 8 ; Case ( yyNum ≥ 0 and yyNum ≤ 57 ; 20 ; 18 ) ;
      digit7 = 9 ; Case ( yyNum ≥ 0 and yyNum ≤ 36 ; 20 ; 19 ) ;
      ) ;
  yyyy = century & yy ;
  ddmmyyyy = Date ( mm ; dd ; yyyy ) ;
  dateError =
    Day ( ddmmyyyy ) ≠ dd
    or
    Month ( ddmmyyyy ) ≠ mm
    or
    Right ( Year ( ddmmyyyy ) ; 2 ) ≠ yy
      ;
  error =
    List (
      error ;
      Case ( dateError ; "Ugyldig dato" )
    ) ;
 
  productSum =
    Middle ( datePart ; 1 ; 1 ) * 4
    +
    Middle ( datePart ; 2 ; 1 ) * 3
    +
    Middle ( datePart ; 3 ; 1 ) * 2
    +
    Middle ( datePart ; 4 ; 1 ) * 7
    +
    Middle ( datePart ; 5 ; 1 ) * 6
    +
    Middle ( datePart ; 6 ; 1 ) * 5
    +
    Middle ( controlPart ; 1 ; 1 ) * 4
    +
    Middle ( controlPart ; 2 ; 1 ) * 3
    +
    Middle ( controlPart ; 3 ; 1 ) * 2
    +
    Middle ( controlPart ; 4 ; 1 ) * 1 ;
 
  valid = not Mod ( productSum ; 11 ) ;
  gender =
    Case (
      Mod ( digit10 ; 2 ) ;
      "Mand" ;
      "Kvinde"
    ) ;
 
  result =
    Case (
      IsEmpty ( error ) ;
      List ( IsValid ( ddmmyyyy ) ; valid ; ddmmyyyy ; gender ) ;
      error
    )
  ] ;
 
  result
 
)

We have ID numbers in Denmark called CPR - Det Centrale PersonRegister- which has been in use since my birth year, 1968. Back then, bytes were expensive, so the biggest problem was that full years (four digits) were not used.

There are validation criteria that are well described:
http://da.wikipedia.org/wiki/CPR-nummer#Kontrol_af_personnummer

This function returns information on validity, date of birth, and gender, given the string.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

ValidateCPR ( CPR )

Comments

Support this website.

Support this website.