@XOR ( numberOne ; numberTwo )

Non-recursive binary XOR function.

Be the first to rate this function Log in to vote

Alex Zueiv - Show more from this author
Tashkent
https://github.com/zueiv

Sample input:

@XOR ( 3 ; 5 )

Sample output:

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/**
* @XOR ( numberOne ; numberTwo )
*
* Non-recursive binary XOR function.
*
* Usage example:

	@XOR ( 3 ; 5 ) ; // ==> 6

* Created 2020-05-03 by Alex Zueiv
* https://www.briandunning.com/cf/2373
**/


Let ( [

	// convert parameters to non-empty positive integers
	N1 = 0 + Abs ( Int ( numberOne ) ) ;
	N2 = 0 + Abs ( Int ( numberTwo ) )

] ;

Case (

	N1 = 0 ; N2 ;
	N2 = 0 ; N1 ;
	N1 = N2 ; 0 ;

	Let ( [

		// isolate local variables
		x = $x ; i = $i ; fx = $fx ;

		// function to convert a decimal number ($x) to a list of binary digits (low bit first)
		$fx = "
			let([¶
				b = if( $x > 0; floor(lg( $x )) );¶
				$i = 1¶
			];¶
				evaluate(¶
					\"mod($x;2)\"¶
					& if( b ;¶
						substitute( 10^b-1; 9; \"&\\\¶&let($i=$i+1;div(mod($x;2^$i);2^($i-1)))\" )¶
					)¶
				)¶
			)
		" ;

		// create two binary lists
		$x = N1 ;
		BL1 = Evaluate ( $fx ) ;
		$x = N2 ;
		BL2 = Evaluate ( $fx ) ;

		// apply boolean xor to the binary lists and summarize the results
		$i = -1 ;
		$x = If ( N1 < N2 ; BL1 ; BL2 ) ;
		LST = If ( N1 > N2 ; BL1 ; BL2 ) & ¶ ;
		EXPRS = "let([x="
			& Substitute ( LST ; ¶ ;
				";$i=$i+1;y=getvalue($x;$i+1)];(x xor y)*2^$i)¶+let([x="
			) &"0];x)" ;
		RSLT = Evaluate ( EXPRS ) ;

		// restore isolated variables
		$x = x ; $i = i ; $fx = fx

	] ; RSLT )

) )

Non-recursive binary XOR function.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

@XOR ( numberOne ; numberTwo )

Comments

Support this website.

Support this website.