PathParser ( thePath ; returnElementPHFNE )

PathParser returns the directory path, home directory, full filename and extension, filename, or extension from a folder and/or file path string.

Average rating: 4.3 (13 votes) Log in to vote

Lewis Lorenz - Show more from this author
Lorenz Companies
http://www.LorenzCom.com

Sample input:

PathParser ( "file:" & Get ( DocumentsPath ) & "Untitled.pdf" ; "p" )
PathParser ( Get ( DocumentsPath ) & "Untitled.pdf" ; "h" )
PathParser ( Get ( DocumentsPath ) & "Untitled.pdf" ; "fullfilename" )
PathParser ( Get ( DocumentsPath ) & "Untitled.pdf" ; "n" )
PathParser ( Get ( DocumentsPath ) & "Untitled.pdf" ; "e" )
PathParser ( Get ( DocumentsPath ) & "Untitled.pdf" ; "2" )
PathParser ( Get ( DocumentsPath ) & "Untitled.pdf" ; "-1" )

Sample output:

file:/Macintosh HD2/Users/user/Documents/
/Users/user/Documents/
Untitled.pdf
Untitled
pdf
/user/Documents/
/Macintosh HD2/Users/user/

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

Let ( [ 
//PATH: Default to NULL if thePath is empty.
p =  If ( IsEmpty ( Trim ( thePath ) ) ; "" ; thePath ) ;

//FM PREFIX: Preserve file reference prefix.
frp = Middle ( p ; 1 ; Position ( p ; ":" ; 1 ; 1 ) ) ;
frn = GetAsBoolean ( PatternCount ( "xfile:xfilemac:xfilewin:xfmnet:" ; "x" & Trim ( frp ) ) ) ;
p = If ( frn ; Replace ( p ; 1 ; Length ( frp ) ; "" ) ; p ) ;

//REQUESTED ELEMENT OR OMIT NUMBER: Get returnElementPHFNE request (PHFNE~ or #).
r = Left ( Trim ( returnElementPHFNE ) ; 1 ) ;
n = Int ( GetAsNumber ( If ( r = "?" ; "" ; returnElementPHFNE ) ) ) ;
r = If ( IsEmpty ( n ) ; r ; "#" ) ;

//OS PATH REQUEST: Is home path requested?
osp = GetAsBoolean ( PatternCount ( "~h" ; r ) ) ;

//SYSTEM PLATFORM. -1 = OS 9, 1 = OSX, -2 = Windows.
sp = Abs ( Get ( SystemPlatform ) ) ;

//PATH SEPARATOR: Get path separator based on platform: if Mac and not ":" use "/" for Unix. Allow "/" or "\" for Windows.
ps = Left ( If ( sp = 1 ; Filter ( p ; ":/\\" ) ; Filter ( p ; "\/" ) ) ; 1 ) ;  //Precedence is important.
s = If ( IsEmpty ( ps ) ; "/" ; ps ) ;

//PATH VALUES: Create the path list.
pl = Substitute ( p ; s ; "¶" ) ;
//Count of elements. Add 1 if rightmost character is a path separator, no filename.
plc = ValueCount ( pl ) + ( Right ( thePath ; 1 ) = s ) ;
//Path is the left values of pl if the count is greater than 1, else only a filename was passed.
pv = If ( plc > 1 ; LeftValues ( pl ; plc - 1 ) ; "" ) ;
//Count the path values.
pvc = ValueCount ( pv ) ;
//Adjust pv for OS home path request.
pvi = Case ( osp and ( GetValue ( pv ; 2 ) = Substitute ( Get ( SystemDrive ) ; "/" ; "" ) )  ; 3 ;  osp ; 2 ; 1 ) ; 
//Adjust the path values with index.
pv = MiddleValues ( pv ; pvi ; pvc ) ;
//Adjust the path values by the omit number, if present.
pv = Case ( r ≠ "#" or n = 0 ; pv ; n < 0 ; LeftValues ( pv ; pvc + n ) ; n > 0 ; RightValues ( pv ; pvc - ( n + GetAsNumber ( IsEmpty ( GetValue ( pv ; 1 ) ) ) ) ) ; "" ) ; 

//PATH STRING: 
p = Substitute ( pv ; "¶" ; s ) ;
//Prepend file reference prefix and add the separator to the left if path not empty.
p = If ( frn ; frp  ; "" ) & If ( IsEmpty ( p ) or Left ( p ; 1 ) = s ; "" ; s ) & p ;
//p = If ( frn ; frp  ; "" ) & p ;

//FILE NAME: The last value of pl. Assumed if only one value in pl.
//File value separated by the extension separator.
fv = Substitute ( GetValue ( pl ; plc ) ; "." ; "¶" ) ;
//Get count of extension separators, adding one if last character is extension separator.
fc = ValueCount ( fv ) + ( Right ( thePath ; 1 ) = "." ) ;
//Filename is all values left of the rightmost "." if it exists.
f = Substitute ( If ( fc > 1 ; LeftValues ( fv ; fc -1 ) ; fv ) ; "¶" ; "." ) ;

//EXTENSION SEPARATOR: Store 0 or 1, based on presence of decimal separator at end of file name. 
es = GetAsNumber ( GetAsBoolean ( Right ( f ; 1 ) = "." ) ) ;

//EXTENSION: Get extension if it exists.
e = If ( fc > 1 ; GetValue ( fv ; fc ) ; "" )

] ;

Case ( 
PatternCount ( "ph~#" ; r ) ; p ;  //Path only.
r = "f" ; f & e ;  //Full filename and extension.
r = "n" ; Left ( f; Length ( f ) - es ) ;  //Filename only (without extension).
r = "e" ; e ;  //Extension only.
r = "?" ; "PathParser ( thePath , returnElementPHFNE: [p]ath, [h]ome or [~], [f]ull name and extension, [n]ame, [e]xtension), [+/-#] omit # of directories )" ;
"" )  //Return nothing is user requested nothing.

)

