ValLeastSquaresSlope ( XValueList ; YValueList ; Xmean ; Ymean )

Calculates the slope of a set of X,Y pairs by least squares fit

Average rating: 3.5 (2 votes) Log in to vote

Bill Thurmes - Show more from this author
MDCA
http://www.miyotadca.com

Sample input:

ValLeastSquaresSlope ( "8¶2¶11" ; "3¶10¶3" ; 7 ; 5.333333 )

Sample output:

-0.833333

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/* ======================
# ValLeastSquaresSlope ( XValueList; YValueList; Xmean; Ymean )
# Purpose:		Calculates the slope of a set of X,Y pairs by least squares fit
# Parameters:	XValueList is a ¶-delimited List of X values (the X of an X,Y pair)
#         		YValueList is a ¶-delimited List of Y values (the Y of an X,Y pair)
#         		Xmean is the mean of all X values
#         		Ymean is the mean of all Y values
#
# Recursive
#
# Example: ValLeastSquaresSlope ( "8¶2¶11" ; "3¶10¶3" ; 7 ; 5.333333 )
# Result: -0.833333
#
# If the X- and Y-lists have different ValueCounts, the CF returns "Problem"; a mismatch means that the CF
# might try to associate an incorrect Y value for a given X value.
#
# This CF uses the following variables temporarily during execution, but should null them before the end:
# $~CFv_LeastSquaresSlope_sumXY
# $~CFv_LeastSquaresSlope_sumX2
#
# Author: Bill Thurmes, MDCA
# Creation date:	6/28/2018
============================*/

Let (
	[
	~c = ( ValueCount ( XValueList ) = ValueCount ( YValueList ) ) and ValueCount ( XValueList ) > 0 ; //check that both lists have the same non-zero number of values
	~x = GetValue ( XValueList ; 1 ) ;
	~y = GetValue ( YValueList ; 1 ) ;
	~dx = ~x - Xmean ;
	~dy = ~y - Ymean ;
	$~CFv_LeastSquaresSlope_sumXY = $~CFv_LeastSquaresSlope_sumXY + ~dx * ~dy ;
	$~CFv_LeastSquaresSlope_sumX2 = $~CFv_LeastSquaresSlope_sumX2 + ~dx^2 ;
	~result = Case ( not ~c ;
		"Problem" ; //If there's a problem, return 'Problem'
		
		ValueCount ( XValueList ) > 1 ; //If there are more values, call the function again
		ValLeastSquaresSlope ( RightValues ( XValueList ; ValueCount ( XValueList ) - 1 ) ;
			RightValues ( YValueList ; ValueCount ( YValueList ) - 1 ) ; 
			Xmean; 
			Ymean 
		) ; 
		
		$~CFv_LeastSquaresSlope_sumXY / $~CFv_LeastSquaresSlope_sumX2 /*If on last value, calculate slope*/ 
	) ; //End Case
	$~CFv_LeastSquaresSlope_sumXY = Case ( IsEmpty ( ~result ) ; $~CFv_LeastSquaresSlope_sumXY ; "" ) ; //If there's a result, null this variable and the next
	$~CFv_LeastSquaresSlope_sumX2 = Case ( IsEmpty ( ~result ) ; $~CFv_LeastSquaresSlope_sumX2 ; "" ) ] ;
~result )

Calculates the slope of a set of X,Y pairs by applying a least squares fit
Note: The ¶-delimited list of X values must have the same ValueCount as the ¶-delimited list of Y values

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

ValLeastSquaresSlope ( XValueList ; YValueList ; Xmean ; Ymean )

Comments

Support this website.

Support this website.