FormatDate ( Date, Format )

Allows you to easily reformat any date

Be the first to rate this function Log in to vote

Kyle Williams - Show more from this author
Augusto Digital
https://www.youtube.com/channel/UCpJlB7cmVNMjbjgY96MEsng

Sample input:

FormatDate ( get(CurrentDate ), "[Dayname] - [Month] [DD], [YYYY]" )

Sample output:

Monday - August 23, 2021

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

//Author, Kyle Williams 1/9/2019

Let ( [
	dt = If ( GetAsText ( TheDate ) = "" ; Get ( CurrentDate )  ; TheDate )      //(Defaults to todays date if empty)
	] ;

	Substitute ( Format ;
		[ "[Dayname]";	DayName ( dt )  ] ;
		[ "[dayname]";	Lower ( DayName ( dt ) ) ] ;
		[ "[DAYNAME]";	Upper ( DayName ( dt ) ) ] ;
		[ "[Day]";		Left ( DayName ( dt ) ; 3 ) ] ;
		[ "[day]";		Lower ( Left ( DayName ( dt ) ; 3 ) ) ] ;
		[ "[DAY]";		Upper ( Left ( DayName ( dt ) ; 3 ) ) ] ;
		[ "[DD]";		Right ( "0" & Day ( dt ) ; 2 )] ;
		[ "[D]";		Day ( dt )] ;
		[ "[Month]";	MonthName ( dt ) ] ;
		[ "[month]";	Lower ( MonthName ( dt ) ) ] ;
		[ "[MONTH]";	Upper ( MonthName ( dt ) ) ] ;
		[ "[Mon]";		Left ( MonthName ( dt ) ; 3 ) ] ;
		[ "[mon]";		Lower ( Left ( MonthName ( dt ) ; 3 ) ) ] ;
		[ "[MON]";		Upper ( Left ( MonthName ( dt ) ; 3 ) ) ] ;
		[ "[MM]";		Right ( "0" & Month ( dt ) ; 2 ) ] ;
		[ "[M]";		Month ( dt ) ] ;
		[ "[YYYY]";		Year ( dt ) ] ;
		[ "[YY]";		Right ( Year ( dt ) ; 2 ) ] ;
		[ "[CC]";		Left ( Year ( dt ) ; 2 ) +1]  //Current Century # (eg: 1/1/2019 = "21" since it is the 21st century)
	)
)

It is really hard to find a really good custom function to format dates. After failing to find any good functions to perform this task, I decided to create my own..

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

FormatDate ( Date, Format )

Comments

Support this website.

Support this website.