SSNValidate ( SSN )

Basic validation for social security numbers

Be the first to rate this function Log in to vote

Travis Wilton - Show more from this author
Entellic Corporation
https://entellic.com

Sample input:

SSNValidate ("123456789")

Sample output:

Dummy SSN

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

// —— 	SSNValidate (SSN) 	——
// Returns "Pass" or the type of error encountered
// SSN must be passed as text or FM won't carry through any leading zeros


// Performs the following checks on a SSN:
//	1. Cannot begin with 9
//	2. 9 digits long (without hyphens)
//	3. If hyphens exist, they are both in the correct place
//	4. Contains only digits and hyphens
//	5. First 3 digits cannot be 000 or 666
//	6. Next 2 digits cannot be 00
//	7. Last 4 digits cannot be 0000
//	8. Cannot be a known dummy number




Let ( [
_ssn = SSN;
_number = Filter ( _ssn ; "1234567890" );
_first = Left ( _number ; 1 ) = "9";
_area = Left ( _number ; 3 );
_group = Left ( Right ( _number ; 6 ) ; 2 );
_serial = Right ( _number ; 4 );
_digits = Length ( _number ) ≠ 9;
_hyphens = 
	Case ( 
		IsEmpty ( Filter ( _ssn ; "-" ) ) ; 
			0 ; 
		Right ( Left ( _ssn ; 4 ) ; 1 ) ≠ "-" 
			or
		Right ( Left ( _ssn ; 7 ) ; 1 ) ≠ "-" 
		 );
_nonDigits = Filter ( _ssn ; "1234567890-" ) ≠ _ssn ;
_ags = 
	_area = "000" 
		or 
	_area = "666" 
		or 
	_group = "00" 
		or 
	_serial = "0000";
_dummy = 
	_number = "078051120" 
		or 
	_number = "111111111" 
		or 
	_number = "123456789" 
		or 
	_number = "219099999" 
		//or
	//_number = "999999999" <<<can't begin with 9 anyway>>>
];
If ( Sum ( _first ; _digits ; _hyphens ; _nonDigits ; _ags ; _dummy ) = 0 ; "Pass";
		Case (
			_first = 1 ; "Begins with \"9\"";
			_hyphens = 1 ; "Hyphen misplaced";
			_nonDigits = 1 ; "Non-digit in SSN";
			_ags = 1 ; "Invalid area, group or serial number";
			_dummy = 1 ; "Dummy SSN";
			_digits = 1 ; "SSN not 9 digits long"
			 )
	 )
 )

Performs the following checks on a SSN:
1. Cannot begin with 9
2. 9 digits long (without hyphens)
3. If hyphens exist, they are both in the correct place
4. Contains only digits and hyphens
5. First 3 digits cannot be 000 or 666
6. Next 2 digits cannot be 00
7. Last 4 digits cannot be 0000
8. Cannot be a known dummy number

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

SSNValidate ( SSN )

Comments

Support this website.

Support this website.