DefineVariables_ ( global_boolean )

subroutine of DefineVariables custom function

Be the first to rate this function Log in to vote

Jeff Drake - Show more from this author
Drakeling Technologies

Sample input:

(see DefineVariables)

Sample output:

returns no visible value

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*
=======================================================
    DefineVariables_ ©2007, 2008, 2009, 2014, 2015 Drakeling Technologies
    Creation: 2007 by Jeff Drake
    Modification: 29 April 2015 by Jeff Drake
    Modification: 7 August 2015 by Jeff Drake
    Modification: 28 September 2015 by Jeff Drake: updated to correctly process question marks.
    Modification: 11 November 2015 by Jeff Drake: updated to correctly process
     subsequent lines starting with a single word followed by a colon.

    Purpose: runs as a subroutine of the DefineVariables function, building the necessary Let( ) string

    Dependencies: TrimFrom

    Warning: if any variable contains a multiline value in which any subsequent line
     begins with a single word followed by a colon, said colon must be preceded by a
     backslash, e.g. "Four score and seven years ago, our fathers brought forth¶" &
     "First\\: a new nation".
=======================================================
*/


Let ( [
         #parameters = List ( Get ( ScriptParameter ) ; Get ( ScriptResult ) ) ;

         $ƒDefineVariables_[1] = $ƒDefineVariables_[1] + 1 ;

         #numberOfLines = ValueCount ( #parameters ) ;
         #currentLine = GetValue ( #parameters; $ƒDefineVariables_[1] ) ;
         #currentLine = Substitute ( #currentLine ; ["::" ; Char ( 2 ) & Char ( 2 )] ; ["\:" ; Char ( 3 ) & Char ( 3 )] ) ;
         #currentVariable = Trim ( Left ( #currentLine ; Position ( #currentLine ; ":" ; 1 ; 1 ) - 1 ) ) ;
         #currentVariable = Case (
                                          #currentVariable = $null ; $null ;
                                          PatternCount ( #currentVariable ; " " ) ; $null ;
                                             If ( global_boolean = True; "$" ) & "$" & #currentVariable
                                       ) ; //end Case

         #currentValue = If (
                                      #currentVariable = $null ;
                                         ¶ & #currentLine ;
                                         TrimFrom ( #currentLine ; ":" ; 1 )
                                   ) ; //end If
         #currentValue = Case (
                                      #currentValue = $null ; Quote ( $null ) ;
                                      #currentValue = "?" ; Quote ( "?" ) ;
                                      GetAsNumber ( #currentValue ) = #currentValue ; #currentValue ;
                                         Quote ( #currentValue )
                                   ) ; //end If
         #currentValue = Substitute ( #currentValue ; [Char ( 2 ) & Char ( 2 ) ; "::"] ; [Char ( 3 ) & Char ( 3 ) ; ":"] )

] ; //end define Let

   If (

      #currentVariable = $null ;

         " & " ;

         If ( $ƒDefineVariables_[1] > 1 ; "¶; " ) & #currentVariable & " = "

   ) //end If

   & #currentValue &

   //RECURSE THE FUNCTION, IF NECESSARY.
   If (

      $ƒDefineVariables_ < #numberOfLines ;

         DefineVariables_ ( global_boolean ) ;

         Let ( [ $ƒDefineVariables_[1] = $null ; $ƒDefineVariables_[2] = $null ] ; $null )

   ) //end If

) //end Let

runs as a subroutine of the DefineVariables function, building the necessary Let( ) string

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

DefineVariables_ ( global_boolean )

Comments

Support this website.

Support this website.