Compare ( value1 ; operation ; value2 )

Compares two values based on a given operator. Useful if operator is variable.

Average rating: 3.0 (2 votes) Log in to vote

Ethan - Show more from this author
Tactile Medical
https://www.linkedin.com/in/ethyoder

Sample input:

Input 1: Compare ( 80 ; ">=" ; 90 )
Input 2: Compare ( "aa" ; "bw" ; "a" )
Input 3: Compare ( 1 ; "asdf" ; 1 )

Sample output:

Output 1: 0
Output 2: 1
Output 3:

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

//	NAME		Compare
//	DESCRIPTION	Compares two values based on a given operator. Useful if operator is variable.
//
//	PARAMETERS	value1 (any): the first value you want to compare
//			operation (see below):  the operator you want to use to compare the two values
//			value2 (any): the second value you want to compare

//	RETURNS	boolean
//
//	EXAMPLE	Compare ( 80 ; ">=" ; 90 )
//	RESULT		0
//
//	DEPENDENCIES	<<none>>
//
//	NOTES		The operators available are:
//
//			= equals
//			== exact equal
//
//			!= not equal
//			≠ not equal
//			<> not equal
//
//			> greater than
//			>= greater than or equal
//			< less than
//			<= less than or equal
//
//			bw begins with
//			!bw does not begin with
//			ew ends with
//			!ew does not end with
//
//			>> contains
//			!>> does not contain
//
//
//	2021-10-27, EY, Created CF (based on cfMatch [https://www.briandunning.com/cf/1134])


Let ([

	vValue1 = value1 ;
	vOperation = operation ;
	vValue2 = value2

];

	Case ( 
		vOperation = "<>" or Exact ( vOperation ; "!=" ) or ( Code ( vOperation ) = Code ( "≠" ) ) ;
		vValue1 <> vValue2 ;

		vOperation = "=" ;
		vValue1 = vValue2 ;

		vOperation = "==" ;
		Exact ( vValue1 ; vValue2 ) ;

		vOperation = ">" ;
		vValue1 > vValue2 ;

		vOperation = ">=" ;
		vValue1 >= vValue2 ;

		vOperation = "<" ;
		vValue1 < vValue2 ;

		vOperation = "<=" ;
		vValue1 <= vValue2 ;

		vOperation = "bw" ;
		Left ( vValue1 ; Length ( vValue2 ) ) = vValue2 ;

		vOperation = "!bw" ;
		Left ( vValue1 ; Length ( vValue2 ) ) <> vValue2 ;

		vOperation = "ew" ;
		Right ( vValue1 ; Length ( vValue2 ) ) = vValue2 ;

		vOperation = "!ew" ;
		Right ( vValue1 ; Length ( vValue2 ) ) <> vValue2 ;

		vOperation = ">>" ;
		PatternCount ( vValue1 ; vValue2 ) > 0 ;

		vOperation = "!>>" ;
		PatternCount ( vValue1 ; vValue2 ) = 0 ;
		
		// ELSE
		""
	)
)

Compares two values based on a given operator. Useful if operator is variable. Available operators are listed in the custom function.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

Compare ( value1 ; operation ; value2 )

Comments

Support this website.

Support this website.