/* PathParser ( thePath , returnElementPHFNE )

PathParser returns the directory path, home directory, full filename and extension, filename, or extension from a folder and/or file path string.

- Easily extract path elements from thePath.
- Preserves FileMaker Pro file reference prefixes (file:, filemac:, and filewin:).
- Omit directories forwards or backwards from thePath.
- The home or ~ (tilde) element request returns the home path - path without Get ( SystemDrive ) prepended.
- Works with the thePath string as passed - it does not format thePath, except to prepend a missing path separator when returning path or home requests.
- Uses the leftmost path separator in thePath to delineate path elements.
- Use with the PathMaker custom function for added path formatting control.

Parameters:

- thePath - A folder and/or file path.
- returnElementPHFNE - The element in thePath to return. Determined from the first letter of the passed parameter or the number:
   - [p]ath: Returns the directory path, without the filename and extension.
   - [h]ome or ~: Returns the home directory path, without the system drive information.
   - [f]ullfilename: Returns the filename and extension, without the path directory.
   - [n]ame: Returns the filename, without the path directory and without the file extension.
   - [e]xtension: Returns the file extension, without the path directory and without filename.
   - [+/-#]: Returns the path after omitting the specified number (#) of directories from the left or right of thePath. 
       - A positive number omits directories forwards from the left.
       - A negative number omits directories backwards from the right.

Examples:

- PathParser ( "file:" & Get ( DocumentsPath ) & "Untitled.pdf" ; "p" ) = file:/Macintosh HD2/Users/user/Documents/
- PathParser ( Get ( DocumentsPath ) & "Untitled.pdf" ; "h" ) = /Users/user/Documents/
- PathParser ( Get ( DocumentsPath ) & "Untitled.pdf" ; "fullfilename" ) = Untitled.pdf
- PathParser ( Get ( DocumentsPath ) & "Untitled.pdf" ; "n" ) = Untitled
- PathParser ( Get ( DocumentsPath ) & "Untitled.pdf" ; "e" ) = pdf
- PathParser ( Get ( DocumentsPath ) & "Untitled.pdf" ; "2" ) = /user/Documents/
- PathParser ( Get ( DocumentsPath ) & "Untitled.pdf" ; "-1" ) = /Macintosh HD2/Users/user/

Help:

- Passing '?' as the leftmost text in returnElementPHFNE returns this help text: PathParser ( thePath , returnElementPHFNE: [p]ath, [h]ome or [~], [f]ull name and extension, [n]ame, [e]xtension), [+/-#] omit # of directories ).
*/

