rapidTimeEntry ( text ; workdayStartHour )

enter time with numbers only

Average rating: 4.3 (28 votes) Log in to vote

David Schellenberg - Show more from this author

Sample input:

rapidTimeEntry ( "1323 ; 7 )
rapidTimeEntry ( "655 ; 7 )
rapidTimeEntry ( "1005 ; 7 )

Sample output:

1:23 PM
6:55 PM
10:05 AM

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*
rapidTimeEntry ( text ; workdayStartHour )
2015  David Schellenberg  filemaker@rivetcom.ca
slick Mod logic pulled from fmforums discussion by user:'comment'

- convert a string of numbers, without any punctuation, to time.
- AM/PM  is determined by Workday Starting Hour.
- opening IF statement will allow the user to modify the result. 

- currently function only considers a workdayStartHour less then 12

*/


If ( not IsEmpty ( Filter ( text ; "aApP" ) ) ; text ; 

	Let ([

		wdH = workdayStartHour ;	//workday starting hour 24hr

		//Self = "1320" ;	//test
		base1 = Filter ( text ; "0123456789" ) ;
		bl = Length ( base1 ) ;
		base2 = Case (
				bl < 3 ; Right ( "0" & base1 ; 2 ) & "00" ;
				Right (  "0000" & base1 ; 4 ) 
				) ;

		hh1 = Left ( base2 ; 2 ) ;
		hh2 = Mod ( hh1 - 1 ; 12 ) + 1 ;
		mm1 = Right ( base2 ; 2 ) ;
		mm2 = Mod ( mm1 - 1 ; 60 ) + 1 ;
		mm3 = If ( mm2 = 60 ; 0 ; mm2 ) ;

		ap = Choose ( hh2 >= wdH and hh2 <= 11 ; "PM" ; "AM" ) ;
		t1 = Time ( hh2 ; mm3 ; 0 ) ; 
		t2 = Left ( t1 ; Length ( t1 ) - 3 ) ;
		t3 = t2 &" "& ap ;
		t4 = GetAsTime ( t3 )

		];

	t4

	)
)

- convert a string of numbers (no punctuation) to time.
- AM/PM is determined by Workday Starting Hour.
- opening IF statement will allow the user to modify the result.

- currently function only considers a workdayStartHour less then 12

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

rapidTimeEntry ( text ; workdayStartHour )

Comments

Support this website.

Support this website.