GetRecordAsJSON2

Get the data for one record as json with the field name as key.

Be the first to rate this function Log in to vote

tomida - Show more from this author
https://twitter.com/qbxxdp

Sample input:

GetRecordAsJSON2 ( "TableName" )

Sample output:

{"Field01":"Value01","Field02":["Repetition01","Repetition02","Repetition03"]}

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

Let (
[
_query = "select  
'[\"'||TableName ||'::'||FieldName||'\"'
,''||''||FieldReps||']'
FROM FILEMAKER_FIELDS
WHERE 
TableName ='{TableName}'
AND
FieldClass = 'Normal'
AND
FieldType NOT LIKE 'global%' /*Exclude global field*/
AND
FieldType <> 'binary' /*Excluded object field*/

"
;_query=Substitute ( _query ; "{TableName}" ; TableName )
;_FieldNames = ExecuteSQL ( _query　; "," ; "" )
]; 

While ( 
	[ 
		_json=""
		;_MAX = ValueCount ( _FieldNames )
		;_n= 1 
	] ; 
	_n <= _MAX ; 
	[
		_Array=GetValue ( _FieldNames ; _n )
		;_FieldName=JSONGetElement(_Array;0)
		;_FieldReps=JSONGetElement(_Array;1)
		;_key = GetValue ( Substitute ( _FieldName ; "::" ; ¶ ) ; 2 )      

		;_json = If(_FieldReps=1;
					JSONSetElement ( _json ; _key ; GetField ( _FieldName ) ; JSONString)
				;
					JSONSetElement ( _json ; _key ; 
						While ( 
							[
							_RepsData=""
							;_i = 1
							;_index=0
							]; 
							_i<=_FieldReps; 
							[
							_RepsData=JSONSetElement (_RepsData ; "[" &_index & "]" ; GetField ( _FieldName & "["&_i &"]" ) ;JSONString)
							;_i =_i+ 1
							;_index=_index+1
							]; 
							_RepsData
							)
						; JSONArray)
				)//if

		;_n=_n+1
	] ;
	_json
)

)

Get the data for one record as json with the field name as key.

Excluded fields: Calculation, Summary, Object, Global
FileMaker Pro 18 or later

If the field is iterative, it will be a JSON array.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

GetRecordAsJSON2

Comments

Support this website.

Support this website.