PutValue18 ( ValueList ; ValueNumber ; ReplaceString )

Replaces a designated value in a value list with another value

Be the first to rate this function Log in to vote

Bill Thurmes - Show more from this author
MDCA
http://www.miyotadca.com

Sample input:

PutValue18 ( "1¶3¶5" ; 2 ; "yellow" )
PutValue18 ( "1¶3¶5" ; 5 ; "yellow" )

Sample output:

"1¶yellow¶5"
"1¶3¶5¶¶yellow"

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/* =====================================
# PutValue18 ( ValueList ; ValueNumber ; ReplaceString )
# 
# Complement to GetValue, replacing a given value number with ReplaceString
# Returns the new value list complete with ReplaceString
#
# Parameters:
# ValueList: a ¶-delimited value list
# ValueNumber: the value into which ReplaceString should be placed, replacing current value
# ReplaceString: new value
#
# Notes: 
# If ValueNumber > ValueCount ( ValueList ), more values will be added before ReplaceString so that
# 	it will be value # ValueNumber
#		(only recursion is in While statement adding extra values)
# If ReplaceString is "" then value ValueNumber will be empty
# ReplaceString can include ¶, so Result may contain more values than original ValueList
#
# Examples: PutValue18 ( "1¶3¶5" ; 2 ; "yellow" ) = "1¶yellow¶5"
# PutValue18 ( "1¶3¶5" ; 5 ; "yellow" ) = "1¶3¶5¶¶yellow"
# PutValue18 ( "1¶9¶3¶577¶6" ; 3 ; GetValue ( "1¶9¶3¶577¶6" ; 3 ) & ¶ & "yellow" ) = "1¶9¶3¶yellow¶577¶6"
# 
# By Bill Thurmes, MDCA
# revised 9/8/2016, header reformatted for clarity 2/16/2019; Changed with While 10/17/2019
========================================*/
Let ( [ ~VL = Case ( PatternCount ( ValueList ; ¶ ) < ValueNumber - 1 ;
		While ( [ `v = ValueList ;
				`n = ValueNumber ;
				`c = PatternCount ( ValueList ; ¶ ) ] ; //end While initial
				GetAsNumber ( `c ) < `n - 1 ; //While condition
					[ `v = `v & ¶ ;
					`c = `c + 1 ] ; //end While Logic
				`v ) ; //end While
			ValueList ) ; //end Case
	~N = ValueNumber - 1 ;
	~B = Position ( ~VL ; ¶ ; 1 ; ~N ) ;
	~L = Length ( ~VL ) ;
	~E = Case ( 	
					PatternCount ( ~VL ; ¶ ) ≥ GetAsNumber ( ValueNumber ) ; 
					Position ( ~VL ; ¶ ; 1 ; ValueNumber ) - 1 ; 
					
					~L ) ; //end Case
	~Result = Case (
			PatternCount ( ~VL ; ¶ ) ≥ ValueNumber - 1 ; 
			Left ( ~VL ; ~B ) & ReplaceString & Right ( ~VL ; ~L - ~E ) ;
			
			"" ) //end Case
		] ; //end variable assignment portion of Let
					
	~Result
	)//end Let

Replaces a designated value with another value in ¶-delimited value list. If value list does not already contain ValueNumber values, adds extra values until ValueCount = ValueNumber. A compliment to GetValue.
Requires FMP 18 or later.
Just like PutValue, except that recursion (to bring ValueCount to ValueNumber) is replaced by While function, which just seems more elegant.
Note that ReplaceString can contain multiple values (separated by ¶), so Result may have more values than ValueList, but never fewer
(Note: if you continue using PutValue, for FMP versions previous to 18, a problem was fixed in Oct 2019.)

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

PutValue18 ( ValueList ; ValueNumber ; ReplaceString )

Comments

Support this website.

Support this website.