SQLasJSON ( tablename ; fields ; condition )

Performs SQL query on designated table and returns response from declared fields wrapped as JSON.

Be the first to rate this function Log in to vote

Jonni™ - Show more from this author

Sample input:

SQLasJSON ( "myTable" ; "field1, field2, field3" ; "WHERE myField = 'myValue'" )

Sample output:

{
"data" :
{
"columns" : 3,
"rows" : 2
},
"response" :
[
{
"fieldName1" : "value1",
"fieldName2" : "value2",
"fieldName3" : "value3"
},
{
"fieldName1" : "value1",
"fieldName2" : "value2",
"fieldName3" : "value3"
}
]
}

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

If ( GetAsNumber ( Filter ( Get ( ApplicationVersion ) ; ".0123456789" ) ) < 18 ; "Error: requires FileMaker 18 or higher." ;

While ( [ 

~table = tablename ; // insert table name here
~columns = fields ;
~cleanColumns = Case ( Right ( ~columns ; 1 ) = "," ; Left ( ~columns ; Length ( ~columns ) - 1 ) ; ~columns ) ; 
~condition = Case ( IsEmpty ( condition ) ; "" ; " " & condition )  ; // optional condition
~thatUUID = Get ( UUID ) ; // unique row separator
~fields = Substitute ( ~cleanColumns ; ", " ; "¶" ) ; // sql query for all field names in designated table
~selector = "\"" & Substitute ( ~fields ; "¶" ; "\", \"" )  & "\""; // yields comma separated string of field names
~query = "SELECT " & ~selector & " FROM " & ~table & ~condition ; // define sql query 
~execute = ExecuteSQL ( ~query ; ~thatUUID ; "" ) ; // perform sql query, fields are separaed with unique separation key
~rowCount = ValueCount ( ~execute ) ; // number of rows returned from query
~fieldCount = ValueCount ( ~fields ) ; // number of fields in table
~runCount = ~fieldCount * ~rowCount ; // number of times the statement has to run is once for every field in each row
~calc = Case ( ~rowCount > 0 ; JSONSetElement ( "" ; [ "data.rows" ; ~rowCount ; 2 ] ; [ "data.columns" ; ~fieldCount ; 2 ] ) ; "" ) ; // initalisaion of variable ; // initalisaion of variable
~row = "" ; // initalisaion of variable
~i = 1 ; // run iterator
~ri = 1 ; // row iterator
~fi = 1 ; // field iterator
~ai = 0 // object array iterator

] ; 

~i ≤ ~runCount // run this as long as the iterator is less than or equal to the number of runs needed

; [ 

~ai = Ceiling ( ( ~i / ~fieldCount ) - 1 ) ; // repeat the array iterator as many times as the number of fields then increase by one 
~ri = Ceiling ( ~i / ~fieldCount ) ; // repeat the row iterator as many times as the number of fields then increase by one 
~row = Substitute ( GetValue ( ~execute ; ~ri ) ; ~thatUUID ; "¶" ) ; // fetch current row form list of returned rows from sql query
~calc = JSONSetElement ( ~calc ; "response[" & ~ai & "]" & GetValue ( ~fields ; ~fi ) ; GetValue ( ~row ; ~fi ) ; 1 ) ; // build json array with field name as key
~fi = Case ( ~fi < ~fieldCount ; ~fi + 1 ; 1 ) ; // iterator that increments by one until the number of fields is reached then it's reset to start again from 1
~i = ~i + 1 // run iterator

] ; 

~calc

)
)

// Written by: jonni@me.com
// V 2.0

This function performs an ExecuteSQL query to the designated table to retrieve values of declared field names. If the condition is passed blank or partial table if SQL conditions are passed in the conditions parameter.

The results is then wrapped into a JSON array where each row is defined as one object consisting of entities where key is defined as the declared field name populated but the returned value.

Additionally row count and field count are returned within the data object.

Requires FileMaker 18 or higher

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

SQLasJSON ( tablename ; fields ; condition )

Comments

Support this website.

Support this website.