Text_Wrap_Around ( Text ; limit_around )

Wraps text around specific number of characters, preserving manually set line breaks. Words usually stay complete.

Average rating: 4.2 (20 votes) Log in to vote

Thomas Siebert - Show more from this author
http://www.t-seabird.de

Sample input:

Text_Wrap_Around ( "Why is six afraid of seven? Because 7 8 9." ; 12 )

Sample output:

Why is six afraid
of seven? Because
7 8 9.

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*
Text_Wrap_Around ( text ; limit_around )

version 25
---------------------------------------------
Thomas Siebert, 14.05.2016
info@t-seabird.de
www.t-seabird.de
---------------------------------------------
Wraps text around specific number of characters.
manually set returns (¶) will be recognized correctly.
usually words remain complete.
if the limit is set very short words will be broken.
no problems with special characters found.
Text length is limited to ~10000 Lines.

Char (65279) = BOM

*/

Let ([
limit_around = Case ( limit_around < 1 ; 1 ; limit_around ) ;
text = TrimAll ( Substitute ( text ; [ ¶ ; Char (65279) ] ; [ "." ; ". " ] ; [ "," ; ", " ] ; [ ";" ; "; " ] ; [ "?" ; "? " ] ; [ "!" ; "! " ] ) ; 0 ; 2 ) & " " ;
text_length = Length ( text ) ;

left_string = Left ( text ; limit_around ) ;
number_of_blanks = PatternCount ( left_string ; " " ) ;
last_blank_position = Position ( left_string ; " " ; 1 ; number_of_blanks ) ;

line_feed_position = Position ( left_string ; Char (65279) ; 1 ; 1 ) ;

break_position = Case ( line_feed_position > 0 and line_feed_position < last_blank_position ; line_feed_position ; last_blank_position ) ;
left_string_trimmed = Left ( text ; break_position - 1 ) ;

length_conflict = last_blank_position = 0 and line_feed_position = 0 and Length ( LeftWords ( text ; 1 ) ) > 0  ;

x_processed = Case ( length_conflict ; Left ( text ; limit_around ) & Case ( Length ( LeftWords ( text ; 1 ) ) > limit_around ; "-" ) ; left_string_trimmed ) ;
x_unprocessed = Case ( length_conflict ; Right ( text ; text_length - limit_around ) ; Right ( text ; text_length - break_position ) ) ;
length_unprocessed = Length ( x_unprocessed )
];

x_processed & Case ( length_unprocessed > 1 ; ¶ & Substitute ( Text_Wrap_Around ( x_unprocessed ; limit_around ) ; [ Char (65279) ; "" ] )  )

)

Wraps text around specific number of characters.
manually set returns (¶) will be recognized correctly.
usually words remain complete.
if the limit is set very short words will be broken.
no problems with special characters found.
Text length is limited to ~10000 Lines.

Comments

		Bernard Moreau, Belgium May 3, 2016
Looks nice, but specific number of chars "Line_Char_Limit" is not respected, even in your exemple output : "Why is six afraid" > 12 chars (I guess last word had to be trimmed ?). BM

		Thomas Siebert May 3, 2016
No, it is ment that words remain complete if they are inside the given limit. You also may set the limit to 1 â€¦ I also tried 0, it behaves different.

		Bernard Moreau, Belgium May 3, 2016
Thanks Thomas for pointing out the "wrapping" limit I didn't read. I got some problem with this splitting error : Text_Wrap_Around ( "Very good job, Iâ€™m excited! but [Iâ€™m] may not be split." ; 17 ) ---> Very good job, Iâ€™ m excited! but [Iâ€™ m] may not be split. Please advice.

		Thomas Siebert May 4, 2016
Hi Bernard, I rewrote the function completely and it is now shorter and more clear. Now I get with your Text: Text_Wrap_Around ( "Very good job, Iâ€™m excited! but [Iâ€™m] may not be split." ; 17 ) ---> "Very good job, Iâ€™m excited! but [Iâ€™m] may not be split. "

		Bernard Moreau, Belgium, Borchtlombeek May 4, 2016
Hi Thomas, For me, this is perfect. I vote the maximum rate ! Thanks. Bernard.

		Thomas Siebert May 5, 2016
Error found: if text ends with: "Bernard Moreau, Belgium May 03, 2016 3:34am" â€¦ the last line will be missing. but if works with a blank before "am" : "Bernard Moreau, Belgium May 03, 2016 3:34 am"

		Bernard Moreau, Belgium, Borchtlombeek May 9, 2016
Indeed, this last new version is not stable : - error you pointed out (line with "3:34am" missing) - some errors with Â¶ return in text - not keeping the linespaces between 2 paragraphs ( = .Â¶Â¶ or more repeated Â¶ returns) Previous version (I fortunately keeped) didn't generated the first error and was nicely compact. Knowing it was not managing the 'Â¶ return' in text, for me it was more convenient.

		Thomas Siebert May 13, 2016
I have the function rewritten once again. seems a lot better then the last version and more flexible then the first stable version.

		Bernard Moreau, Belgium, Borchtlombeek May 16, 2016
Much better, thank you. Last remaining error, depending of the limit_around length, Â¶ end of paragraph sometimes becomes Â¶Â¶ (adds one line space).

		Douglas Faneuil, n/a Oct 8, 2024
absolute lifesaver thank you!

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

Text_Wrap_Around ( Text ; limit_around )

Comments

Support this website.

Support this website.