rw ( text )

evaluates formula inside texts

Average rating: 4.6 (11 votes) Log in to vote

Hisc - Show more from this author
noplace
http://nourl

Sample input:

rw ( "Hello //$firstName//" )
rw ( "Hello //'$firstName & ', the bold'//")

Sample output:

"Hello Finn"
"Hello Finn, the bold"

// assuming $firstName is Finn

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*
RW (reWrite) — courtesy of Hisc — version 1.01
- this function is a fast way to compose text with evaluated parts inside.

for example, if one wants to use the variables $firstName and $lastName
  in a greeting in regular filemaker, they must write something like:

	"Hello " & $firstName & " " & $lastName

  with this function they will just write:

	rw ( "Hello //$firstName// //$lastName//" )

everything between the "//"s will be evaluated if possible. If impossible,
  the function returns the typed formula. So:

	rw ( "Hello //$firstName + x// //2+3//" )

  returns:

	"Hello //$firstName + x// 5"

Hope you may gain some time with this function!

*** version 1.01 NEW ***
- added the ability to use single quotes ( ' ) for double quotes ( " ) inside the evaluated part of the function.
- to do so, the evaluated part must begin with a single quote ( ' ); the initial single quote will not be considered in evaluation

	example without this technique:

		rw ( "I'd love to be an //if ( $gender = \"female\" ; \"actress\" ; \"actor\" )//! " )

	example with this new functionality:

		rw ( "I'd love to be an //'if ( $gender = 'female' ; 'actress' ; 'actor' )//! " )

WARNING:
- the initial single quote will not be considered.

So, for example, one could write:

		rw ( "//''Hi'//" )              // with two single quotes in the beginning

	and this will be evaluated as:

		Hi

	reason: the first single quote will trigger the functionality and the second and third will be converted to double quotes

But if one writes:

		rw ( "//'Hi'//" )              // with only one single quote in the beginning

	the result will be:

		//Hi"//

	reason:
	- the first single quote triggered the functionality
	- the second single quote was converted to double quote
	- as the second single quote was then the only double quote (for the first single quote was not considered) the function could not evaluate correctly. 

*/

Let([
	string = "//" ;
	stringEnd = "//" ;
	pos01 = Position ( text ; string ; 1 ; 1 ) ;
	pos02 = Position ( text ; stringend ; pos01 + Length ( string ) ; 1 )
];
	If (
		pos01 and pos02 ;
			Let ( [
				before = Left ( text ; pos01 - 1 ) ;
				middle_ = Middle ( text ; pos01 + Length ( string ) ; pos02 - ( pos01 + Length ( string ) ) ) ;
				middle_ = If ( Left ( middle_ ; 1 ) = "'" ; Substitute ( Right ( middle_ ; Length ( middle_ ) - 1 ) ; "'" ; "\"" ) ; middle_ ) ;
				after = Right ( text ; Length ( text ) - ( pos02 + Length ( stringEnd ) - 1 ) ) ;
				error = EvaluationError ( Let ( [ $RW_CF_temp_evaluatedMiddle = Evaluate ( middle_ ) ] ; "" ) ) ;
				nMiddle = If ( error ; string & middle_ & stringEnd ; $RW_CF_temp_evaluatedMiddle )
			];
				before & nMiddle & rw ( after )
			) ;
		text 
	)
)

this function is an easy way to code faster text in FileMaker. Using " & $var & " is not the simplest way to do stuff.
With this function, within your text you may include variables, calculations etc that will make your code clean.
The only con of this method is that it's not recommended for typing field names or custom functions inside, for FMP will not be able to adjust them if you make any adjustments on the CFs or names

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

rw ( text )

Comments

Support this website.

Support this website.