@TextEncode ( textToEncode ; extendedASCIIChars ; lineEndings )

A wrapper for the function TextEncode() to convert text to any old-style Extended ASCII encoding.

Be the first to rate this function Log in to vote

Alex Zueiv - Show more from this author
Tashkent
https://github.com/zueiv

Sample input:

Let ( [
TEXT = "Çüé" ;
FILE = @TextEncode ( TEXT ; "ÇüéâäàąçêëèïîćÄĄĘęłôöĆûùŚÖÜ¢Ł¥śƒŹŻóÓńŃźż" ; 1 )
] ;
List (
HexEncode ( TEXT ) ;
HexEncode ( TextEncode ( TEXT ; "iso-8859-1" ; 1 ) ) ;
HexEncode ( FILE )
)
)

Sample output:

C387 C3BC C3A9
C7 FC E9
80 81 82

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

// @TextEncode ( textToEncode ; extendedASCIIChars ; lineEndings )
//
// Created 2019-06-25 by Alex Zueiv
//
// A wrapper for the function TextEncode() to convert text to any
// old-style Extended ASCII encoding.
//
// Parameters:
//
//    textToEncode - a text to be converted
//
//    extendedASCIIChars - a conversion table of 128 high ASCII
//                         characters to Substitute() each with
//                         Char(128…255)
//
//    lineEndings - 1 (unchanged), 2 (CR), 3 (LF), or 4 (CR/LF);
//                  see FMP help of the original function
//
// Result: container
//
// Note:
//
//    Any character above U+007F that is not present in the
//    extendedASCIIChars parameter will be removed.
//
// Test calculation for Data Viewer:
/*
      // convert the phrase "Hello World!" in Polish with Mazovia encoding table
      Let ( [
         TEXT = "Witaj świecie!" ;
         FILE = @TextEncode (
            TEXT ;
            "ÇüéâäàąçêëèïîćÄĄĘęłôöĆûùŚÖÜ¢Ł¥śƒŹŻóÓńŃźż¿⌐¬½¼¡«»░▒▓│┤╡╢╖╕╣║╗╝╜╛┐└┴┬├─┼╞╟╚╔╩╦╠═╬╧╨╤╥╙╘╒╓╫╪┘┌█▄▌▐▀αßΓπΣσµτΦΘΩδ∞φε∩≡±≥≤⌠⌡÷≈°∙·√ⁿ²■ " ;
            4
         )
      ] ;
         List (
            HexEncode ( TEXT ) ; // ==> 576974616A20 C59B 77696563696521
            HexEncode ( FILE ) ; // ==> 576974616A20  9E  77696563696521
         )
      )
*/
// Script example:
/*
      Export Records [ "utf-8.csv" ; Unicode (UTF-8) ]
      Insert File [ $FILE ; "utf-8.csv" ]
      Set Variable [ $TEXT ; TextDecode ( $FILE ; "utf-8" ) ]
      Set Field [ table::container ; @TextEncode ( $TEXT ; … ) ]
      Export Field Contents [ table::container ; "output.csv" ]
*/


Let ( [

// isolate local variables
i = $i ; t = $t ; h = $h ;

$i = 0 ;
$t = extendedASCIIChars ;

$h =	"|80|81|82|83|84|85|86|87|88|89|8A|8B|8C|8D|8E|8F" &
	"|90|91|92|93|94|95|96|97|98|99|9A|9B|9C|9D|9E|9F" &
	"|A0|A1|A2|A3|A4|A5|A6|A7|A8|A9|AA|AB|AC|AD|AE|AF" &
	"|B0|B1|B2|B3|B4|B5|B6|B7|B8|B9|BA|BB|BC|BD|BE|BF" &
	"|C0|C1|C2|C3|C4|C5|C6|C7|C8|C9|CA|CB|CC|CD|CE|CF" &
	"|D0|D1|D2|D3|D4|D5|D6|D7|D8|D9|DA|DB|DC|DD|DE|DF" &
	"|E0|E1|E2|E3|E4|E5|E6|E7|E8|E9|EA|EB|EC|ED|EE|EF" &
	"|F0|F1|F2|F3|F4|F5|F6|F7|F8|F9|FA|FB|FC|FD|FE|FF|" ;

// build substitution parameter list
SBST = Evaluate ( Replace ( Substitute (
	10 ^ Length ( $t ) - 1 ; 9 ;
	"&	let ( [
			h = middle( $h; $i*3+1; 4);
			$i = $i + 1;
			c = middle( $t; $i; 1)
		];
			\";[\" & quote(hexencode(c)) & \";\" & quote(h) & \"]\¶\"
		)¶
	"
) ; 1 ; 1 ; "" ) ) & ";[\"|\";\"\"]" ;

// generate low ascii table
ASCII = TextDecode ( HexDecode (
	  "0102030405060708090A0B0C0D0E0F" &
	"101112131415161718191A1B1C1D1E1F" &
	"202122232425262728292A2B2C2D2E2F" &
	"303132333435363738393A3B3C3D3E3F" &
	"404142434445464748494A4B4C4D4E4F" &
	"505152535455565758595A5B5C5D5E5F" &
	"606162636465666768696A6B6C6D6E6F" &
	"707172737475767778797A7B7C7D7E7F" ;
	"ascii.txt"
) ; "utf-8" ) ;

// remove unsupported unicode characters
$t = HexEncode ( Filter ( textToEncode ; ASCII & extendedASCIIChars ) ) ;

// perform substitution in hex mode
RSLT = Evaluate ( "substitute( $t" & SBST & ")" ) ;

// restore isolated variables
$i = i ; $t = t ; $h = h

] ;

// adjust line endings with the original function
TextEncode ( TextDecode (
	HexDecode ( RSLT ; "output.txt" ) ;
	"iso-8859-1"
) ; "iso-8859-1" ; lineEndings )

)

A wrapper for the function TextEncode() to convert text to any old-style Extended ASCII encoding.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

@TextEncode ( textToEncode ; extendedASCIIChars ; lineEndings )

Comments

Support this website.

Support this website.