PathParser ( thePath , returnElementPHFNE )

PathParser returns the directory path, home directory, full filename and extension, filename, or extension from a folder and/or file path string.

- Easily extract path elements from thePath.
- Preserves FileMaker Pro file reference prefixes (file:, filemac:, and filewin:).
- Omit directories forwards or backwards from thePath.
- The home or ~ (tilde) element request returns the home path - path without Get ( SystemDrive ) prepended.
- Works with the thePath string as passed - it does not format thePath, except to prepend a missing path separator when returning path or home requests.
- Uses the leftmost path separator in thePath to delineate path elements.
- Use with the PathMaker custom function for added path formatting control.

Parameters:

- thePath - A folder and/or file path.
- returnElementPHFNE - The element in thePath to return. Determined from the first letter of the passed parameter or the number:
- [p]ath: Returns the directory path, without the filename and extension.
- [h]ome or ~: Returns the home directory path, without the system drive information.
- [f]ullfilename: Returns the filename and extension, without the path directory.
- [n]ame: Returns the filename, without the path directory and without the file extension.
- [e]xtension: Returns the file extension, without the path directory and without filename.
- [+/-#]: Returns the path after omitting the specified number (#) of directories from the left or right of thePath.
- A positive number omits directories forwards from the left.
- A negative number omits directories backwards from the right.

Examples:

- PathParser ( "file:" & Get ( DocumentsPath ) & "Untitled.pdf" ; "p" ) = file:/Macintosh HD2/Users/user/Documents/
- PathParser ( Get ( DocumentsPath ) & "Untitled.pdf" ; "h" ) = /Users/user/Documents/
- PathParser ( Get ( DocumentsPath ) & "Untitled.pdf" ; "fullfilename" ) = Untitled.pdf
- PathParser ( Get ( DocumentsPath ) & "Untitled.pdf" ; "n" ) = Untitled
- PathParser ( Get ( DocumentsPath ) & "Untitled.pdf" ; "e" ) = pdf
- PathParser ( Get ( DocumentsPath ) & "Untitled.pdf" ; "2" ) = /user/Documents/
- PathParser ( Get ( DocumentsPath ) & "Untitled.pdf" ; "-1" ) = /Macintosh HD2/Users/user/

Help:

- Passing '?' as the leftmost text in returnElementPHFNE returns this help text: PathParser ( thePath , returnElementPHFNE: [p]ath, [h]ome or [~], [f]ull name and extension, [n]ame, [e]xtension), [+/-#] omit # of directories ).

Comments

		Lewis Lorenz, Lorenz Companies Oct 23, 2016
I updated this function 10/23/2016 to allow skipping directories in thePath. User can send a positive or negative number in the returnElement parameter to skip directories either forward from the left or backwards from the right.

		Robert R, Brooksville, FL Jan 21, 2018
I have tried this in FMPA 16 and can't get by the saving it as a custom function as it says "The specified parameter can't be found " refering to "thePath" any thoughts or updates for FMPA 16

		Lewis Lorenz, Lorenz Companies Jan 25, 2018
I haven't had issues with this. Can you supply more information?

		Steve, Lancaster May 8, 2018
I too am having the same issue with the error "The specified parameter can't be found" in reference to "thePath." I copied and pasted it directly from the site. Is there anything else that needs to be done prior to trying to save the custom function? Thank you in advance.

		Lewis Lorenz, Lorenz Companies May 9, 2018
I am happy to fix this, but I can not replicate this issue. Please contact me at lewis@lorenzcom.com with information about how you encountered this error. Thank you.

		Steve, Lancaster May 9, 2018
Sure, I will email you in a second. Thanks!

		Steve, Lancaster May 9, 2018
Actually, I figured out what I was doing wrong. I had not set the Function Parameters. Thank you for your custom function and willingness to help. Much appreciated!

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

PathParser ( thePath ; returnElementPHFNE )

Comments

Support this website.

Support this website.