JSONGetElementWhere ( json ; element ; where ; operator ; criteria )

Get a desired element from a JSON array

Be the first to rate this function Log in to vote

Jake Scheele - Show more from this author
Edimate
http://www.edimate.com

Sample input:

JSONGetElementWhere ( "[{\"status\":\"active\"},{\"status\":\"inactive\"}]" ; "~i" ; "status" ; "=" ; "active" )

Sample output:

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

// JSONGetElementWhere ( json ; element ; where ; operator ; criteria )
// Author/Date: 	Jake Scheele 11/4/20 www.edimate.com
// Purpose: Return desired element from an array where a certain value is true
// Compatibility:	FileMaker 18 or newer
// Parameters:
//		1. JSON Array
//		2. Desired element from the found array index (pass "~i" to get index number, or pass "" to get the entire found element)
//		3. Where - the element in the array you want to search on
//		4. Operator (usually "=") - the operator used in evaluate function to compare Where to Criteria
//		5. Criteria - what you are searching for in the Where
// Notes: This function currently only grabs 1 value. You can only grab a unique value, not multiple. This may be changed in the future.

SetRecursion ( 

While ([ initialVariables = 1
	; ~json = json
	; ~element = element
	; ~where = where
	; ~operator = operator
	; ~criteria = criteria

	; ~counter = 0
	; ~countValues = ValueCount ( JSONListValues ( ~json ; "" ) )
	; ~result = ""
 ]; 
	~counter < ~countValues ; // condition to run while loop (only runs while condition is true)
 [ logic = 1
	; ~counter = ~counter + 1
	; ~test_criteria	= JSONGetElement ( ~json ; "[" & ~counter - 1 & "]" & ~where )
	; ~validation = Evaluate ( Quote ( ~test_criteria ) & ~operator & Quote ( ~criteria ) )
	; ~new_element = If ( ~element = "~i" ; ~counter - 1 ; JSONGetElement ( ~json ; "[" & ~counter - 1 & "]" & ~element  ) )
	; ~result = If ( ~validation 
				; ~new_element
				; ~result
			   )
   ]; 
	~result
 )

; 10000 )

This function will return the desired element or index number when passed a valid JSON array and criteria.

Note: This function currently only grabs 1 value. You can only grab a unique value, not multiple. This may be changed in the future.

Comments

		Kyle Williams, Augusto Digital May 11, 2021
https://www.youtube.com/watch?v=ksJ-s1Zz2C8

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

JSONGetElementWhere ( json ; element ; where ; operator ; criteria )

Comments

Support this website.

Support this website.