@GetBackgroundFileName ( )

Returns the name of the topmost background file.

Be the first to rate this function Log in to vote

Alex Zueiv - Show more from this author
Tashkent
https://github.com/zueiv

Sample input:

@GetBackgroundFileName

Sample output:

MySecondFile

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

// @GetBackgroundFileName ( )
// Created 2019-07-10 by Alex Zueiv
//
// Returns the name of the topmost background file.
// All windows must have unique names.
// Does non support floating windows.
// Requires FM 18 or higher.


Let ( [

FLS = DatabaseNames ;
QTY = ValueCount ( FLS ) ;

// get window names of other files
WINS = While (
	[ i = 0 ; this = Get ( FileName ) ; r = "" ] ;
	i < QTY ;
	[
		i = i + 1 ;
		f = GetValue ( FLS ; i ) ;
		r = List (
			r ;
			If ( f ≠ this ;
				WindowNames ( f )
			)
		)
	] ;
	r
) ;

// sort to get the topmost window
TOPW = GetValue ( FilterValues ( WindowNames ; WINS ) ; 1 )

] ;

// return the background file name
While (
	[ i = 0 ; r = "" ] ;
	i < QTY and IsEmpty ( r ) ;
	[
		i = i + 1 ;
		f = GetValue ( FLS ; i ) ;
		w = WindowNames ( f ) ;
		r = If ( not IsEmpty ( FilterValues ( w ; TOPW ) ) ; f )
	] ;
	r
)

)

All windows must have unique names.
Does non support floating windows.
Requires FM 18 or higher.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

@GetBackgroundFileName ( )

Comments

Support this website.

Support this website.