CF.TextToTime ( TXT ; F ; L )

Coverts the first 3 up to 7 numbers of a text string into a time indication (hours, minutes, seconds).

Average rating: 4.4 (24 votes) Log in to vote

Thomas Hellwig
Delasocial GmbH, Hamburg (Germany)
http://www.delasocial.com

Sample input:

CF.TextToTime ( "ABC250761" ; 1 ; 0)
CF.TextToTime ( "milliseconds0155900" ; 3 ; 3 )
CF.TextToTime ( "61594" ; 2 ; 0 )

Sample output:

25:08:01
01:55:900
01:59

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*############################################################################################
 
___ Function name: CF.TextToTime ( TXT ; F ; L )
___ Version: 3.1 --- April 13th 2016
___ Code language: English
___ FMP version: 12
___ Written on March 8th 2016
___ Author: Thomas Hellwig
___ Contact: grafzahl68@gmx.de

Description:
Coverts the first 3, 4, 5, 6, or 7 numbers of a text string into a time indication (like hours:minutes or hours:minutes:seconds or minutes:seconds:milliseconds).
 
Version:
2.0: Completely revised code.
3.0: New Format "mm:ss" as code 2 and "ss:ms" as code 4. Additional parameter (L) for the numbers of digits of milliseconds.
3.1: Bugfix

Parameters:
(TXT) Possible values:
A text string with numbers ---> e.g. "Your time is 8 min and 23 sec." or "12445" or "089 hu!77-3p"
 
(F) Possible values:
Output format code:
0 ---> without seconds (hh:mm)
1 ---> with seconds (hh:mm:ss)
2 ---> without hours (mm:ss)
3 ---> without hours, but with milliseconds (mm:ss:ms)
4 ---> without hours and minutes (ss:ms)
 
(L) Lenght of millisecongs (number of digits):
0 ---> if not needed
1 ---> 1 digit
2 ---> 2 digits
3 ---> 3 digits
 
############################################################################################*/
 
Let (
[
L = Case ( IsEmpty ( L ) ; 0 ; L ) ;
FZ = Filter ( TXT ; "0123456789" ) ;
IN = Case ( F = 0 or F = 2 ; Left ( FZ ; 4 ) ; F = 1 ; Left ( FZ ; 6 ) ; F = 3 and L = 1 ; Left ( FZ ; 5 ) ; F = 3 and L = 2 ; Left ( FZ ; 6 ) ; F = 3 and L = 3 ; Left ( FZ ; 7 ) ; F = 4 and L = 1 ; Left ( FZ ; 3 ) ; F = 4 and L = 2 ; Left ( FZ ; 4 ) ; F = 4 and L = 3 ; Left ( FZ ; 5 ) ) ;
FIN = GetAsText ( "0000000" & IN ) ;
AZ = Case ( F = 0 or F = 2 ; Right ( FIN ; 4 ) ; F = 1 ; Right ( FIN ; 6 ) ; F = 4 ; Right ( FIN ; 5 ) ; Right ( FIN ; 7 ) )
]
 
; //__________________________________________________________________________________________________________________
 
Case (
F = 0 ; Left ( Time ( Left ( AZ ; 2 ) ; Right ( AZ ; 2 ) ; 0 ) ; 5 ) ;
F = 1 ; Time ( Left ( AZ ; 2 ) ; Middle ( AZ ; 3 ; 2 ) ; Right ( AZ ; 2 ) ) ;
F = 2 ; Right ( Time ( 0 ; Left ( AZ ; 2 ) ; Right ( AZ ; 2 ) ) ; 5 ) ;
F = 3 and L = 1 ; Right ( Time ( 0 ; Middle ( AZ ; 3 ; 2 ) ; Middle ( AZ ; 5 ; 2 ) ) ; 5 ) & ":" & Right ( AZ ; 1 ) ;
F = 3 and L = 2 ; Right ( Time ( 0 ; Middle ( AZ ; 2 ; 2 ) ; Middle ( AZ ; 4 ; 2 ) ) ; 5 ) & ":" & Right ( AZ ; 2 ) ;
F = 3 and L = 3 ; Right ( Time ( 0 ; Left ( AZ ; 2 ) ; Middle ( AZ ; 3 ; 2 ) ) ; 5 ) & ":" & Right ( AZ ; 3 ) ;
F = 4 and L = 1 ; Right ( Time ( 0 ; 0 ; Middle ( AZ ; 3 ; 2 ) ) ; 2 ) & ":" & Right ( AZ ; 1 ) ;
F = 4 and L = 2 ; Right ( Time ( 0 ; 0 ; Middle ( AZ ; 2 ; 2 ) ) ; 2 ) & ":" & Right ( AZ ; 2 ) ;
F = 4 and L = 3 ; Right ( Time ( 0 ; 0 ; Left ( AZ ; 2 ) ) ; 2 ) & ":" & Right ( AZ ; 3 ) ;
"Code Error"
)
 
) //___ EndLet
 
