util.TextMatchesFormat ( text_to_match ; format )

Determines if text_to_match is in the format specified

Be the first to rate this function Log in to vote

Pip Meadway - Show more from this author
PIPCO IT

Sample input:

util.TextMatchesFormat ( "01234987654" ; "01nnnnnnnnn" )

Sample output:

True

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/* ==========================================================
 
PUBLIC (Boolean) <- util.TextMatchesFormat ( text_to_match  ; format )
 
PURPOSE:
	Determines if <<text_to_match>> is in the format <<format>>

RETURNS:
	The formatted text

PARAMETERS:
	NAME		TYPE		DESCRIPTION
	text_to_match	Text		The original text
	format		Text		The format to be checked againsy

The <<format>> parameter can take any of the following symbols as a matching value

	n 	any number
	a	any letter, upper or lower case
	A-Z	The specific letter, upper or lower case
	_	A space
	?	Any character

SIDE EFFECTS:
	None

EXAMPLES:
	util.TextMatchesFormat ( "01234987654" ; "01nnnnnnnnn" ) returns True
	util.TextMatchesFormat ( "01234987654" ; "01nnnnnnnn" ) returns False


DEPENDENCIES: 
	None

HISTORY:
	CREATED on 2020-07-22 by Pip Meadway

=========================================================== */

While ( 
	[
	~alpha	= "a" ;
	~numeric	= "n" ;
	~space	= "_" ;
	~any		= "?" ;

	~alphabet_upper	= "ABCDEFGHIJKLMNOPQRSTUVWXYZ" ;
	~alphabet_lower	= "abcdefghijklmnopqrstuvwxyz" ;
	~alphabet_all		= ~alphabet_upper & ~alphabet_lower ;
	~digits			= "0123456789" ;

	~all_allowed = ~alpha & ~numeric & ~space & ~any & ~alphabet_upper & ~alphabet_lower & ~digits;

	~fmt_len = Length ( format );
	~fmt_idx = 1;

	~txt_len = Length ( text_to_match ) ;

	// Number should be same length as the format and format should only contain allowed chars

	~match = (~txt_len = ~fmt_len) and Filter ( format ; ~all_allowed ) = format

	] ; 

	~match = True and  ~fmt_idx <= ~fmt_len; 

	[
	~fmt_chr = Middle ( format ; ~fmt_idx ; 1 ) ;
	~txt_chr = Middle ( text_to_match ; ~fmt_idx ; 1 ) ;

	~match = Case (
				~fmt_chr = ~numeric ;
					Filter ( ~txt_chr ; ~digits ) = ~txt_chr ;

				~fmt_chr = ~alpha ;
					Filter ( ~txt_chr ; ~alphabet_all ) = ~txt_chr ;

				~fmt_chr = ~space ;
					Filter ( ~txt_chr ; " " ) = ~txt_chr ;

				~fmt_chr = ~any ;
					True ;

				/* Else */
					~txt_chr = ~fmt_chr );

	~fmt_idx = ~fmt_idx + 1
	] ; 

~match )

This is a simple format matching CF, for more complex formatting I would suggest using BERegularExpression () from Base Elements plug-in.

The format parameter can be a combination of literal text and placeholders for types of characters:

n any number
a any letter, upper or lower case
A-Z The specific letter, upper or lower case
_ A space
? Any character

Some examples:

a six digit number "nnnnnn"
six digits with a trailing alpha "nnnnnna"

I developed this to detect and format UK phone numbers, and I have tested it on c. 30,000 phone numbers.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

util.TextMatchesFormat ( text_to_match ; format )

Comments

Support this website.

Support this website.