JSONGetElementsAsVariables ( JSON ; Globals ; Prefix )

Converts JSON to Variables or Global Variables (Supports JSON sub arrays)

Be the first to rate this function Log in to vote

Kyle Williams - Show more from this author
Augusto Digital
https://www.youtube.com/channel/UCpJlB7cmVNMjbjgY96MEsng

Sample input:

JSONGetElementsAsVariables ( $$JSON; 1; "" )

Sample output:

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*
  Created by: 		Kyle Williams    12/03/2020    kylew.fmdev@gmail.com
  UPDATED by:		Kyle Williams      7/17/2021 - Added a Substitute to replace spaces in the key value with underscores to prevent variable name errors
  UPDATED by:		Kyle Williams         6/22/2022 to corrected bug from variable name used in formula ($~~Thisvalue -> at the end of the formula)
  Purpose:			use to pass in JSON objects to convert to FileMaker variables
  Dependencies:	None
  NOTE:  			This function uses a recursion formula so it will work with versions prior to FM18

  - Example formula (includes extracting JSON SubArrays:
==================================================================

Let([
	 vars = JSONGetElementsAsVariables ( Get(ScriptParameter); 0; "" )
	;vars = JSONGetElementsAsVariables ( $window; 0; "window" )
	;vars = JSONGetElementsAsVariables ( $position; 0; "window.position" )
];"")


---------------------
 - Example Returns 
	* $Title
	* $Message
	* $window (=JSON SubArray)
	* $position (=JSON SubArray from within $window )

	* $window.Name
	* $window.dimWindow

	* $window.position.Top
	* $window.position.Left
	* $window.position.Width
	* $window.position.Height

==================================================================*/


Case (
    not $~~LoopCount
    ;Let ( [
		 $~~LoopCount = 1
		;$$~~s = If ( Globals ; "$$" ; "$" ) 
		;$$~~s = $$~~s & If(not IsEmpty( Prefix ); Prefix & ".") 
		;$$~~Keys = JSONListKeys ( JSON; "" ) 
		;$$~~FoundCount = ValueCount ( $$~~Keys )
     ];
        JSONGetElementsAsVariables ( JSON; Globals; Prefix )
     )

//ELSE IF
    ;$~~LoopCount < $$~~FoundCount

    ;Let ( [
		 $~~Thiskey = Substitute( GetValue ( $$~~keys ; $~~LoopCount ); " "; "_" )
		;$~~Thisvalue = JSONGetElement ( JSON ;  $~~Thiskey )		;$~~SetVariable = Evaluate ( "Let(" & $$~~s & $~~Thiskey & "=" & Quote( $~~Thisvalue ) & ",\"\")" )
		;$~~LoopCount = $~~LoopCount + 1 
     ];
        JSONGetElementsAsVariables ( JSON; Globals; Prefix )
     )

//ELSE IF
    ;$~~LoopCount ≥ $$~~FoundCount
	;Let([
		 $~~Thiskey = GetValue ( $$~~keys ; $~~LoopCount )
		;$~~Thisvalue = JSONGetElement ( JSON ;  $~~Thiskey )
		;$~~SetVariable = Evaluate ( "Let(" & $$~~s & $~~Thiskey & "=" & Quote( $~~Thisvalue ) & ",\"\")" )
		;$~~LoopCount = "" 
		;$$~~s = ""
		;$$~~Keys = ""
		;$~~Thiskey = ""
		;$~~Thisvalue = ""
		;$$~~FoundCount = ""
	];
       ""
	)
 )

Converts JSON to Variables or Global Variables (Supports JSON sub arrays)

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

JSONGetElementsAsVariables ( JSON ; Globals ; Prefix )

Comments

Support this website.

Support this website.