//############################################################################################

Description:
Coverts the first 3, 4, 5, 6, or 7 numbers of a text string into a time indication (like hours:minutes or hours:minutes:seconds or minutes:seconds:milliseconds).

Version:
2.0: Completely revised code.
3.0: New Format "mm:ss" as code 2 and "ss:ms" as code 4. Additional parameter (L) for the numbers of digits of milliseconds.
3.1: Bugfix

Parameters:
(TXT) Possible values:
A text string with numbers ---> e.g. "Your time is 8 min and 23 sec." or "12445" or "089 hu!77-3p"

(F) Possible values:
Output format code:
0 ---> without seconds (hh:mm)
1 ---> with seconds (hh:mm:ss)
2 ---> without hours (mm:ss)
3 ---> without hours, but with milliseconds (mm:ss:ms)
4 ---> without hours and minutes (ss:ms)

(L) Lenght of millisecongs (number of digits):
0 ---> if not needed
1 ---> 1 digit
2 ---> 2 digits
3 ---> 3 digits

Comments

		Lee Smith Mar 10, 2016
Your custom function is stumbling on â€œSetzeVarsâ€ as if Iâ€™m supposed to have a CF with that name, or the English version of what that does.

		Thomas Hellwig, Hamburg/Germany Mar 10, 2016
Please note that the FileMaker version is 12. The function "SetzeVars" is renamed in version 13. I hope this information is helping you.

		Lee Smith Mar 10, 2016
I guess Iâ€™m fighting more than one issue, the version Iâ€™m using is 14 and the Calc is in German which I donâ€™t know the the equivalent of English from German.

		Thomas Hellwig, Hamburg/Germany Mar 11, 2016
You can use the tool "Language Switcher" to start FileMaker in german. But the code above will be also switched automatically if you copy it into the Specify Calculation. Here it is in english: Let ( [ FZS = Filter ( TXT ; "0123456789" ) ; AZ = Case ( Length ( FZS ) = 1 ; GetAsText ( "0" & FZS ) ; FZS ) ; P = Left ( GetAsText ( AZ & "000000" ) ; 6 ) ; SEC = Case ( M = 1 ; 8 ; 5 ) ; Z = Left ( Time ( Left ( P ; 2 ) ; Middle ( P ; 3 ; 2 ) ; Right ( P ; 2 ) ) ; SEC ) ] ; //______________________________ Calculation Z ) //___ EndLet

		Thomas Hellwig, Hamburg/Germany Apr 2, 2016
Version 2.0 has a complete new structure and is reduced to three codes for three output formats: 0 ---> without seconds (hh:mm) 1 ---> with seconds (hh:mm:ss) 2 ---> without hours, but with milliseconds (mm:ss:ms )

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

CF.TextToTime ( TXT ; F ; L )

Comments

Support this website.

Support this website.