util.FormatWithMask ( text_to_format ; format_mask )

Format text with a simple mask using # as a placeholder for text in the mask

Be the first to rate this function Log in to vote

Pip Meadway - Show more from this author
PIPCO IT

Sample input:

util.FormatWithMask ( "01234987654" ; "(#####) ######" )

Sample output:

"(01234) 987654"

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/* ==========================================================
 
PUBLIC (Text) <- util.FormatWithMask ( text_to_format  ; format_mask )
 
PURPOSE:
	Format the text in <<text_to_format>> with the mask <<format_mask>>

RETURNS:
	The formatted text

PARAMETERS:
	NAME		TYPE		DESCRIPTION
	text_to_format	Text		The original text
	format_mask	Text		The mask.

 A hash symbol # is used in the mask as a placeholder for a character from the 
<<text_to_format>>,with each # consuming a character from the <<text_to_format>>.

To insert a hash symbol, use \# in the mask

SIDE EFFECTS:
	None

EXAMPLES:
	$my_home_phone = util.FormatWithMask ( "01234987654" ; "(#####) ######" )

			$my_home_phone is set to "(01234) 987654"

	$my_home_phone = util.FormatWithMask ( "01234987654" ; "\# (#####) ######" )

			$my_home_phone is set to "# (01234) 987654"


DEPENDENCIES: 
	None

HISTORY:
	CREATED on 2020-07-22 by Pip Meadway

This was inspired by the Mask () custom function by Geoffrey Gerhard here:
https://www.briandunning.com/cf/872

=========================================================== */

While ( [
	~placeholder	= "#" ;
	~escape_chr	= "\\" ;

	~len_text = Length ( text_to_format ) ;
	~idx_text = 1 ;

	~len_mask = Length (format_mask ) ;
	~idx_mask = 1 ;

	~result = "" 
	] ;

	~idx_mask <= ~len_mask ; 


	[
	~mask_chr = Middle ( format_mask ; ~idx_mask ; 1 ) ;
	~escaped  = ( ~mask_chr = ~escape_chr and Middle ( format_mask ; ~idx_mask + 1 ; 1 ) = ~placeholder ) ;
 
	~result = ~result & 
		Case ( 
			~mask_chr = ~placeholder and ~idx_text <= ~len_text ;
				Middle ( text_to_format ; ~idx_text ; 1 ) ; 

			~mask_chr = ~placeholder and ~idx_text > ~len_text ;
				"" ; 

			~escaped = True ;
				~placeholder ;

			 /* Else */
			~mask_chr ) ;

	~idx_mask = ~idx_mask + 1 + ~escaped; $idx_mask = ~idx_mask ;

	~idx_text = If ( ~mask_chr = ~placeholder ; ~idx_text + 1 ; ~idx_text )

	] ; 

~result )

This was inspired by the Mask () custom function by Geoffrey Gerhard here: https://www.briandunning.com/cf/872

I have used the FMP18 While () function to implement this rather than making it recursive.

The mask uses a hash character # to show where the text in the text to format is consumed - each # character consumes a single character from the text to format.

If the mask is longer than the text to format, then the return result is only as long as the text to format, conversely if the text to format is longer than the mask, then the return result is only as long as the mask.

e.g.

util.FormatWithMask ( "ABCDE" ; "#######" ) will return "ABCDE"
util.FormatWithMask ( "ABCDE" ; "###" ) will return "ABC"

Anything other than a # character is put into the result as is

e.g.

util.FormatWithMask ( "ABCDE" ; "Start=#-#-#-#-#=The end" ) will return "Start=A-B-C-D-E=The end"

If you need to include a # character as literal text, escape it using the backslash \ character

e.g.

util.FormatWithMask ( 12345 ; "\####-##" ) will return "#123-45"

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

util.FormatWithMask ( text_to_format ; format_mask )

Comments

Support this website.

Support this website.