ElapsedTimeInWords ( aTimeStamp )

Calculates time elapsed since TimeStamp in words

Average rating: 4.3 (29 votes) Log in to vote

Jason Ball
Streamtime Software
www.streamtime.net

Sample input:

ElapsedTimeInWords ( 31/12/2000 12:00:00 am )

Sample output:

2 hours ago
6 days ago
about 1 month ago
about 1 year ago
almost 2 years ago
3 years ago

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

// Jason Ball 9th December 2015
// jasonlukeball@me.com
// Calculates (in words) time elapsed since a timestamp 

Let ( 

	[
	now 	 	 	 	 	= 	Get ( CurrentTimeStamp ) ; 
	then 	 	 	 	 	= 	aTimeStamp ;
	elapsedTimeInSeconds    	= 	GetAsNumber ( now ) - GetAsNumber ( then )  ;
	elapsedTimeInMinutes    	= 	Round ( ( elapsedTimeInSeconds / 60 ) ; 0 )  ;
	elapsedTimeInHours      	= 	Round ( ( elapsedTimeInMinutes / 60 ) ; 0 ) ;
	elapsedTimeInDays       	= 	Round ( ( elapsedTimeInHours / 24 ) ; 0 ) ;
	elapsedTimeInMonths     	= 	Round ( ( elapsedTimeInDays / 30.5 ) ; 0 ) ;
	elapsedTimeInYears      	=	Round ( ( elapsedTimeInMonths / 12 ) ; 2 )
	]

	;  

	Case ( 
		elapsedTimeInSeconds 	= 0		; "Just now";
		elapsedTimeInSeconds 	≤ 59		; elapsedTimeInSeconds & If ( elapsedTimeInSeconds = 1 ; " second ago" ; " seconds ago" ) ;
		elapsedTimeInMinutes 	≤ 59		; elapsedTimeInMinutes & if ( elapsedTimeInMinutes = 1 ; " minute ago" ; " minutes ago" ) ;
		elapsedTimeInHours		< 24		; elapsedTimeInHours & if ( elapsedTimeInHours = 1 ; " hour ago" ; " hours ago" ) ;
		elapsedTimeInHours		≤ 42		; "1 day ago" ;
		elapsedTimeInDays		≤ 30		; elapsedTimeInDays & " days ago" ;
		elapsedTimeInDays		≤ 45		; "about 1 month ago" ;
		elapsedTimeInMonths		< 12		; elapsedTimeInMonths & " months ago" ;
		elapsedTimeInYears		≤ 1.25	; "about 1 year ago" ;
		elapsedTimeInYears		≤ 1.75	; "over 1 year ago" ;
		elapsedTimeInYears		< 2		; "almost 2 years ago" ;
		Round ( elapsedTimeInYears ; 0 ) & " years ago"
	)

)

Calculates (in words) time elapsed since a timestamp much like you'd see in a Facebook / Twitter feed....

Comments

		JoÃ£o Coutinho Jan 25, 2018
Great work. Love this for our Chat System.

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

ElapsedTimeInWords ( aTimeStamp )

Comments

Support this website.

Support this website.