Modulo97 ( Praefix ; String )

Calclutates the 2 digit check code for Modulo97 validation and puts it between Praefix and String

Be the first to rate this function Log in to vote

Christoph Kaufmann - Show more from this author
CLK.ch
http://clk.ch

Sample input:

ISO11649

Sample output:

RF60ISO11649

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/* CF Modulo97 ( Praefix; String )

Praefix: two capital latin letters
String: the Ceditor reference or whatever you need check digits for. Digits, Spaces and latin letters only.

Calclutates the 2 digit check code for Modulo97 validation and puts it in.

sample input: Modulo97 ( "RF" ; "1234" )
sample output: RF541234

Uses: Creditor Reference with Modulo 97 validation (ISO 11649). Requires a string of 4-21 characters. The CF will work with any string length.

You may want to insert eye friendly spaces in the output: RF54 1234

Calculation by Erich Schmidt, Roggentin/Rostock
*/

Case	(
	Length ( praefix ) <> 2 ; "Praefix must be two capital latin letters."
	;
	praefix <> Filter ( Praefix ; "ABCDEFGHIJKLMNOPQRSTUVWXYZ" ) ; "Use capital latin letters only in the Praefix."
	;
	string <> Filter ( string ; "1234567890 ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz" ) ; "Illegal characters in the string, use " & Quote ( "1234567890 ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz" ) & " only."

	; // Checks end here, calculation starts

	Let	( [
		st = TrimAll ( string ; 1 ; 3 )
		;
		z = Substitute ( st & Praefix & "00" ; [ "A" ; 10 ] ; [ "B" ; 11 ] ; [ "C" ; 12 ] ; [ "D" ; 13 ] ; [ "E" ; 14 ] ; [ "F"; 15 ] ; [ "G" ; 16 ] ; [ "H" ; 17 ] ; [ "I" ; 18 ] ; [ "J" ; 19 ] ; [ "K" ; 20 ] ; [ "L" ; 21 ] ; [ "M" ; 22 ] ; [ "N" ; 23 ] ; [ "O" ;24 ] ; [ "P" ; 25] ; [ "Q" ; 26 ] ; [ "R" ; 27 ] ; [ "S" ; 28 ] ; [ "T" ; 29 ] ; [ "U" ; 30 ] ; [ "V" ; 31 ] ; [ "W" ; 32 ] ; [ "X" ; 33 ] ; [ "Y" ; 34 ] ; [ "Z" ; 35 ] )
		;
		m = 98 - Mod ( z ; 97 )
		;
		pp = Right ( 100 + m ; 2 )
		] ;

		praefix & pp & string

		) // End Let
	) // End Case

Building a Creditor Reference defined in ISO 11649:
Say your invoice number is 1234 (4-21 characters for Creditor References)
The Creditor Reference must be RFpp1234, where pp ist the check code that makes the whole string validate with Modulo97.

This CD calculates the check code for any combination of Prafix and String. No dependencies, but since the recipient's software will validate the Creditor Reference, you may want to test that validation using this CF here: https://www.briandunning.com/cf/988

Do not use this CF to build your own IBAN at home - a technically correct IBAN is an incorrect IBAN if your bank is not aware of its existence.

Thanks to Erich Schmidt for the math part.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

Modulo97 ( Praefix ; String )

Comments

Support this website.

Support this website.