JSON.AssignScriptResults ( )

Assign script results to variables that were passed as a JSON Object

Average rating: 5.0 (1 vote) Log in to vote

Michael Wallace - Show more from this author
Empowered Data Solutions
http://empowereddatasolutions.com

Sample input:

JSON.AssignScriptResults()

Sample output:

Various key/value pair from JSON Object -> variables and values

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/**
 * =====================================
 * JSON.AssignScriptResults
 * 
 * Modified from #AssignScriptParameters
 *
 * PURPOSE:
 * JSON.AssignScriptResults uses the current script result assuming
 * JSON format to declare and populate a series of locally-scoped script variables. 
 *
 * RETURNS:
 * True (Nonzero) when the script parameter is a valid set of name-value pairs (which
 * includes the empty string) and all parameters defined as required according to
 * the script name are non-null; False (0) otherwise.
 *
 * PARAMETERS: none
 *
 * DEPENDENCIES: none
 *
 *
 * HISTORY:
 * MODIFIED on 2020-05-02 by Michael Wallace of Empowered Data Solutions to handle
 * values that start and end with {} or [] but are not JSON elements or arrays
 * PORTED on 2019-03-28 by michael.wallace@empoweredds.com to use JSON parameters
 * MODIFIED on 2010-10-04 by jeremy@kyologic.com to return explicit True or
 * False values indicating successful evaluation of the script parameter, and to
 * fit syntax inspired by a comment on standards.filemakermagazine.com by
 * Richard Dyce.
 * CREATED on 2010-03-13 by Jeremy Bante of Kyo Logic (jeremy@kyologic.com).
 * INSPIRED by an example in the FileMaker help documentation.
 *
 * =====================================
 */
 
Let([
  ~jsonToUse = Get ( ScriptResult  )
; ~validJSON = Left ( JSONGetElement ( ~jsonToUse ; "" ) ; 1 ) <> "?"
; ~keys = JSONListKeys ( ~JSONToUse ; "" )

; ~start = "Let([ ~jsonToUse=" & Quote ( ~jsonToUse ) & ";~key=\""
; ~end = "\"; ~value=JSONGetElement(~jsonToUse;~key)];Case ( IsEmpty ( ~value ) ; \"\" ;GetAsNumber ( ~value ) = ~value ;\"$\" & ~key & \"=\" & ~value & \";\" ;Left(~value;1)=\"{\" and Right(~value;1)=\"}\" and Left(JSONGetElement (~value;\"\");1)<>\"?\" ;\"$\" & ~key & \"=JSONGetElement(\" & Quote ( ~value ) & \";\\\"\\\");\" ;Left(~value;1)=\"[\" and Right(~value;1)=\"]\" and Left(JSONGetElement (~value;\"\");1)<>\"?\";\"$\" & ~key & \"=JSONGetElement(\" & Quote ( ~value ) & \";\\\"\\\");\" ;\"$\" & ~key & \"=\" & Quote ( ~value ) & \";\"));"

; ~calc = "List(" & ~start & Substitute ( ~keys ; "¶" ; ~end & ~start ) & ~end & "\"\")"

; ~calc2 = If ( ~validJSON ; "Let([" & Evaluate ( ~calc ) & "~invalidvariable=\"\"];\"\")" )
; ~result = If ( ~validJSON ; Evaluate ( ~calc2 ) )
; ~checkCalc = "Length ( $" & Substitute ( ~keys ; "¶" ; " ) and Length ( $" ) & " )"
];
//check that required parameters are non-null
Case (
	not ~validJSON ; JSONListKeys ( ~JSONToUse ; "" ) ; // Return the JSON error if invalid JSON
	~validJSON and Length ( ~keys ); //script name specifies parameters
		Evaluate ( ~checkCalc	);
	//else, parameters are adequate by default
	True
)// End Case
)// End Let


/* Full expanded calc that creates second calc */
/*
Let([
  ~key="d"
; ~value=JSONGetElement($json;~key)
];
Case ( 
/* Empty then do nothing */
IsEmpty ( ~value ) ; "" ;

/* Number */
GetAsNumber ( ~value ) = ~value ;
"$" & ~key & "=" & ~value & ";" ;

/* Object */
Left(~value;1)="{" and Right(~value;1)="}" ;
"$" & ~key & "=JSONGetElement(" & Quote ( ~value ) & ";\"\");" ;

/* Array */
Left(~value;1)="[" and Right(~value;1)="]" ;
"$" & ~key & "=JSONGetElement(" & Quote ( ~value ) & ";\"\");" ;

"$" & ~key & "=" & Quote ( ~value ) & ";" 
)
)
*/

/* Second calc created from first calc */
/*
Let([
$a=1;
$b="ten";
$c=JSONGetElement("[\"hello\",\"world\"]";"");
$d=JSONGetElement("{\"foo\":\"bar\"}";"");~invalidvariable=""
];
""
)
*/

* =====================================
* JSON.AssignScriptResults
*
* Modified from #AssignScriptParameters
*
* PURPOSE:
* JSON.AssignScriptResults uses the current script result assuming
* JSON format to declare and populate a series of locally-scoped script variables.
*
* RETURNS:
* True (Nonzero) when the script parameter is a valid set of name-value pairs (which
* includes the empty string) and all parameters defined as required according to
* the script name are non-null; False (0) otherwise.
*
* PARAMETERS: none
*
* DEPENDENCIES: none
*
*
* HISTORY:
* MODIFIED on 2020-05-02 by Michael Wallace of Empowered Data Solutions to handle
* values that start and end with {} or [] but are not JSON elements or arrays
* PORTED on 2019-03-28 by michael.wallace@empoweredds.com to use JSON parameters
* MODIFIED on 2010-10-04 by jeremy@kyologic.com to return explicit True or
* False values indicating successful evaluation of the script parameter, and to
* fit syntax inspired by a comment on standards.filemakermagazine.com by
* Richard Dyce.
* CREATED on 2010-03-13 by Jeremy Bante of Kyo Logic (jeremy@kyologic.com).
* INSPIRED by an example in the FileMaker help documentation.
*
* =====================================

Comments

		Tom RuBane, RuBane Law P.C. Nov 19, 2020
Michael, I've found this - and your other JSON functions - to be really useful. Thank you!

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

JSON.AssignScriptResults ( )

Comments

Support this website.

Support this website.