@JsonEvaluate ( quotedJSONString )

Returns the decoded value of a quoted JSON string (for all FM versions).

Be the first to rate this function Log in to vote

Alex Zueiv - Show more from this author
Tashkent
https://github.com/zueiv

Sample input:

@JsonEvaluate ("\"a\rb\"" )

Sample output:

a
b

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/**
* @JsonEvaluate ( quotedJSONString )
*
* Returns the decoded value of a quoted JSON string.
* Works with any FM version including Runtime.
* In FM16+, calls the built-in JSON function.
* A pair for the cf/2411 @JsonQuote().
*
* Usage examples:
*
	Let ( [
		OBJ = "{\"a\":\"b\rc\"}" ;
		ObjQLS = Substitute (
			Middle ( OBJ ; 2 ; Length ( OBJ ) - 2 ) ;
			[ ":\"" ; "¶\"" ]
		) ;
		ARR = "[\"a\",\"b\rc\",\"d\"]" ;
		ArrQLS = Substitute (
			Middle ( ARR ; 2 ; Length ( ARR ) - 2 ) ;
			[ ",\"" ; "¶\"" ]
		)
	] ;
		List (
			Quote ( @JsonEvaluate ( GetValue ( ObjQLS  ; 1 ) ) ) ;
			Quote ( @JsonEvaluate ( GetValue ( ObjQLS  ; 2 ) ) ) ;
			"--" ;
			Quote ( @JsonEvaluate ( GetValue ( ArrQLS  ; 1 ) ) ) ;
			Quote ( @JsonEvaluate ( GetValue ( ArrQLS  ; 2 ) ) ) ;
			Quote ( @JsonEvaluate ( GetValue ( ArrQLS  ; 3 ) ) )
		)
	)
*
* Result:
*
*	"a"
*	"b¶c"
*	--
*	"a"
*	"b¶c"
*	"d"
*
* Created 2020-09-11 by Alex Zueiv
* https://www.briandunning.com/cf/2412
**/

Let (

VRS = Substitute ( Get ( ApplicationVersion ) ; "." ; Left ( 1/2 ; 1 ) ) ;

If ( Abs ( VRS ) < 16 or PatternCount ( VRS ; "Runtime" ) ;

	Evaluate ( Substitute (

		quotedJSONString ;

		[ "\\\\"	; ¶		] ; // encode backslashes parity
		[ "\\"		; "\1"		] ;
		[ ¶		; "\1\2"	] ;

		[ "\¶"		; "\\\¶"	] ; // add odd backslashes
		[ "\“"		; "\\\“"	] ;
		[ "\”"		; "\\\”"	] ;
		[ "\„"		; "\\\„"	] ;
		[ "\‟"		; "\\\‟"	] ;
		[ "\﹨"		; "\\\﹨"	] ;

		[ "\1\""	; "\\\"" 	] ; // decode odd & even backslashes
		[ "\2\""	; "\\\"" 	] ;

		[ "\1u0001"	; Char(1)	] ; // decode control characters
		[ "\1u0002"	; Char(2)	] ;
		[ "\1u0003"	; Char(3)	] ;
		[ "\1u0004"	; Char(4)	] ;
		[ "\1u0005"	; Char(5)	] ;
		[ "\1u0006"	; Char(6)	] ;
		[ "\1u0007"	; Char(7)	] ;
		[ "\1b"		; Char(8)	] ;
		[ "\1t"		; Char(9)	] ;
		[ "\1r\1n"	; "\¶"		] ;
		[ "\1n"		; "\¶"		] ;
		[ "\1f"		; Char(12)	] ;
		[ "\1r"		; "\¶"		] ;
		[ "\1u000B"	; Char(11)	] ;
		[ "\1u000E"	; Char(14)	] ;
		[ "\1u000F"	; Char(15)	] ;
		[ "\1u0010"	; Char(16)	] ;
		[ "\1u0011"	; Char(17)	] ;
		[ "\1u0012"	; Char(18)	] ;
		[ "\1u0013"	; Char(19)	] ;
		[ "\1u0014"	; Char(20)	] ;
		[ "\1u0015"	; Char(21)	] ;
		[ "\1u0016"	; Char(22)	] ;
		[ "\1u0017"	; Char(23)	] ;
		[ "\1u0018"	; Char(24)	] ;
		[ "\1u0019"	; Char(25)	] ;
		[ "\1u001A"	; Char(26)	] ;
		[ "\1u001B"	; Char(27)	] ;
		[ "\1u001C"	; Char(28)	] ;
		[ "\1u001D"	; Char(29)	] ;
		[ "\1u001E"	; Char(30)	] ;
		[ "\1u001F"	; Char(31)	] ;

		[ "\2\¶"	; "\\\¶"	] ; // decode even backslashes

		[ "\2\\"	; ¶		] ; // remove even backslashes
		[ "\2"		; ""		] ;
		[ "\1"		; "\\"		] ;
		[ "¶1"		; "\\\\"	] ;
		[ ¶		; "\\\\"	]

	) ) ;

	// fm16+
	Evaluate (
		"jsongetelement(\"[\\"
		& Left ( quotedJSONString ; Length ( quotedJSONString ) - 1 )
		& "\\\"]\";0)"
	)

) )

Returns the decoded value of a quoted JSON string.
Works with any FM version including Runtime.
In FM16+, calls the built-in JSON function.
A pair for the cf/2411 @JsonQuote().

Comments

		Philip Wang, 106th Street Wheel and Tire Dec 7, 2022
The substitution is missing the [ "\1/" ; "/" ] ; Otherwise it's all good.

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

@JsonEvaluate ( quotedJSONString )

Comments

Support this website.

Support this website.